build.gradle

group 'io.github'
version '1.0-SNAPSHOT'

buildscript {
    ext.kotlin_version = '1.1.3-2'

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'kotlin'

repositories {
    mavenCentral()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
    // https://mvnrepository.com/artifact/com.google.code.gson/gson
    compile group: 'com.google.code.gson', name: 'gson', version: '2.8.1'
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}
compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

// Configuration options for Docker builds

// Produces a JAR with a fixed name
jar {
    manifest {
        attributes(
                'Main-Class': 'Main', // needs to be changed to your project's main class name
                'Class-Path': configurations.compile.collect { it.getName() }.join(' ')
        )
    }
    archiveName "build.jar"
}

// Copies the project and its dependent JARs into a folder that'll be copied into the runtime container.
task bundleWithDependencies(type: Copy) {
    dependsOn build
    from configurations.runtime
    from jar
    into "${project.projectDir}/build/output"
}

// No-op task; serves to make Gradle install dependencies when building the Docker container
task install {}