-
Notifications
You must be signed in to change notification settings - Fork 7
/
ECCO.jl
314 lines (249 loc) · 8.49 KB
/
ECCO.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
module ECCO
export ECCOMetadata, ecco_field, ecco_mask, adjusted_ecco_tracers, initialize!
export ECCO2Monthly, ECCO4Monthly, ECCO2Daily
export ECCO_restoring_forcing
using ClimaOcean.DataWrangling: inpaint_mask!
using ClimaOcean.InitialConditions: three_dimensional_regrid!, interpolate!
using Oceananigans
using Oceananigans.Architectures: architecture, child_architecture
using Oceananigans.BoundaryConditions
using Oceananigans.DistributedComputations: DistributedField, all_reduce, barrier!
using Oceananigans.Utils
using KernelAbstractions: @kernel, @index
using NCDatasets
using Downloads: download
using Dates
using Adapt
include("ecco_metadata.jl")
# Vertical coordinate
const ECCO_z = [
-6128.75,
-5683.75,
-5250.25,
-4839.75,
-4452.25,
-4087.75,
-3746.25,
-3427.75,
-3132.25,
-2859.75,
-2610.25,
-2383.74,
-2180.13,
-1999.09,
-1839.64,
-1699.66,
-1575.64,
-1463.12,
-1357.68,
-1255.87,
-1155.72,
-1056.53,
-958.45,
-862.10,
-768.43,
-678.57,
-593.72,
-515.09,
-443.70,
-380.30,
-325.30,
-278.70,
-240.09,
-208.72,
-183.57,
-163.43,
-147.11,
-133.45,
-121.51,
-110.59,
-100.20,
-90.06,
-80.01,
-70.0,
-60.0,
-50.0,
-40.0,
-30.0,
-20.0,
-10.0,
0.0,
]
empty_ecco_field(variable_name::Symbol; kw...) = empty_ecco_field(ECCOMetadata(variable_name); kw...)
function empty_ecco_field(metadata::ECCOMetadata;
architecture = CPU(),
horizontal_halo = (3, 3))
Nx, Ny, Nz, _ = size(metadata)
variable_name = metadata.name
location = field_location(metadata)
location = ecco_location[variable_name]
longitude = (0, 360)
latitude = (-90, 90)
TX, TY = (Periodic, Bounded)
if variable_is_three_dimensional(metadata)
z = ECCO_z
# add vertical halo for 3D fields
halo = (horizontal_halo..., 3)
LZ = Center
TZ = Bounded
N = (Nx, Ny, Nz)
else
z = nothing
halo = horizontal_halo
LZ = Nothing
TZ = Flat
N = (Nx, Ny)
end
# Flat in z if the variable is two-dimensional
grid = LatitudeLongitudeGrid(architecture; halo, size = N, topology = (TX, TY, TZ),
longitude, latitude, z)
return Field{location...}(grid)
end
"""
ecco_field(variable_name;
architecture = CPU(),
horizontal_halo = (1, 1),
user_data = nothing,
url = ecco_urls[variable_name],
filename = ecco_metadata_filenames[variable_name],
short_name = ecco_short_names[variable_name])
Retrieve the ecco field corresponding to `variable_name`.
The data is either:
(1) retrieved from `filename`,
(2) dowloaded from `url` if `filename` does not exists,
(3) filled from `user_data` if `user_data` is provided.
"""
function ecco_field(metadata::ECCOMetadata;
architecture = CPU(),
horizontal_halo = (3, 3),
filename = metadata_filename(metadata))
shortname = short_name(metadata)
download_dataset!(metadata)
ds = Dataset(filename)
if variable_is_three_dimensional(metadata)
data = ds[shortname][:, :, :, 1]
# The surface layer in three-dimensional ECCO fields is at `k = 1`
data = reverse(data, dims = 3)
else
data = ds[shortname][:, :, 1]
end
close(ds)
field = empty_ecco_field(metadata; architecture, horizontal_halo)
FT = eltype(field)
data[ismissing.(data)] .= 1e10 # Artificially large number!
data = if location(field)[2] == Face
new_data = zeros(FT, size(field))
new_data[:, 1:end-1, :] .= data
new_data
else
convert.(FT, data)
end
# ECCO4 data is on a -180, 180 longitude grid as opposed to ECCO2 data that
# is on a 0, 360 longitude grid. To make the data consistent, we shift ECCO4
# data by 180 degrees in longitude
if metadata.version isa ECCO4Monthly
Nx = size(data, 1)
data = circshift(data, (Nx ÷ 2, 0, 0))
end
set!(field, data)
fill_halo_regions!(field)
return field
end
# Fallback
ecco_field(var_name::Symbol; kw...) = ecco_field(ECCOMetadata(var_name); kw...)
@kernel function _set_ecco2_mask!(mask, Tᵢ, minimum_value, maximum_value)
i, j, k = @index(Global, NTuple)
@inbounds mask[i, j, k] = (Tᵢ[i, j, k] < minimum_value) | (Tᵢ[i, j, k] > maximum_value)
end
@kernel function _set_ecco4_mask!(mask, Tᵢ, args...)
i, j, k = @index(Global, NTuple)
@inbounds mask[i, j, k] = (Tᵢ[i, j, k] == 0)
end
@inline mask_kernel(version) = _set_ecco2_mask!
@inline mask_kernel(::ECCO4Monthly) = _set_ecco4_mask!
"""
ecco_mask(architecture = CPU(); minimum_value = Float32(-1e5))
A boolean field where `true` represents a missing value in the ECCO dataset.
"""
function ecco_mask(metadata, architecture = CPU();
minimum_value = Float32(-1e5),
maximum_value = Float32(1e5),
filename = metadata_filename(metadata))
field = ecco_field(metadata; architecture, filename)
mask = Field{location(field)...}(field.grid, Bool)
# ECCO4 has zeros in place of the missing values, while
# ECCO2 expresses missing values with values < -1e5
_set_mask! = mask_kernel(metadata.version)
# Set the mask with zeros where field is defined
launch!(architecture, field.grid, :xyz, _set_mask!, mask, field, minimum_value, maximum_value)
return mask
end
# Default
ecco_mask() = ecco_mask(ECCOMetadata(:temperature))
"""
inpainted_ecco_field(variable_name;
architecture = CPU(),
filename = "./inpainted_ecco_fields.nc",
mask = ecco_mask(architecture))
Retrieve the ECCO field corresponding to `variable_name` inpainted to fill all the
missing values in the original dataset.
Arguments:
==========
- `variable_name`: the variable name corresponding to the Dataset.
Keyword Arguments:
==================
- `architecture`: either `CPU()` or `GPU()`.
- `filename`: the path where to retrieve the data from. If the file does not exist,
the data will be downloaded from the ECCO dataset.
- `mask`: the mask used to inpaint the field (see `inpaint_mask!`).
- `maxiter`: the maximum number of iterations to inpaint the field (see `inpaint_mask!`).
"""
function inpainted_ecco_field(metadata::ECCOMetadata;
architecture = CPU(),
filename = metadata_filename(metadata),
mask = ecco_mask(metadata, architecture),
maxiter = Inf,
kw...)
f = ecco_field(metadata; architecture, filename, kw...)
# Make sure all values are extended properly
@info "In-painting ecco $(metadata.name)"
inpaint_mask!(f, mask; maxiter)
fill_halo_regions!(f)
return f
end
inpainted_ecco_field(variable_name::Symbol; kw...) = inpainted_ecco_field(ECCOMetadata(variable_name); kw...)
function set!(field::DistributedField, ecco_metadata::ECCOMetadata; kw...)
# Fields initialized from ECCO
grid = field.grid
arch = architecture(grid)
child_arch = child_architecture(arch)
f_ecco = if arch.local_rank == 0 # Make sure we read/write the file using only one core
mask = ecco_mask(ecco_metadata, child_arch)
inpainted_ecco_field(ecco_metadata; mask,
architecture = child_arch,
kw...)
else
empty_ecco_field(ecco_metadata; architecture = child_arch)
end
barrier!(arch)
# Distribute ecco field to all workers
parent(f_ecco) .= all_reduce(+, parent(f_ecco), arch)
f_grid = Field(field_location(ecco_metadata), grid)
interpolate!(f_grid, f_ecco)
set!(field, f_grid)
return field
end
function set!(field::Field, ecco_metadata::ECCOMetadata; kw...)
# Fields initialized from ECCO
grid = field.grid
mask = ecco_mask(ecco_metadata, architecture(grid))
f = inpainted_ecco_field(ecco_metadata; mask,
architecture = architecture(grid),
kw...)
f_grid = Field(field_location(ecco_metadata), grid)
interpolate!(f_grid, f)
set!(field, f_grid)
return field
end
include("ecco_restoring.jl")
end # Module