-
Notifications
You must be signed in to change notification settings - Fork 51
/
validation.jl
338 lines (295 loc) · 12.1 KB
/
validation.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
# validation of properties and code
export InvalidIRError
# TODO: upstream
function method_matches(@nospecialize(tt::Type{<:Tuple}); world::Integer)
methods = Core.MethodMatch[]
matches = Base._methods_by_ftype(tt, -1, world)
matches === nothing && return methods
for match in matches::Vector
push!(methods, match::Core.MethodMatch)
end
return methods
end
function typeinf_type(mi::MethodInstance; interp::CC.AbstractInterpreter)
ty = Core.Compiler.typeinf_type(interp, mi.def, mi.specTypes, mi.sparam_vals)
return something(ty, Any)
end
function check_method(@nospecialize(job::CompilerJob))
ft = job.source.specTypes.parameters[1]
ft <: Core.Builtin && error("$(unsafe_function_from_type(ft)) is not a generic function")
for sparam in job.source.sparam_vals
if sparam isa TypeVar
throw(KernelError(job, "method captures typevar '$sparam' (you probably use an unbound type variable)"))
end
end
# kernels can't return values
if job.config.kernel
rt = typeinf_type(job.source; interp=get_interpreter(job))
if rt != Nothing && rt != Union{}
throw(KernelError(job, "kernel returns a value of type `$rt`",
"""Make sure your kernel function ends in `return`, `return nothing` or `nothing`."""))
end
end
return
end
# The actual check is rather complicated
# and might change from version to version...
function hasfieldcount(@nospecialize(dt))
try
fieldcount(dt)
catch
return false
end
return true
end
function explain_nonisbits(@nospecialize(dt), depth=1; maxdepth=10)
dt===Module && return "" # work around JuliaLang/julia#33347
depth > maxdepth && return ""
hasfieldcount(dt) || return ""
msg = ""
for (ft, fn) in zip(fieldtypes(dt), fieldnames(dt))
if !isbitstype(ft)
msg *= " "^depth * ".$fn is of type $ft which is not isbits.\n"
msg *= explain_nonisbits(ft, depth+1)
end
end
return msg
end
function check_invocation(@nospecialize(job::CompilerJob))
sig = job.source.specTypes
ft = sig.parameters[1]
tt = Tuple{sig.parameters[2:end]...}
Base.isdispatchtuple(tt) || error("$tt is not a dispatch tuple")
# make sure any non-isbits arguments are unused
real_arg_i = 0
for (arg_i,dt) in enumerate(sig.parameters)
isghosttype(dt) && continue
Core.Compiler.isconstType(dt) && continue
real_arg_i += 1
# XXX: can we support these for CPU targets?
if dt <: Core.OpaqueClosure
throw(KernelError(job, "passing an opaque closure",
"""Argument $arg_i to your kernel function is an opaque closure.
This is a CPU-only object not supported by GPUCompiler."""))
end
if !isbitstype(dt)
throw(KernelError(job, "passing non-bitstype argument",
"""Argument $arg_i to your kernel function is of type $dt, which is not a bitstype:
$(explain_nonisbits(dt))
Only bitstypes, which are "plain data" types that are immutable
and contain no references to other values, can be used in GPU kernels.
For more information, see the `Base.isbitstype` function."""))
end
end
return
end
## IR validation
const IRError = Tuple{String, StackTraces.StackTrace, Any} # kind, bt, meta
struct InvalidIRError <: Exception
job::CompilerJob
errors::Vector{IRError}
end
const RUNTIME_FUNCTION = "call to the Julia runtime"
const UNKNOWN_FUNCTION = "call to an unknown function"
const POINTER_FUNCTION = "call through a literal pointer"
const CCALL_FUNCTION = "call to an external C function"
const LAZY_FUNCTION = "call to a lazy-initialized function"
const DELAYED_BINDING = "use of an undefined name"
const DYNAMIC_CALL = "dynamic function invocation"
function Base.showerror(io::IO, err::InvalidIRError)
print(io, "InvalidIRError: compiling ", err.job.source, " resulted in invalid LLVM IR")
for (kind, bt, meta) in err.errors
printstyled(io, "\nReason: unsupported $kind"; color=:red)
if meta !== nothing
if kind == RUNTIME_FUNCTION || kind == UNKNOWN_FUNCTION || kind == POINTER_FUNCTION || kind == DYNAMIC_CALL || kind == CCALL_FUNCTION || kind == LAZY_FUNCTION
printstyled(io, " (call to ", meta, ")"; color=:red)
elseif kind == DELAYED_BINDING
printstyled(io, " (use of '", meta, "')"; color=:red)
end
end
Base.show_backtrace(io, bt)
end
println(io)
printstyled(io, "Hint"; bold = true, color = :cyan)
printstyled(
io,
": catch this exception as `err` and call `code_typed(err; interactive = true)` to",
" introspect the erronous code with Cthulhu.jl";
color = :cyan,
)
return
end
function check_ir(job, args...)
errors = check_ir!(job, IRError[], args...)
unique!(errors)
if !isempty(errors)
throw(InvalidIRError(job, errors))
end
return
end
function check_ir!(job, errors::Vector{IRError}, mod::LLVM.Module)
for f in functions(mod)
check_ir!(job, errors, f)
end
# custom validation
append!(errors, validate_ir(job, mod))
return errors
end
function check_ir!(job, errors::Vector{IRError}, f::LLVM.Function)
for bb in blocks(f), inst in instructions(bb)
if isa(inst, LLVM.CallInst)
check_ir!(job, errors, inst)
elseif isa(inst, LLVM.LoadInst)
check_ir!(job, errors, inst)
end
end
return errors
end
const libjulia = Ref{Ptr{Cvoid}}(C_NULL)
function check_ir!(job, errors::Vector{IRError}, inst::LLVM.LoadInst)
bt = backtrace(inst)
src = operands(inst)[1]
if src isa ConstantExpr
if opcode(src) == LLVM.API.LLVMBitCast
src = operands(src)[1]
end
end
if src isa GlobalVariable
name = LLVM.name(src)
if startswith(name, "jlplt_")
try
rx = r"jlplt_(.*)_\d+_got"
name = match(rx, name).captures[1]
push!(errors, (LAZY_FUNCTION, bt, name))
catch e
@safe_debug "Decoding name of PLT entry failed" inst bb=LLVM.parent(inst)
push!(errors, (LAZY_FUNCTION, bt, nothing))
end
end
end
return errors
end
function check_ir!(job, errors::Vector{IRError}, inst::LLVM.CallInst)
bt = backtrace(inst)
dest = called_operand(inst)
if isa(dest, LLVM.Function)
fn = LLVM.name(dest)
# some special handling for runtime functions that we don't implement
if fn == "jl_get_binding_or_error" || fn == "ijl_get_binding_or_error"
try
m, sym = arguments(inst)
sym = first(operands(sym::ConstantExpr))::ConstantInt
sym = convert(Int, sym)
sym = Ptr{Cvoid}(sym)
sym = Base.unsafe_pointer_to_objref(sym)
push!(errors, (DELAYED_BINDING, bt, sym))
catch e
@safe_debug "Decoding arguments to jl_get_binding_or_error failed" inst bb=LLVM.parent(inst)
push!(errors, (DELAYED_BINDING, bt, nothing))
end
elseif fn == "jl_reresolve_binding_value_seqcst" || fn == "ijl_reresolve_binding_value_seqcst"
try
# pry the binding from the IR
expr = arguments(inst)[1]::ConstantExpr
expr = first(operands(expr))::ConstantInt # get rid of inttoptr
ptr = Ptr{Any}(convert(Int, expr))
obj = Base.unsafe_pointer_to_objref(ptr)
push!(errors, (DELAYED_BINDING, bt, obj.globalref))
catch e
@safe_debug "Decoding arguments to jl_reresolve_binding_value_seqcst failed" inst bb=LLVM.parent(inst)
push!(errors, (DELAYED_BINDING, bt, nothing))
end
elseif fn == "jl_invoke" || fn == "ijl_invoke"
try
f, args, nargs, meth = arguments(inst)
meth = first(operands(meth::ConstantExpr))::ConstantInt
meth = convert(Int, meth)
meth = Ptr{Cvoid}(meth)
meth = Base.unsafe_pointer_to_objref(meth)::Core.MethodInstance
push!(errors, (DYNAMIC_CALL, bt, meth.def))
catch e
@safe_debug "Decoding arguments to jl_invoke failed" inst bb=LLVM.parent(inst)
push!(errors, (DYNAMIC_CALL, bt, nothing))
end
elseif fn == "jl_apply_generic" || fn == "ijl_apply_generic"
try
f, args, nargs = arguments(inst)
f = first(operands(f))::ConstantInt # get rid of inttoptr
f = convert(Int, f)
f = Ptr{Cvoid}(f)
f = Base.unsafe_pointer_to_objref(f)
push!(errors, (DYNAMIC_CALL, bt, f))
catch e
@safe_debug "Decoding arguments to jl_apply_generic failed" inst bb=LLVM.parent(inst)
push!(errors, (DYNAMIC_CALL, bt, nothing))
end
elseif fn == "jl_load_and_lookup" || fn == "ijl_load_and_lookup"
try
f_lib, f_name, hnd = arguments(inst)
f_name = first(operands(f_name))::GlobalVariable # get rid of the GEP
name_init = LLVM.initializer(f_name)::ConstantDataSequential
name_value = map(collect(name_init)) do char
convert(UInt8, char)
end |> String
name_value = name_value[1:end-1] # remove trailing \0
push!(errors, (CCALL_FUNCTION, bt, name_value))
catch e
@safe_debug "Decoding arguments to jl_load_and_lookup failed" inst bb=LLVM.parent(inst)
push!(errors, (CCALL_FUNCTION, bt, nothing))
end
# detect calls to undefined functions
elseif isdeclaration(dest) && !LLVM.isintrinsic(dest) && !isintrinsic(job, fn)
# figure out if the function lives in the Julia runtime library
if libjulia[] == C_NULL
paths = filter(Libdl.dllist()) do path
name = splitdir(path)[2]
startswith(name, "libjulia")
end
libjulia[] = Libdl.dlopen(first(paths))
end
if Libdl.dlsym_e(libjulia[], fn) != C_NULL
push!(errors, (RUNTIME_FUNCTION, bt, LLVM.name(dest)))
else
push!(errors, (UNKNOWN_FUNCTION, bt, LLVM.name(dest)))
end
end
elseif isa(dest, InlineAsm)
# let's assume it's valid ASM
elseif isa(dest, ConstantExpr)
# detect calls to literal pointers
if opcode(dest) == LLVM.API.LLVMIntToPtr
# extract the literal pointer
ptr_arg = first(operands(dest))
@compiler_assert isa(ptr_arg, ConstantInt) job
ptr_val = convert(Int, ptr_arg)
ptr = Ptr{Cvoid}(ptr_val)
if !valid_function_pointer(job, ptr)
# look it up in the Julia JIT cache
frames = ccall(:jl_lookup_code_address, Any, (Ptr{Cvoid}, Cint,), ptr, 0)
# XXX: what if multiple frames are returned? rare, but happens
if length(frames) == 1
fn, file, line, linfo, fromC, inlined = last(frames)
push!(errors, (POINTER_FUNCTION, bt, fn))
else
push!(errors, (POINTER_FUNCTION, bt, nothing))
end
end
end
end
return errors
end
# helper function to check for illegal values in an LLVM module
function check_ir_values(mod::LLVM.Module, predicate, msg="value")
errors = IRError[]
for fun in functions(mod), bb in blocks(fun), inst in instructions(bb)
if predicate(inst) || any(predicate, operands(inst))
bt = backtrace(inst)
push!(errors, (msg, bt, inst))
end
end
return errors
end
## shorthand to check for illegal value types
function check_ir_values(mod::LLVM.Module, T_bad::LLVMType)
check_ir_values(mod, val -> value_type(val) == T_bad, "use of $(string(T_bad)) value")
end