sp_cardio_certeza.CLP

; De momento, esto queda asi.
; Seria necesario explicar por que se calcula todo como se calcula.
; Ademas, el ejercicio sugiere al final realizar ciertas discretizaciones.
; Esto queda pendiente.

;PLANTILLAS OBJETO-ATRIBUTO-VALOR-FACTORDECERTEZA
;*******************************************************************************
(deftemplate oavc-u "Hechos univaluados"
	(slot objeto (type SYMBOL) )
	(slot atributo (type SYMBOL) )
	(slot valor)
	(slot factor (type FLOAT) (range -1.0 +1.0) )
)

(deftemplate oavc-m "Hechos multivaluados"
	(slot objeto (type SYMBOL) )
	(slot atributo (type SYMBOL) )
	(slot valor)
	(slot factor (type FLOAT) (range -1.0 +1.0) )
)

;DESCRIPCION DE HECHOS
;*******************************************************************************
(deffacts hechos_Marta "Descripcion de Marta"
	(oavc-u	(objeto Marta)
		(atributo sexo)
		(valor mujer)
		(factor 1.0)
	)
	(oavc-u	(objeto Marta)
		(atributo edad)
		(valor 12)
		(factor 1.0)
	)
	(oavc-u	(objeto Marta)
		(atributo peso)
		(valor obeso)
		(factor 1.0)
	)
	(oavc-m	(objeto Marta)
		(atributo sintomas)
		(valor fiebre)
		(factor 0.6)
	)
	(oavc-m	(objeto Marta)
		(atributo evidencias)
		(valor rumor_sistolico)
		(factor 0.8)
	)
	(oavc-u	(objeto Marta)
		(atributo sistolica)
		(valor 150)
		(factor 1.0)
	)
	(oavc-u	(objeto Marta)
		(atributo diastolica)
		(valor 60)
		(factor 1.0)
	)
)

(deffacts hechos_Luis "Descripcion de Luis"
	(oavc-u	(objeto Luis)
		(atributo sexo)
		(valor hombre)
		(factor 1.0)
	)
	(oavc-u	(objeto Luis)
		(atributo edad)
		(valor 49)
		(factor 1.0)
	)
	(oavc-u	(objeto Luis)
		(atributo peso)
		(valor obeso)
		(factor 0.5)
	)
	(oavc-m	(objeto Luis)
		(atributo sintomas)
		(valor dolor_abdominal)
		(factor 0.7)
	)
	(oavc-m	(objeto Luis)
		(atributo sintomas)
		(valor calambres_en_la_pierna_al_andar)
		(factor 0.6)
	)
	(oavc-m	(objeto Luis)
		(atributo evidencias)
		(valor rumor_abdominal)
		(factor 0.7)
	)
	(oavc-m	(objeto Luis)
		(atributo evidencias)
		(valor masa_pulsante_en_abdomen)
		(factor 0.8)
	)
	(oavc-u	(objeto Luis)
		(atributo sistolica)
		(valor 130)
		(factor 1.0)
	)
	(oavc-u	(objeto Luis)
		(atributo diastolica)
		(valor 90)
		(factor 1.0)
	)
)

(deffacts hechos_Andres "Descripcion de Andres"
	(oavc-u	(objeto Andres)
		(atributo sexo)
		(valor hombre)
		(factor 1.0)
	)
	(oavc-u	(objeto Andres)
		(atributo edad)
		(valor 63)
		(factor 1.0)
	)
	(oavc-u	(objeto Andres)
		(atributo peso)
		(valor obeso)
		(factor 0.7)
	)
	(oavc-m	(objeto Andres)
		(atributo sintomas)
		(valor calambres_en_la_pierna_al_andar)
		(factor 1.0)
	)
	(oavc-m	(objeto Andres)
		(atributo evidencias)
		(valor dilatacion_del_corazon)
		(factor 0.7)
	)
	(oavc-m	(objeto Andres)
		(atributo años_fumando)
		(valor 18)
		(factor 1.0)
	)
	(oavc-u	(objeto Andres)
		(atributo sistolica)
		(valor 145)
		(factor 1.0)
	)
	(oavc-u	(objeto Andres)
		(atributo diastolica)
		(valor 85)
		(factor 1.0)
	)
)

