build.gradle

buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

plugins {
    id "com.matthewprenger.cursegradle" version "1.0.9"
}

apply plugin: 'net.minecraftforge.gradle.forge'

ext.configFile = file "build.properties"
configFile.withReader {
    // Load config. It shall from now be referenced as simply config or project.config
    def prop =  new Properties()
    prop.load(it)
    project.ext.config = new ConfigSlurper().parse prop
}

version = config.minecraft_version + "-" + config.mod_version
group = "com.indemnity83.irontanks"
archivesBaseName = "irontanks"

sourceCompatibility = targetCompatibility = config.java_compatability
compileJava {
    sourceCompatibility = targetCompatibility = config.java_compatability
}

minecraft {
    version = config.minecraft_version + "-" + config.forge_version
    mappings = config.mappings
    runDir = "run"

    // Try appending the github sha first
    if (System.getenv("GITHUB_SHA") != null) {
        project.version += "+${System.getenv("GITHUB_SHA").substring(0,7)}"

    // If that doesn't work, just append "SNAPSHOT"
    } else {
        project.version += "+SNAPSHOT"
    }

    // replacing stuff in the source
    replace "\${version}", project.version
    replace "\${mcversion}", version
    // Replace @Mod.acceptedMinecraftVersions specially as it has to be a valid version in a dev environment :/
    replace "(gradle_replace_mcversion,)", "[" + version + "]"
    replace "(gradle_replace_forgeversion,)", "[" + config.forge_version + ",)"
    replace "(gradle_replace_buildcraftversion,)", "[" + config.buildcraft_version + ",)"
}

curseforge {
    apiKey = System.getenv("CURSE_API_KEY") ?: 'no-key'
    project {
        id = '236226'
        releaseType = 'release'
        changelog = ''
        relations {
            requiredLibrary 'buildcraft'
        }
    }
}

repositories {
    maven {
        name "BuildCraft"
        url "http://www.mod-buildcraft.com/maven"
    }
}

dependencies {
    deobfCompile "com.mod-buildcraft:buildcraft:" + config.buildcraft_version
}

processResources
{
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'

        // replace version and mcversion
        // ${version}   and    ${mcversion}    are the exact strings being replaced
        expand "version":project.version, "mcversion":project.minecraft.version
    }

    // copy everything else, that's not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}