build.gradle

import com.github.jengelman.gradle.plugins.shadow.tasks.ConfigureShadowRelocation

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "com.gradle.publish:plugin-publish-plugin:0.9.1"
    }
}

plugins {
    id 'java'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '7.0.0'
}

apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: "com.gradle.plugin-publish"

group = 'com.github.ReplayMod'
version = '2.3-SNAPSHOT'
//version = '2.2.1'
archivesBaseName = 'ForgeGradle'
targetCompatibility = '16'
sourceCompatibility = '16'

repositories {
    mavenLocal()
    maven {
        name = "forge"
        url = "https://maven.minecraftforge.net"
    }
    maven {
        // because Srg2Source needs an eclipse dependency.
        name = "eclipse"
        url = "https://repo.eclipse.org/content/groups/eclipse/"
    }
    jcenter() // get as many deps from here as possible
    mavenCentral()

    // because SS and its snapshot
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/repositories/snapshots/"
    }


    // because of the GradleStart stuff
    maven {
        name = "mojang"
        url = "https://libraries.minecraft.net/"
    }

    maven { url = "https://jitpack.io" } // updated MCInjector
}

// The Side and SideOnly classes are injected into MC, so they must be compiled to Java 8 so Forge does not blow up.
sourceSets {
    side
}
tasks.named(sourceSets.side.compileJavaTaskName, JavaCompile.class).configure {
    sourceCompatibility '1.8'
    targetCompatibility '1.8'
}
jar {
    from(sourceSets.side.output)
}
shadowJar {
    from(sourceSets.side.output)
}

configurations {
    // compile has been replaced with api, re-adding to keep the diff small
    compile
    api.extendsFrom(compile)
    testCompile
    testImplementation.extendsFrom(testCompile)

    deployerJars
}

dependencies {
    shadow gradleApi()
    testImplementation gradleApi()

    shadow sourceSets.side.output

    compile 'org.ow2.asm:asm:6.0'
    compile 'org.ow2.asm:asm-tree:6.0'
    compile 'org.ow2.asm:asm-commons:6.0'

    // moved to the beginning to be the overrider
    //compile 'org.ow2.asm:asm-debug-all:6.0'
    compile 'com.google.guava:guava:18.0'

    compile 'net.sf.opencsv:opencsv:2.3' // reading CSVs.. also used by SpecialSource
    compile 'com.cloudbees:diff4j:1.1' // for difing and patching
    compile 'com.github.abrarsyed.jastyle:jAstyle:1.3' // formatting
    compile 'net.sf.trove4j:trove4j:2.1.0' // because its awesome.

    compile 'com.github.jponge:lzma-java:1.3' // replaces the LZMA binary
    compile 'com.nothome:javaxdelta:2.0.1' // GDIFF implementation for BinPatches
    compile 'com.google.code.gson:gson:2.2.4' // Used instead of Argo for buuilding changelog.
    compile 'com.github.tony19:named-regexp:0.2.3' // 1.7 Named regexp features
    compile 'net.minecraftforge:forgeflower:1.0.342-SNAPSHOT' // Fernflower Forge edition

    compile('net.md-5:SpecialSource:1.8.2'){
        exclude group: 'org.ow2.asm'
    } // deobf and reobf

    // because curse
    compile 'org.apache.httpcomponents:httpclient:4.3.3'
    compile 'org.apache.httpcomponents:httpmime:4.3.3'

    // mcp stuff
    compile 'de.oceanlabs.mcp:RetroGuard:3.6.6'
    compile('com.github.ModCoderPack:MCInjector:c36f39f'){
        exclude group: 'org.ow2.asm'
    }
    compile('net.minecraftforge.srg2source:Srg2Source:4.0-SNAPSHOT'){
        exclude group: 'org.ow2.asm'
        exclude group: 'org.eclipse.equinox', module: 'org.eclipse.equinox.common'
    }

    //Stuff used in the GradleStart classes
    compileOnly 'com.mojang:authlib:1.5.16'
    compileOnly('net.minecraft:launchwrapper:1.11'){
     exclude group: 'org.ow2.asm', module: 'asm-debug-all'
    }

    compileOnly "org.jetbrains.kotlin:kotlin-gradle-plugin:1.1.3-2"
    testCompile 'junit:junit:4.12'

    constraints {
        compile('org.eclipse.jdt:org.eclipse.jdt.core:3.12.3') {
            because 'Srg2Source depends on a snapshot version which the forge maven has stopped serving'
        }
    }
}

wrapper {
    gradleVersion = '7.0.2'
}

compileJava {
	options.deprecation = true
	//options.compilerArgs += ["-Werror"]
	//options.compilerArgs += ["-Werror", "-Xlint:unchecked"]
}

processResources {
    filesMatching(["forgegradle.version.txt"]) {
        expand 'version': project.version
    }
}

jar {
    manifest {
        attributes 'version':project.version
        attributes 'javaCompliance': project.targetCompatibility
        attributes 'group':project.group
        attributes 'Implementation-Version': project.version + getGitHash()
    }
}

javadoc {
	classpath += configurations.compileOnly

    // linked javadoc urls.. why not...
    options.addStringOption 'link', 'https://gradle.org/docs/current/javadoc/'
    options.addStringOption 'link', 'http://docs.guava-libraries.googlecode.com/git-history/v18.0/javadoc'
    options.addStringOption 'link', 'http://asm.ow2.org/asm50/javadoc/user/'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    from javadoc
    classifier = "javadoc"
}

artifacts {
    archives jar
    //archives javadocJar
}

test {
    if (project.hasProperty("filesmaven")) // disable this test when on the forge jenkins
        exclude "**/ExtensionMcpMappingTest*"
}

pluginBundle {
    website = 'http://www.gradle.org/'
    vcsUrl = 'https://github.com/MinecraftForge/ForgeGradle'
    description = 'Gradle plugin for all Minecraft mod development needs'
    tags = ['forge', 'minecraft', 'minecraftforge', 'sponge', 'mcp']

    plugins {
        patcher {
            id = 'net.minecraftforge.gradle.patcher'
            displayName = 'Minicraft Patcher Plugin'
        }
        tweakerClient {
            id = 'net.minecraftforge.gradle.tweaker-client'
            displayName = 'Mincraft Client Tweaker Plugin'
        }
        tweakerServer {
            id = 'net.minecraftforge.gradle.tweaker-server'
            displayName = 'Mincraft Server Tweaker Plugin'
        }
        forge {
            id = 'net.minecraftforge.gradle.forge'
            displayName = 'MincraftForge Mod Development Plugin'
        }

        launch4j {
            id = 'net.minecraftforge.gradle.launch4j'
            displayName = 'Specialized Launch4J Gradle Plugin'
        }
    }
}

task relocateShadowJar(type: ConfigureShadowRelocation) {
    target = tasks.shadowJar
    prefix = "fg_2_3"
}
tasks.shadowJar.dependsOn tasks.relocateShadowJar

publishing {
    publications {
        shadow(MavenPublication) { publication ->
            project.shadow.component(publication)
        }
    }
}

// write out version so its convenient for doc deployment
file('build').mkdirs()
file('build/version.txt').text = version;

def getGitHash() {
    def process = 'git rev-parse --short HEAD'.execute()
    process.waitFor()
    return '-' + (process.exitValue() ? 'unknown' : process.text.trim())
}