;REGLAS DE LA SEMANTICA
;*t*****************************************************************************
(defrule acumula_positivos_univaluados
	(declare (salience 10000) )
	?fact1 <-  (oavc-u (objeto ?o)
		(atributo ?a)
		(valor ?v)
		(factor ?f1&:(>= ?f1 0)&:(<= ?f1 1) )
	)
	?fact2 <-  (oavc-u (objeto ?o)
		(atributo ?a)
		(valor ?v)
		(factor ?f2&:(>= ?f2 0)&:(<= ?f2 1) ) 
	)
	(test (neq ?fact1 ?fact2) )
=>
	(retract ?fact1)
	(bind ?f3 (+ ?f1 (* ?f2 (- 1 ?f1) ) ) )
	(modify ?fact2 (factor ?f3) )
)

(defrule acumula_positivos_multivaluados
	(declare (salience 10000) )
	?fact1 <-  (oavc-m (objeto ?o)
		(atributo ?a)
		(valor ?v)
		(factor ?f1&:(>= ?f1 0)&:(<= ?f1 1) )
	)
	?fact2 <-  (oavc-m (objeto ?o)
		(atributo ?a)
		(valor ?v)
		(factor ?f2&:(>= ?f2 0)&:(<= ?f2 1) ) 
	)
	(test (neq ?fact1 ?fact2) )
=>
	(retract ?fact1)
	(bind ?f3 (+ ?f1 (* ?f2 (- 1 ?f1) ) ) )
	(modify ?fact2 (factor ?f3) )
)

(defrule garantizar_semantica "mantiene la semantica de los oav univaluados"
	(declare (salience 9000) )
	?f1 <-	(oavc-u	(objeto ?obj)
			(atributo ?atr)
			(valor ?)
		)
	?f2 <-	(oavc-u	(objeto ?obj)
			(atributo ?atr)
			(valor ?)
		)
	(test	(neq ?f1 ?f2) )
=>
	(retract ?f2)
)

(defrule duplicar-hechos
	(declare (salience 10000))
=>
	(set-fact-duplication TRUE)
)

;REGLAS DEL PROBLEMA
;*******************************************************************************
(defrule A "calcula la presion: presion = sistolica - diastolica"
	(declare (salience 20) )
	(oavc-u	(objeto ?paciente)
		(atributo sistolica)
		(valor ?sistolica)
		(factor 1.0)
	)
	(oavc-u	(objeto ?paciente)
		(atributo diastolica)
		(valor ?diastolica)
		(factor 1.0)
	)
=>
	(bind ?pulso (- ?sistolica ?diastolica) )
	(assert	(oavc-u	(objeto ?paciente)
			(atributo presion_pulso)
			(valor ?pulso)
			(factor 1.0)
		)
	)
)

(defrule B "aneurisma en arteria abdominal"
	(oavc-m	(objeto ?paciente)
		(atributo sintomas)
		(valor dolor_abdominal)
		(factor ?f1))
	(oavc-m	(objeto ?paciente)
		(atributo evidencias)
		(valor rumor_abdominal)
		(factor ?f2))
	(oavc-m	(objeto ?paciente)
		(atributo evidencias)
		(valor masa_pulsante_en_abdomen)
		(factor ?f3))
	(test (> (min ?f1 ?f2 ?f3) 0.2))
=>
	(bind ?f (* (min ?f1 ?f2 ?f3) 0.9))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor aneurisma_de_la_arteria_abdominal)
			(factor ?f)
		)
	)
)

(defrule R3a "regurgitacion aortica (ambas ciertas)"
	(oavc-u	(objeto ?paciente)
		(atributo sistolica)
		(valor ?sistolica &:(> ?sistolica 140) )
		(factor ?f1)
	)
	(oavc-u	(objeto ?paciente)
		(atributo presion_pulso)
		(valor ?pulso & :(> ?pulso 50) )
		(factor ?f2)
	)
	(oavc-m (objeto ?paciente)
		(atributo evidencias)
		(valor rumor_sistolico)
		(factor ?f3)
	)
	(oavc-m	(objeto ?paciente)
		(atributo evidencias)
		(valor dilatacion_del_corazon)
		(factor ?f4)
	)
	(test (> (min ?f1 ?f2 (max ?f3 ?f4)) 0.2))
=>
	(bind ?f (* (min ?f1 ?f2 (max ?f3 ?f4)) 0.7))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor regurgitacion_aortica)
			(factor ?f)
		)
	)
)
 
