-
Notifications
You must be signed in to change notification settings - Fork 414
/
mvnormal.jl
375 lines (301 loc) · 11.7 KB
/
mvnormal.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
# Multivariate Normal distribution
###########################################################
#
# Abstract base class for multivariate normal
#
# Each subtype should provide the following methods:
#
# - length(d): vector dimension
# - mean(d): the mean vector (in full form)
# - cov(d): the covariance matrix (in full form)
# - invcov(d): inverse of covariance
# - logdetcov(d): log-determinant of covariance
# - sqmahal(d, x): Squared Mahalanobis distance to center
# - sqmahal!(r, d, x): Squared Mahalanobis distances
# - gradlogpdf(d, x): Gradient of logpdf w.r.t. x
# - _rand!(d, x): Sample random vector(s)
#
# Other generic functions will be implemented on top
# of these core functions.
#
###########################################################
abstract AbstractMvNormal <: ContinuousMultivariateDistribution
### Generic methods (for all AbstractMvNormal subtypes)
insupport(d::AbstractMvNormal, x::AbstractVector) =
length(d) == length(x) && allfinite(x)
mode(d::AbstractMvNormal) = mean(d)
modes(d::AbstractMvNormal) = [mean(d)]
function entropy(d::AbstractMvNormal)
ldcd = logdetcov(d)
(length(d) * (typeof(ldcd)(log2π) + 1) + ldcd)/2
end
mvnormal_c0(g::AbstractMvNormal) = -(length(g) * Float64(log2π) + logdetcov(g))/2
sqmahal(d::AbstractMvNormal, x::AbstractMatrix) = sqmahal!(Array(promote_type(partype(d), eltype(x)), size(x, 2)), d, x)
_logpdf(d::AbstractMvNormal, x::AbstractVector) = mvnormal_c0(d) - sqmahal(d, x)/2
function _logpdf!(r::AbstractArray, d::AbstractMvNormal, x::AbstractMatrix)
sqmahal!(r, d, x)
c0 = mvnormal_c0(d)
for i = 1:size(x, 2)
@inbounds r[i] = c0 - r[i]/2
end
r
end
_pdf!(r::AbstractArray, d::AbstractMvNormal, x::AbstractMatrix) = exp!(_logpdf!(r, d, x))
###########################################################
#
# MvNormal
#
# Multivariate normal distribution with mean parameters
#
###########################################################
immutable MvNormal{T<:Real,Cov<:AbstractPDMat,Mean<:Union{Vector, ZeroVector}} <: AbstractMvNormal
μ::Mean
Σ::Cov
end
const MultivariateNormal = MvNormal # for the purpose of backward compatibility
typealias IsoNormal MvNormal{Float64,ScalMat{Float64},Vector{Float64}}
typealias DiagNormal MvNormal{Float64,PDiagMat{Float64,Vector{Float64}},Vector{Float64}}
typealias FullNormal MvNormal{Float64,PDMat{Float64,Matrix{Float64}},Vector{Float64}}
typealias ZeroMeanIsoNormal MvNormal{Float64,ScalMat{Float64},ZeroVector{Float64}}
typealias ZeroMeanDiagNormal MvNormal{Float64,PDiagMat{Float64,Vector{Float64}},ZeroVector{Float64}}
typealias ZeroMeanFullNormal MvNormal{Float64,PDMat{Float64,Matrix{Float64}},ZeroVector{Float64}}
### Construction
function MvNormal{T<:Real}(μ::Union{Vector{T}, ZeroVector{T}}, Σ::AbstractPDMat{T})
dim(Σ) == length(μ) || throw(DimensionMismatch("The dimensions of mu and Sigma are inconsistent."))
MvNormal{T,typeof(Σ), typeof(μ)}(μ, Σ)
end
MvNormal{T<:Real, Cov<:AbstractPDMat}(μ::Union{Vector{T}, ZeroVector{T}}, Σ::Cov) = MvNormal(promote_eltype(μ, Σ)...)
function MvNormal{Cov<:AbstractPDMat}(Σ::Cov)
T = eltype(Σ)
MvNormal{T,Cov,ZeroVector{T}}(ZeroVector(T, dim(Σ)), Σ)
end
MvNormal{T<:Real}(μ::Vector{T}, Σ::Matrix{T}) = MvNormal(μ, PDMat(Σ))
MvNormal{T<:Real}(μ::Vector{T}, σ::Vector{T}) = MvNormal(μ, PDiagMat(@compat(abs2.(σ))))
MvNormal{T<:Real}(μ::Vector{T}, σ::T) = MvNormal(μ, ScalMat(length(μ), abs2(σ)))
MvNormal{T<:Real,S<:Real}(μ::Vector{T}, Σ::VecOrMat{S}) = MvNormal(promote_eltype(μ, Σ)...)
MvNormal{T<:Real}(μ::Vector{T}, σ::Real) = MvNormal(promote_eltype(μ, σ)...)
MvNormal{T<:Real}(Σ::Matrix{T}) = MvNormal(PDMat(Σ))
MvNormal{T<:Real}(σ::Vector{T}) = MvNormal(PDiagMat(@compat(abs2.(σ))))
MvNormal(d::Int, σ::Real) = MvNormal(ScalMat(d, abs2(σ)))
### Conversion
function convert{T<:Real}(::Type{MvNormal{T}}, d::MvNormal)
MvNormal(convert_eltype(T, d.μ), convert_eltype(T, d.Σ))
end
function convert{T<:Real}(::Type{MvNormal{T}}, μ::Union{Vector, ZeroVector}, Σ::AbstractPDMat)
MvNormal(convert_eltype(T, μ), convert_eltype(T, Σ))
end
### Show
distrname(d::IsoNormal) = "IsoNormal" # Note: IsoNormal, etc are just alias names
distrname(d::DiagNormal) = "DiagNormal"
distrname(d::FullNormal) = "FullNormal"
distrname(d::ZeroMeanIsoNormal) = "ZeroMeanIsoNormal"
distrname(d::ZeroMeanDiagNormal) = "ZeroMeanDiagNormal"
distrname(d::ZeroMeanFullNormal) = "ZeroMeanFullNormal"
Base.show(io::IO, d::MvNormal) =
show_multline(io, d, [(:dim, length(d)), (:μ, mean(d)), (:Σ, cov(d))])
### Basic statistics
length(d::MvNormal) = length(d.μ)
mean(d::MvNormal) = full(d.μ)
params(d::MvNormal) = (d.μ, d.Σ)
@inline partype{T<:Real}(d::MvNormal{T}) = T
var(d::MvNormal) = diag(d.Σ)
cov(d::MvNormal) = full(d.Σ)
invcov(d::MvNormal) = full(inv(d.Σ))
logdetcov(d::MvNormal) = logdet(d.Σ)
### Evaluation
sqmahal(d::MvNormal, x::AbstractVector) = invquad(d.Σ, x - d.μ)
sqmahal!(r::AbstractVector, d::MvNormal, x::AbstractMatrix) =
invquad!(r, d.Σ, x .- d.μ)
gradlogpdf(d::MvNormal, x::Vector) = -(d.Σ \ (x - d.μ))
# Sampling (for GenericMvNormal)
_rand!(d::MvNormal, x::VecOrMat) = add!(unwhiten!(d.Σ, randn!(x)), d.μ)
# Workaround: randn! only works for Array, but not generally for AbstractArray
function _rand_abstr!(d::MvNormal, x::AbstractVecOrMat)
for i = 1:length(x)
@inbounds x[i] = randn()
end
add!(unwhiten!(d.Σ, x), d.μ)
end
# define these separately to avoid ambiguity with
# _rand(d::Multivariate, x::AbstractMatrix)
_rand!(d::MvNormal, x::AbstractMatrix) = _rand_abstr!(d, x)
_rand!(d::MvNormal, x::AbstractVector) = _rand_abstr!(d, x)
###########################################################
#
# Estimation of MvNormal
#
###########################################################
### Estimation with known covariance
immutable MvNormalKnownCov{Cov<:AbstractPDMat}
Σ::Cov
end
MvNormalKnownCov(d::Int, σ::Real) = MvNormalKnownCov(ScalMat(d, abs2(Float64(σ))))
MvNormalKnownCov(σ::Vector{Float64}) = MvNormalKnownCov(PDiagMat(abs2(σ)))
MvNormalKnownCov(Σ::Matrix{Float64}) = MvNormalKnownCov(PDMat(Σ))
length(g::MvNormalKnownCov) = dim(g.Σ)
immutable MvNormalKnownCovStats{Cov<:AbstractPDMat}
invΣ::Cov # inverse covariance
sx::Vector{Float64} # (weighted) sum of vectors
tw::Float64 # sum of weights
end
function suffstats{Cov<:AbstractPDMat}(g::MvNormalKnownCov{Cov}, x::AbstractMatrix{Float64})
size(x,1) == length(g) || throw(DimensionMismatch("Invalid argument dimensions."))
invΣ = inv(g.Σ)
sx = vec(sum(x, 2))
tw = Float64(size(x, 2))
MvNormalKnownCovStats{Cov}(invΣ, sx, tw)
end
function suffstats{Cov<:AbstractPDMat}(g::MvNormalKnownCov{Cov}, x::AbstractMatrix{Float64}, w::AbstractArray{Float64})
(size(x,1) == length(g) && size(x,2) == length(w)) ||
throw(DimensionMismatch("Inconsistent argument dimensions."))
invΣ = inv(g.Σ)
sx = x * vec(w)
tw = sum(w)
MvNormalKnownCovStats{Cov}(invΣ, sx, tw)
end
## MLE estimation with covariance known
fit_mle{C<:AbstractPDMat}(g::MvNormalKnownCov{C}, ss::MvNormalKnownCovStats{C}) =
MvNormal(ss.sx * inv(ss.tw), g.Σ)
function fit_mle(g::MvNormalKnownCov, x::AbstractMatrix{Float64})
d = length(g)
size(x,1) == d || throw(DimensionMismatch("Invalid argument dimensions."))
μ = multiply!(vec(sum(x,2)), 1.0 / size(x,2))
MvNormal(μ, g.Σ)
end
function fit_mle(g::MvNormalKnownCov, x::AbstractMatrix{Float64}, w::AbstractArray{Float64})
d = length(g)
(size(x,1) == d && size(x,2) == length(w)) ||
throw(DimensionMismatch("Inconsistent argument dimensions."))
μ = Base.LinAlg.BLAS.gemv('N', inv(sum(w)), x, vec(w))
MvNormal(μ, g.Σ)
end
### Estimation (both mean and cov unknown)
immutable MvNormalStats <: SufficientStats
s::Vector{Float64} # (weighted) sum of x
m::Vector{Float64} # (weighted) mean of x
s2::Matrix{Float64} # (weighted) sum of (x-μ) * (x-μ)'
tw::Float64 # total sample weight
end
function suffstats(D::Type{MvNormal}, x::AbstractMatrix{Float64})
d = size(x, 1)
n = size(x, 2)
s = vec(sum(x,2))
m = s * inv(n)
z = x .- m
s2 = A_mul_Bt(z, z)
MvNormalStats(s, m, s2, Float64(n))
end
function suffstats(D::Type{MvNormal}, x::AbstractMatrix{Float64}, w::Array{Float64})
d = size(x, 1)
n = size(x, 2)
length(w) == n || throw(ArgumentError("Inconsistent argument dimensions."))
tw = sum(w)
s = x * vec(w)
m = s * inv(tw)
z = similar(x)
for j = 1:n
xj = view(x,:,j)
zj = view(z,:,j)
swj = sqrt(w[j])
for i = 1:d
@inbounds zj[i] = swj * (xj[i] - m[i])
end
end
s2 = A_mul_Bt(z, z)
MvNormalStats(s, m, s2, tw)
end
# Maximum Likelihood Estimation
#
# Specialized algorithms are respectively implemented for
# each kind of covariance
#
fit_mle(D::Type{MvNormal}, ss::MvNormalStats) = fit_mle(FullNormal, ss)
fit_mle(D::Type{MvNormal}, x::AbstractMatrix{Float64}) = fit_mle(FullNormal, x)
fit_mle(D::Type{MvNormal}, x::AbstractMatrix{Float64}, w::AbstractArray{Float64}) = fit_mle(FullNormal, x, w)
fit_mle(D::Type{FullNormal}, ss::MvNormalStats) = MvNormal(ss.m, ss.s2 * inv(ss.tw))
function fit_mle(D::Type{FullNormal}, x::AbstractMatrix{Float64})
n = size(x, 2)
mu = vec(mean(x, 2))
z = x .- mu
C = Base.LinAlg.BLAS.syrk('U', 'N', 1.0/n, z)
Base.LinAlg.copytri!(C, 'U')
MvNormal(mu, PDMat(C))
end
function fit_mle(D::Type{FullNormal}, x::AbstractMatrix{Float64}, w::AbstractVector{Float64})
m = size(x, 1)
n = size(x, 2)
length(w) == n || throw(DimensionMismatch("Inconsistent argument dimensions"))
inv_sw = 1.0 / sum(w)
mu = Base.LinAlg.BLAS.gemv('N', inv_sw, x, w)
z = Array(Float64, m, n)
for j = 1:n
cj = sqrt(w[j])
for i = 1:m
@inbounds z[i,j] = (x[i,j] - mu[i]) * cj
end
end
C = Base.LinAlg.BLAS.syrk('U', 'N', inv_sw, z)
Base.LinAlg.copytri!(C, 'U')
MvNormal(mu, PDMat(C))
end
function fit_mle(D::Type{DiagNormal}, x::AbstractMatrix{Float64})
m = size(x, 1)
n = size(x, 2)
mu = vec(mean(x, 2))
va = zeros(Float64, m)
for j = 1:n
for i = 1:m
@inbounds va[i] += abs2(x[i,j] - mu[i])
end
end
multiply!(va, inv(n))
MvNormal(mu, PDiagMat(va))
end
function fit_mle(D::Type{DiagNormal}, x::AbstractMatrix{Float64}, w::AbstractArray{Float64})
m = size(x, 1)
n = size(x, 2)
length(w) == n || throw(DimensionMismatch("Inconsistent argument dimensions"))
inv_sw = 1.0 / sum(w)
mu = Base.LinAlg.BLAS.gemv('N', inv_sw, x, w)
va = zeros(Float64, m)
for j = 1:n
@inbounds wj = w[j]
for i = 1:m
@inbounds va[i] += abs2(x[i,j] - mu[i]) * wj
end
end
multiply!(va, inv_sw)
MvNormal(mu, PDiagMat(va))
end
function fit_mle(D::Type{IsoNormal}, x::AbstractMatrix{Float64})
m = size(x, 1)
n = size(x, 2)
mu = vec(mean(x, 2))
va = 0.
for j = 1:n
va_j = 0.
for i = 1:m
@inbounds va_j += abs2(x[i,j] - mu[i])
end
va += va_j
end
MvNormal(mu, ScalMat(m, va / (m * n)))
end
function fit_mle(D::Type{IsoNormal}, x::AbstractMatrix{Float64}, w::AbstractArray{Float64})
m = size(x, 1)
n = size(x, 2)
length(w) == n || throw(DimensionMismatch("Inconsistent argument dimensions"))
sw = sum(w)
inv_sw = 1.0 / sw
mu = Base.LinAlg.BLAS.gemv('N', inv_sw, x, w)
va = 0.
for j = 1:n
@inbounds wj = w[j]
va_j = 0.
for i = 1:m
@inbounds va_j += abs2(x[i,j] - mu[i]) * wj
end
va += va_j
end
MvNormal(mu, ScalMat(m, va / (m * sw)))
end