-
Notifications
You must be signed in to change notification settings - Fork 0
/
Main.asm
1187 lines (1069 loc) · 25.4 KB
/
Main.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; ===============
; Bounced trainer
; ===============
; Defines
include "Defines.inc"
include "Trainer.inc"
; ===========
; Reset vectors
; ===========
if !def(nogame)
section "Reset 00",rom0[$0]
Reset00:
ret ; wtf? if this is all Reset00 is why is it called by GameStart?
ds $10-@,0
section "GBDK thumbprint",rom0[$10]
GBDKThumbprint:
db $80,$40,$20,$10,$08,$04,$02,$01,$01,$02,$04,$08,$10,$20,$40,$80
ds $40-@,0
endc
; ================================================================
; ==================
; Interrupt handlers
; ==================
section "VBlank IRQ",rom0[$40]
IRQ_VBlank::
jp DoVBlank
ds $48-@,0
section "STAT IRQ",rom0[$48]
IRQ_STAT::
jp DoScanline
ds $50-@,0
if !def(nogame)
section "Timer IRQ",rom0[$50]
IRQ_Timer::
push hl
ld hl,$c0c6
jp DoInterrupt
ds $58-@,0
section "Serial IRQ",rom0[$58]
IRQ_Serial::
push hl
ld hl,$c0d6
jp DoInterrupt
ds $60-@,0
section "Joypad IRQ",rom0[$60]
IRQ_Joypad::
push hl
ld hl,$c0e6
jp DoInterrupt ; wtf?
DoInterrupt:
push af
push bc
push de
.loop
ld a,[hl+]
or [hl]
jr z,.skipint
push hl
ld a,[hl-]
ld l,[hl]
ld h,a
call Sys_JPHL
pop hl
inc hl
jr .loop
.skipint
pop de
pop bc
pop af
pop hl
reti
Sys_JPHL:
jp hl
ds $100-@,0
endc
; ================================================================
section "ROM header",rom0[$100]
EntryPoint::
nop
jp ProgramStart
NintendoLogo: ; DO NOT MODIFY OR ROM WILL NOT BOOT!!!
db $ce,$ed,$66,$66,$cc,$0d,$00,$0b,$03,$73,$00,$83,$00,$0c,$00,$0d
db $00,$08,$11,$1f,$88,$89,$00,$0e,$dc,$cc,$6e,$e6,$dd,$dd,$d9,$99
db $bb,$bb,$67,$63,$6e,$0e,$ec,$cc,$dd,$dc,$99,$9f,$bb,$b9,$33,$3e
ROMTitle: db "BOUNCED! AUDP" ; ROM title (15 chars)
GBCSupport: db $C0 ; GBC support (0 = DMG only, $80 = DMG/GBC, $C0 = GBC only)
NewLicenseCode: db "6N" ; new license code (2 bytes)
SGBSupport: db 0 ; SGB support
CartType: db $19 ; Cart type, see hardware.inc for a list of values
ROMSize: db $05 ; ROM size (handled by post-linking tool)
RAMSize: db $00 ; RAM size
DestCode: db $01 ; Destination code (0 = Japan, 1 = All others)
OldLicenseCode: db $33 ; Old license code (if $33, check new license code)
ROMVersion: db $00 ; ROM version
HeaderChecksum: db ; Header checksum (handled by post-linking tool)
ROMChecksum: dw ; ROM checksum (2 bytes) (handled by post-linking tool)
; ================================================================
if !def(nogame)
GameStart:
di
ld d,a
xor a
ld sp,$e000
ld hl,$dfff
ld c,$20
.clrRAM_loop
ld [hl-],a
dec b
jr nz,.clrRAM_loop
dec c
jr nz,.clrRAM_loop
ld hl,$feff
ld b,0
.clrOAM_loop:
ld [hl-],a
dec b
jr nz,.clrOAM_loop
; clear HRAM routine removed
; register init
ld a,d
ld [GBCFlag],a
call DisableLCD
xor a
ldh [rSCY],a
ldh [rSCX],a
ldh [rSTAT],a ; wtf?
ldh [rWY],a
ld a,7
ldh [rWX],a
; copy OAM DMA routine
ld bc,$ff80
ld hl,_OAMDMA2
ld b,_OAMDMASize
.copyOAMDMALoop
ld a,[hl+]
ld [c],a
inc c
dec b
jr nz,.copyOAMDMALoop
ld bc,UnkTable0248
call Unk_020D
ld bc,UnkTable0283
call Unk_021F
ld a,%11100100 ; 3 2 1 0
ldh [rBGP],a ; DMG background palette
ld [rOBP0],a ; DMG object palette 1
ld a,%00011011 ; 0 1 2 3
ldh [rOBP1],a ; DMG object palette 2
ld a,LCDCF_ON|LCDCF_WIN9C00
ldh [rLCDC],a ; enable LCD + window address $9C00 (wtf?)
xor a
ldh [rIF],a ; wtf?
ld a,IEF_VBLANK|IEF_SERIAL
ldh [rIE],a ; enable VBlank + serial (wtf?) interrupts
xor a ; wtf?
ldh [rNR52],a ; disable sound output
ldh [rSC],a ; disable link port
ld a,$66
ldh [rSB],a ; wtf?
ld a,%10000000
ldh [rSC],a ; wtf?
call Reset00 ; wtf?
ei
call GameInit
.trap jr .trap
ds $1e0-@,0
section "lonely ret",rom0[$1e0]
LonelyRet:
ret
ds $200-@,0
incbin "bounced.gbc",$200,$32b3-@
CreditsPatch: db $a0 ; fixes game freeze on clearing level 31
incbin "bounced.gbc",$32b4,$39d9-@
endc
; ================================================================
if !def(nogame)
section "Trainer + intro code",rom0[$39d9]
else
section "Trainer + intro code",rom0[$150]
endc
ProgramStart::
cp $11
if !def(nogame)
jr z,.notdmg
jp GameStart
else
jr nz,@
endc
.notdmg
di
push af
ld e,0
ld hl,$c000
ld bc,$2000
call _FillRAM
ld bc,$7c80
.loop
ldh [c],a
inc c
dec b
jr nz,.loop
dec a ; a = $ff
ld [Intro_MenuLast],a
pop af
ld [Intro_GBCFlag],a
ld a,%10000000
ldh [TrainerFlags],a
ld bc,(_OAMDMA_End-_OAMDMA)<<8|low(OAMDMA)
ld hl,_OAMDMA
.copyloop
ld a,[hl+]
ld [c],a
inc c
dec b
jr nz,.copyloop
xor a
ldh [rLCDC],a ; disable LCD
call DoubleSpeed
ld e,$ff
ld hl,$9800
ld bc,$400
call _FillRAM
ld a,1
ldh [rVBK],a
ld a,bank(GFX1)
ld [rROMB0],a
ld hl,Font
ld de,$9200
call DecodeWLE
xor a
ldh [rVBK],a
ld hl,Font
ld de,$8000
call DecodeWLE
ld hl,CapitalLogoTiles
ld de,$9000
call DecodeWLE
ld hl,Pal_CapitalLogo
xor a
call LoadPal
ld hl,Pal_Trainer
ld a,3
call LoadPal
inc a
call LoadPal
inc a
call LoadPal
inc a
call LoadPal
inc a
call LoadPal
inc a
call LoadPal
ld hl,CapitalLogoMap
ld bc,$0414
ld de,$9800
push bc
push de
call LoadMap
ld a,IEF_VBLANK|IEF_LCDC
ldh [rIE],a
ld a,8
ldh [rLYC],a ; LY compare = 0
xor %01000000
ldh [rSTAT],a ; enable LYC interrupt
ld a,7
ldh [rWX],a
ld a,104
ldh [rWY],a
ld hl,str_InfiniteLives
wline 0
ld c,3
call PrintString
ld hl,str_InfiniteTime
wline 1
inc c
call PrintString
ld hl,str_LevelSkip
wline 2
inc c
call PrintString
ld hl,str_SuperJump
wline 3
inc c
call PrintString
ld hl,str_NoStick
wline 4
inc c
call PrintString
ld hl,str_Marquee1+1
ld c,3
line 12
call PrintString
ld hl,$9C00
WaitForVRAM
ld [hl],">"
ld a,bank(MusicData)
ld [rROMB0],a
call Carillon_Init
call Carillon_Load
ld a,LCDCF_ON|LCDCF_WIN9C00|LCDCF_BG8800|LCDCF_OBJON|LCDCF_BGON|LCDCF_WINON
ldh [rLCDC],a
ld a,192
ld [MarqueeTimer],a
xor a
ld [MarqueePos],a
inc a
ld [MarqueeMessage],a
ld a,8
ld [ScrollerOffset],a
xor a
ld [Intro_RedBuffer+94],a
ld a,15
ld [Intro_GreenBuffer+94],a
ld a,31
ld [Intro_BlueBuffer+94],a
ei
Intro_MainLoop::
call CheckInput
ld a,[sys_btnPress]
bit btnStart,a
jp nz,ExitIntro
bit btnUp,a
jr nz,.cursorup
bit btnDown,a
jr nz,.cursordown
bit btnA,a
jr z,.done
.togglecheat
ld a,[Intro_MenuItem]
ld hl,Intro_Cheatmask
add l
ld l,a
ld a,[hl]
ld b,a
ld a,[TrainerFlags]
xor b
ld [TrainerFlags],a
jr .done
.cursorup
ld a,[Intro_MenuItem]
ld b,a
dec a
cp -1
jr nz,.setcursor
ld a,Intro_MenuMax-1
jr .setcursor
.cursordown
ld a,[Intro_MenuItem]
ld b,a
inc a
cp Intro_MenuMax
jr c,.setcursor
xor a
; fall through
.setcursor
ld [Intro_MenuItem],a
call Intro_GetCursorPos
WaitForVRAM
ld [hl],">"
ld a,b
ld [Intro_MenuLast],a
call Intro_GetCursorPos
WaitForVRAM
ld [hl]," "
.done
Menu_DrawYN::
; draw Y/N
ld a,[TrainerFlags]
ld hl,$9C12
ld de,$0020
ld b,5
.loop
rra
ld c,a
jr nc,.no
WaitForVRAM
ld [hl],"Y"
jr .next
.no
WaitForVRAM
ld [hl],"N"
.next
add hl,de
ld a,c
dec b
jr nz,.loop
ld a,bank(MusicData)
ld [rROMB0],a
call Carillon_Play
; run marquee
ld a,[MarqueeTimer]
cp $ff
jr z,.skip
dec a
ld [MarqueeTimer],a
jr c,.waitvbl
.skip
ld a,[MarqueePos]
add 2
bit 7,a
jr z,.noreset
xor a
ld [MarqueePos],a
ld [MarqueeScroll],a
ld a,192
ld [MarqueeTimer],a
ld a,[MarqueeMessage]
inc a
and 7
ld [MarqueeMessage],a
jr .waitvbl
.noreset
ld [MarqueePos],a
ld e,a
ld a,bank(MarqueeScrollTable)
ld [rROMB0],a
ld h,high(MarqueeScrollTable)
ld l,e
ld a,[hl]
ld [MarqueeScroll],a
; update marquee string
rra ; /2
rra ; /4
rra ; /8
and $1f
ld c,a
line 12
add e
dec a
ld e,a
ld hl,MarqueeMessageTable
ld a,[MarqueeMessage]
add a
add l
ld l,a
ld a,[hl+]
ld h,[hl]
add c
jr nc,.nocarry
inc h
.nocarry
ld l,a
WaitForVRAM
ld a,[hl]
ld [de],a
.waitvbl
halt
ldh a,[rLY]
cp 144
jr nz,.waitvbl
call DoScroller
ld a,bank(ColorBarTable)
ld [rROMB0],a
ld de,Intro_RedBuffer
ld a,[sys_CurrentFrame]
and 63
ld h,high(ColorBarTable)
ld l,a
ld b,93
call .colorloop
ld de,Intro_GreenBuffer
ld a,[sys_CurrentFrame]
rra
and 63
ld l,a
ld b,93
call .colorloop
ld de,Intro_BlueBuffer
ld a,[sys_CurrentFrame]
cpl
and 63
ld l,a
ld b,93
call .colorloop
call OAMDMA
jp Intro_MainLoop
.colorloop
ld a,[hl+]
ld [de],a
inc e
ld a,l
and 63
ld l,a
dec b
jr nz,.colorloop
ret
Intro_GetCursorPos:
ld l,a
ld h,0
add hl,hl ; x2
add hl,hl ; x4
add hl,hl ; x8
add hl,hl ; x16
add hl,hl ; x32
ld de,$9C00
add hl,de
ret
ExitIntro::
ld a,IEF_VBLANK
ldh [rIE],a
halt
xor a
ldh [rLCDC],a
ld a,bank(MusicData)
ld [rROMB0],a
call Carillon_Stop
call NormalSpeed
; init routine doesn't clear VRAM so do that here
ld a,1
ldh [rVBK],a
ld e,0
ld hl,$8000
ld bc,$2000
call _FillRAM
xor a
ldh [rVBK],a
ld e,0
ld hl,$8000
ld bc,$2000
call _FillRAM
ld a,bank(GFX1)
ld [rROMB0],a
ld hl,Pal_Blank
xor a
call LoadPal ; only first line is needed
ld hl,TrainerFlags
res 7,[hl]
; simulate initial boot rom exit register state
; not sure exactly how much of this is actually required for
; a clean boot, but better safe than sorry
ld bc,$1180
push bc
pop af ; evil hack to write to write to f
ld bc,$0000 ; note: inaccurate on GBA
ld de,$ff56
ld hl,$000d
ld sp,$fffe
if !def(nogame)
jp GameStart
else
jp ProgramStart
endc
; ================================================================
; INPUT: hl = pointer
; de = destination
PrintString:
xor a
ldh [rVBK],a
WaitForVRAM
ld a,[hl+]
and a
ret z
ld [de],a
ld a,1
ldh [rVBK],a
WaitForVRAM
ld a,c
or %00001000
ld [de],a
inc de
jr PrintString
; ================================================================
; =================
; Scroller routines
; =================
DoScroller:
ld a,bank(ScrollText)
ld [rROMB0],a
ld hl,ScrollerPos
push hl
ld a,[hl+]
ld h,[hl]
ld l,a
ld a,h
cp high(ScrollTextSize)
jr nz,.skip3
ld a,l
cp low(ScrollTextSize)
jr nz,.skip3
xor a
ld [ScrollerPos],a
ld [ScrollerPos+1],a
; fall through
.skip3
ld a,[ScrollerOffset]
dec a
jr nz,.skip2
pop hl
ld a,[hl+]
ld b,[hl]
ld c,a
inc bc
ld a,b
ld h,b
ld [ScrollerPos+1],a
ld a,c
ld l,c
ld [ScrollerPos],a
ld a,8
ld [ScrollerOffset],a
jr .skip
.skip2
ld [ScrollerOffset],a
pop hl
ld a,[hl+]
ld h,[hl]
ld l,a
.skip
ld bc,ScrollText
add hl,bc
ld de,SpriteBuffer
ld b,21
.loop
; sprite Y pos
push hl
push bc
ld a,b
dec a
add a
add a
add a
ld b,a
ld a,[ScrollerOffset]
ld c,a
ld a,[sys_CurrentFrame]
sub c
add b
pop bc
ld h,high(ScrollerSineTable)
ld l,a
ld a,[hl]
add 16
ld [de],a
inc e
; sprite x pos
ld a,21
sub b
add a ; x2
add a ; x4
add a ; x8
ld l,a
ld a,[ScrollerOffset]
add l
dec a
ld [de],a
inc e
; tile number
pop hl
ld a,[hl+]
sub 32
ld [de],a
inc e
; attributes
xor a
ld [de],a
inc e
dec b
jr nz,.loop
ret
; ================================================================
DoVBlank::
push af
if !def(nogame)
ldh a,[TrainerFlags]
bit IntroRunning,a
jr nz,.intro
call DoTrainer
pop af
push hl
ld hl,$c0a6
jp DoInterrupt
endc
.intro
push hl
ld hl,sys_CurrentFrame
inc [hl]
; do marquee
ld a,[MarqueeScroll]
ldh [rSCX],a
ld a,96
ldh [rSCY],a
ld a,bank(Pal_Blank)
ld [rROMB0],a
xor a
LRGB 0, 7,15
call SetColor
ld a,1
ld [sys_VBlankFlag],a
ld a,6
ldh [rLYC],a
pop hl
pop af
reti
DoScanline::
push af
if !def(nogame)
ldh a,[TrainerFlags]
bit IntroRunning,a
jr nz,.intro
pop af
push hl
ld hl,$c0b6
jp DoInterrupt
endc
.intro
push bc
push de
push hl
ldh a,[rLY]
cp 7
jr c,.exit
cp 144-40
jr nc,.exit
.top
sub 8
ld l,a
ld h,high(Intro_BlueBuffer)
ld c,[hl]
ld h,high(Intro_GreenBuffer)
ld b,[hl]
ld h,high(Intro_RedBuffer)
ld a,[hl]
call CombineColors
xor a
call SetColor
ld hl,rLYC
inc [hl]
xor a
ldh [rSCX],a
ld a,bank(LogoBounce)
ld [rROMB0],a
ld h,high(LogoBounce)
ld a,[sys_CurrentFrame]
and $7f
ld l,a
ld a,[hl]
ldh [rSCY],a
; fall through
.exit
pop hl
pop de
pop bc
pop af
reti
; ================================================================
CheckInput:
push bc
ld a,P1F_5
ld [rP1],a
ld a,[rP1]
ld a,[rP1]
cpl
and a,$f
swap a
ld b,a
ld a,P1F_4
ld [rP1],a
ld a,[rP1]
ld a,[rP1]
ld a,[rP1]
ld a,[rP1]
ld a,[rP1]
ld a,[rP1]
cpl
and a,$f
or a,b
ld b,a
ld a,[sys_btnHold]
xor a,b
and a,b
ld [sys_btnPress],a
ld a,b
ld [sys_btnHold],a
ld a,P1F_5|P1F_4
ld [rP1],a
pop bc
ret
; ================================================================
LoadMap:
ld a,c
ld [Intro_MapTemp],a
xor a
ld [Intro_MapTemp2],a
ld de,$9800
.loop
ld a,[hl+]
ld [de],a
inc de
dec c
jr nz,.loop
dec b
ret z
ld de,$9800
push hl
ld h,0
ld a,[Intro_MapTemp2]
inc a
ld [Intro_MapTemp2],a
ld l,a
add hl,hl ; x2
add hl,hl ; x4
add hl,hl ; x8
add hl,hl ; x16
add hl,hl ; x32
add hl,de
ld d,h
ld e,l
pop hl
ld a,[Intro_MapTemp]
ld c,a
jr .loop
_FillRAM::
ld a,e
ld [hl+],a
dec bc
ld a,b
or c
jr nz,_FillRAM
ret
; needed by WLE decoder
_CopyRAM::
ld a,[hl+]
ld [de],a
inc de
dec bc
ld a,b
or c
jr nz,_CopyRAM
ret
; needed by WLE decoder
_CopyRAMSmall::
ld a,[hl+]
ld [de],a
inc de
dec b
jr nz,_CopyRAMSmall
ret
include "WLE_Decode.asm"
include "GBCPal.asm"
; ================================================================
if !def(nogame)
DoTrainer::
push hl
ldh a,[TrainerFlags]
rra
call c,.infinitelives
rra
call c,.infinitetime
rra
call c,.levelskip
rra
call c,.superjump
rra
call c,.nostick
pop hl
ret
.infinitelives
ld hl,Lives
ld [hl],3
ret
.infinitetime
ld hl,Time
ld [hl],99
ret
.levelskip
push af
call Joypad
bit btnSelect+4,a
jr z,.nolevelskip
ld hl,LevelClearFlag
ld [hl],1
.nolevelskip
pop af
ret
.superjump
push af
call Joypad
bit btnB+4,a
jr z,.nosuperjump
ld hl,MaxJump
ld [hl],$7f
.nosuperjump
pop af
ret
.nostick
ld hl,StickTimer
ld [hl],$1f
ret
endc
; ================================================================
DoubleSpeed:
ldh a,[rKEY1]
bit 7,a ; already in double speed?
ret nz ; if yes, return
jr DoSpeedSwitch
NormalSpeed:
ldh a,[rKEY1]
bit 7,a ; already normal speed
ret z ; if yes, return
; fall through
DoSpeedSwitch:
ld a,%00110000
ldh [rP1],a
xor %00110001 ; a = %00000000
ldh [rKEY1],a ; prepare speed switch
stop
ret
; ================================================================