(defrule R3b "regurgitacion aortica (segunda cierta)"
	(oavc-u	(objeto ?paciente)
		(atributo sistolica)
		(valor ?sistolica & :(> ?sistolica 140))
		(factor ?f1)
	)
	(oavc-u	(objeto ?paciente)
		(atributo presion_pulso)
		(valor ?pulso & :(> ?pulso 50))
		(factor ?f2)
	)
	(not	(oavc-m	(objeto ?paciente)
			(atributo evidencias)
			(valor rumor_sistolico)
			(factor ?f3)
		)
	)
	(oavc-m	(objeto ?paciente)
		(atributo evidencias)
		(valor dilatacion_del_corazon)
		(factor ?f4)
	)
	(test (> (min ?f1 ?f2 ?f4) 0.2))
=>
	(bind ?f (* (min ?f1 ?f2 ?f4) 0.7))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor regurgitacion_aortica)
			(factor ?f)
		)
	)
)
 
(defrule R3c "regurgitacion aortica (primera cierta)"
	(oavc-u	(objeto ?paciente)
		(atributo sistolica)
		(valor ?sistolica & :(> ?sistolica 140))
		(factor ?f1))
	(oavc-u	(objeto ?paciente)
		(atributo presion_pulso)
		(valor ?pulso & :(> ?pulso 50) )
		(factor ?f2))
	(oavc-m	(objeto ?paciente)
			(atributo evidencias)
			(valor rumor_sistolico)
			(factor ?f3)
		)
	(not	(oavc-m	(objeto ?paciente)
			(atributo evidencias)
			(valor dilatacion_del_corazon)
			(factor ?f4)
		)
	)
 	(test (> (min ?f1 ?f2 ?f3) 0.2))
=>
	(bind ?f (* (min ?f1 ?f2 ?f3) 0.7))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor regurgitacion_aortica)
			(factor ?f)
		)
	)
)

(defrule E "calambre pierna debido a estenosis"
	(oavc-m	(objeto ?paciente)
		(atributo sintomas)
		(valor calambres_en_la_pierna_al_andar)
		(factor ?f1)
	)
	(test (> ?f1 0.2))
=>
	(bind ?f (* ?f1 0.9))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor estenosis_en_arteria_de_la_pierna)
			(factor ?f)
		)
	)
)

(defrule F "estenosis debido a arteriosclerosis"
	(oavc-m	(objeto ?paciente)
		(atributo diagnostico)
		(valor estenosis_en_arteria_de_la_pierna)
		(factor ?f1)
	)
	(test (> ?f1 0.2))
=>
	(bind ?f (* ?f1 0.8))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor arteriosclerosis)
			(factor ?f)
		)
	)
)

(defrule G "estenosis por obesidad"
	(oavc-u	(objeto ?paciente)
		(atributo peso)
		(valor obeso)
		(factor ?f1)
	)
	(test (> ?f1 0.2))
=>
	(bind ?riesgo 1)
	(bind ?f (* ?riesgo 0.8)) 
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor estenosis_en_arteria_de_la_pierna)
			(factor ?f)
		)
	)
)

(defrule H "estenosis por fumar durante mas de 15 años"
	(oavc-u (objeto ?paciente)
		(atributo años_fumando)
		(valor ?años)
		(factor ?f1)
	)
	(test (> ?años 15))
=>
	(bind ?riesgo 1)
	(bind ?f (* ?riesgo 0.8)) 
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor estenosis_en_arteria_de_la_pierna)
			(factor ?f1)
		)
	)
)

(defrule I "estenosis por tener mas de 50 años)"
	(oavc-u	(objeto ?paciente)
		(atributo edad)
		(valor ?años)
		(factor ?f1))
	(test (> ?años 50))
=>
	(bind ?riesgo 1)
	(bind ?f (* ?riesgo 0.6))
	(assert	(oavc-m	(objeto ?paciente)
			(atributo diagnostico)
			(valor estenosis_en_arteria_de_la_pierna)
			(factor ?f)
		)
	)
)



(defrule nombra_diagnosticos "imprime por pantalla todos los diagnosticos"
	(declare (salience -1))
	(oavc-m	(objeto ?paciente)
		(atributo diagnostico)
		(valor ?enfermedad)
		(factor ?f)
	)
=>
	(printout t " El paciente " ?paciente " puede padecer " ?enfermedad " con una certeza de " ?f "." crlf)
)