forked from objectbox/objectbox-java
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
178 lines (159 loc) · 6.36 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
buildscript {
ext {
// Typically, only edit those two:
def objectboxVersionNumber = '3.1.0' // without "-SNAPSHOT", e.g. '2.5.0' or '2.4.0-RC'
def objectboxVersionRelease = true // set to true for releasing to ignore versionPostFix to avoid e.g. "-dev" versions
// version post fix: '-<value>' or '' if not defined; e.g. used by CI to pass in branch name
def versionPostFixValue = project.findProperty('versionPostFix')
def versionPostFix = versionPostFixValue ? "-$versionPostFixValue" : ''
ob_version = objectboxVersionNumber + (objectboxVersionRelease? "" : "$versionPostFix-SNAPSHOT")
// Native library version for tests
// Be careful to diverge here; easy to forget and hard to find JNI problems
def nativeVersion = objectboxVersionNumber + (objectboxVersionRelease? "": "-dev-SNAPSHOT")
def osName = System.getProperty("os.name").toLowerCase()
def objectboxPlatform = osName.contains('linux') ? 'linux'
: osName.contains("windows")? 'windows'
: osName.contains("mac")? 'macos'
: 'unsupported'
ob_native_dep = "io.objectbox:objectbox-$objectboxPlatform:$nativeVersion"
essentials_version = '3.1.0'
junit_version = '4.13.2'
mockito_version = '3.8.0'
kotlin_version = '1.6.0'
coroutines_version = '1.6.0-RC'
dokka_version = '1.4.32'
println "version=$ob_version"
println "objectboxNativeDependency=$ob_native_dep"
}
repositories {
mavenCentral()
maven {
url "https://plugins.gradle.org/m2/"
}
}
dependencies {
classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
classpath "org.jetbrains.dokka:dokka-gradle-plugin:$dokka_version"
// https://github.com/spotbugs/spotbugs-gradle-plugin/releases
classpath "gradle.plugin.com.github.spotbugs.snom:spotbugs-gradle-plugin:4.7.0"
classpath "io.github.gradle-nexus:publish-plugin:1.1.0"
}
}
allprojects {
group = 'io.objectbox'
version = ob_version
repositories {
mavenCentral()
}
configurations.all {
resolutionStrategy.cacheChangingModulesFor 0, 'seconds' // SNAPSHOTS
}
}
if (JavaVersion.current().isJava8Compatible()) {
allprojects {
tasks.withType(Javadoc) {
options.addStringOption('Xdoclint:none', '-quiet')
}
}
}
def projectNamesToPublish = [
'objectbox-java-api',
'objectbox-java',
'objectbox-kotlin',
'objectbox-rxjava',
'objectbox-rxjava3'
]
def hasSigningProperties() {
return (project.hasProperty('signingKeyId')
&& project.hasProperty('signingKeyFile')
&& project.hasProperty('signingPassword'))
}
configure(subprojects.findAll { projectNamesToPublish.contains(it.name) }) {
apply plugin: 'maven-publish'
apply plugin: 'signing'
publishing {
repositories {
maven {
name = 'GitLab'
if (project.hasProperty('gitlabUrl') && project.hasProperty('gitlabPrivateToken')) {
// "https://gitlab.example.com/api/v4/projects/<PROJECT_ID>/packages/maven"
url = "$gitlabUrl/api/v4/projects/14/packages/maven"
println "GitLab repository set to $url."
credentials(HttpHeaderCredentials) {
name = "Private-Token"
value = gitlabPrivateToken
}
authentication {
header(HttpHeaderAuthentication)
}
} else {
println "WARNING: Can not publish to GitLab: gitlabUrl or gitlabPrivateToken not set."
}
}
// Note: Sonatype repo created by publish-plugin.
}
publications {
mavenJava(MavenPublication) {
// Note: Projects set additional specific properties.
pom {
packaging = 'jar'
url = 'https://objectbox.io'
licenses {
license {
name = 'The Apache Software License, Version 2.0'
url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
distribution = 'repo'
}
}
developers {
developer {
id = 'ObjectBox'
name = 'ObjectBox'
}
}
issueManagement {
system = 'GitHub Issues'
url = 'https://github.com/objectbox/objectbox-java/issues'
}
organization {
name = 'ObjectBox Ltd.'
url = 'https://objectbox.io'
}
scm {
connection = 'scm:git@github.com:objectbox/objectbox-java.git'
developerConnection = 'scm:git@github.com:objectbox/objectbox-java.git'
url = 'https://github.com/objectbox/objectbox-java'
}
}
}
}
}
signing {
if (hasSigningProperties()) {
String signingKey = new File(signingKeyFile).text
useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
sign publishing.publications.mavenJava
} else {
println "Signing information missing/incomplete for ${project.name}"
}
}
}
wrapper {
distributionType = Wrapper.DistributionType.ALL
}
// Plugin to publish to Central https://github.com/gradle-nexus/publish-plugin/
// This plugin ensures a separate, named staging repo is created for each build when publishing.
apply plugin: "io.github.gradle-nexus.publish-plugin"
nexusPublishing {
repositories {
sonatype {
if (project.hasProperty("sonatypeUsername") && project.hasProperty("sonatypePassword")) {
println('nexusPublishing credentials supplied.')
username = sonatypeUsername
password = sonatypePassword
} else {
println('nexusPublishing credentials NOT supplied.')
}
}
}
}