-
Notifications
You must be signed in to change notification settings - Fork 18
/
filter.frag
495 lines (404 loc) · 15.4 KB
/
filter.frag
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
R""(
#version 450
#extension GL_ARB_separate_shader_objects : enable
#define UX3D_MATH_PI 3.1415926535897932384626433832795
#define UX3D_MATH_INV_PI (1.0 / UX3D_MATH_PI)
layout(set = 0, binding = 0) uniform sampler2D uPanorama;
layout(set = 0, binding = 1) uniform samplerCube uCubeMap;
// enum
const uint cLambertian = 0;
const uint cGGX = 1;
const uint cCharlie = 2;
layout(push_constant) uniform FilterParameters {
float roughness;
uint sampleCount;
uint currentMipLevel;
uint width;
float lodBias;
uint distribution; // enum
} pFilterParameters;
layout (location = 0) in vec2 inUV;
// output cubemap faces
layout(location = 0) out vec4 outFace0;
layout(location = 1) out vec4 outFace1;
layout(location = 2) out vec4 outFace2;
layout(location = 3) out vec4 outFace3;
layout(location = 4) out vec4 outFace4;
layout(location = 5) out vec4 outFace5;
layout(location = 6) out vec3 outLUT;
void writeFace(int face, vec3 colorIn)
{
vec4 color = vec4(colorIn.rgb, 1.0f);
if(face == 0)
outFace0 = color;
else if(face == 1)
outFace1 = color;
else if(face == 2)
outFace2 = color;
else if(face == 3)
outFace3 = color;
else if(face == 4)
outFace4 = color;
else //if(face == 5)
outFace5 = color;
}
vec3 uvToXYZ(int face, vec2 uv)
{
if(face == 0)
return vec3( 1.f, uv.y, -uv.x);
else if(face == 1)
return vec3( -1.f, uv.y, uv.x);
else if(face == 2)
return vec3( +uv.x, -1.f, +uv.y);
else if(face == 3)
return vec3( +uv.x, 1.f, -uv.y);
else if(face == 4)
return vec3( +uv.x, uv.y, 1.f);
else {//if(face == 5)
return vec3( -uv.x, +uv.y, -1.f);}
}
vec2 dirToUV(vec3 dir)
{
return vec2(
0.5f + 0.5f * atan(dir.z, dir.x) / UX3D_MATH_PI,
1.f - acos(dir.y) / UX3D_MATH_PI);
}
float saturate(float v)
{
return clamp(v, 0.0f, 1.0f);
}
// Hammersley Points on the Hemisphere
// CC BY 3.0 (Holger Dammertz)
// http://holger.dammertz.org/stuff/notes_HammersleyOnHemisphere.html
// with adapted interface
float radicalInverse_VdC(uint bits)
{
bits = (bits << 16u) | (bits >> 16u);
bits = ((bits & 0x55555555u) << 1u) | ((bits & 0xAAAAAAAAu) >> 1u);
bits = ((bits & 0x33333333u) << 2u) | ((bits & 0xCCCCCCCCu) >> 2u);
bits = ((bits & 0x0F0F0F0Fu) << 4u) | ((bits & 0xF0F0F0F0u) >> 4u);
bits = ((bits & 0x00FF00FFu) << 8u) | ((bits & 0xFF00FF00u) >> 8u);
return float(bits) * 2.3283064365386963e-10; // / 0x100000000
}
// hammersley2d describes a sequence of points in the 2d unit square [0,1)^2
// that can be used for quasi Monte Carlo integration
vec2 hammersley2d(int i, int N) {
return vec2(float(i)/float(N), radicalInverse_VdC(uint(i)));
}
// Hemisphere Sample
// TBN generates a tangent bitangent normal coordinate frame from the normal
// (the normal must be normalized)
mat3 generateTBN(vec3 normal)
{
vec3 bitangent = vec3(0.0, 1.0, 0.0);
float NdotUp = dot(normal, vec3(0.0, 1.0, 0.0));
float epsilon = 0.0000001;
if (1.0 - abs(NdotUp) <= epsilon)
{
// Sampling +Y or -Y, so we need a more robust bitangent.
if (NdotUp > 0.0)
{
bitangent = vec3(0.0, 0.0, 1.0);
}
else
{
bitangent = vec3(0.0, 0.0, -1.0);
}
}
vec3 tangent = normalize(cross(bitangent, normal));
bitangent = cross(normal, tangent);
return mat3(tangent, bitangent, normal);
}
struct MicrofacetDistributionSample
{
float pdf;
float cosTheta;
float sinTheta;
float phi;
};
float D_GGX(float NdotH, float roughness) {
float a = NdotH * roughness;
float k = roughness / (1.0 - NdotH * NdotH + a * a);
return k * k * (1.0 / UX3D_MATH_PI);
}
// GGX microfacet distribution
// https://www.cs.cornell.edu/~srm/publications/EGSR07-btdf.html
// This implementation is based on https://bruop.github.io/ibl/,
// https://www.tobias-franke.eu/log/2014/03/30/notes_on_importance_sampling.html
// and https://developer.nvidia.com/gpugems/GPUGems3/gpugems3_ch20.html
MicrofacetDistributionSample GGX(vec2 xi, float roughness)
{
MicrofacetDistributionSample ggx;
// evaluate sampling equations
float alpha = roughness * roughness;
ggx.cosTheta = saturate(sqrt((1.0 - xi.y) / (1.0 + (alpha * alpha - 1.0) * xi.y)));
ggx.sinTheta = sqrt(1.0 - ggx.cosTheta * ggx.cosTheta);
ggx.phi = 2.0 * UX3D_MATH_PI * xi.x;
// evaluate GGX pdf (for half vector)
ggx.pdf = D_GGX(ggx.cosTheta, alpha);
// Apply the Jacobian to obtain a pdf that is parameterized by l
// see https://bruop.github.io/ibl/
// Typically you'd have the following:
// float pdf = D_GGX(NoH, roughness) * NoH / (4.0 * VoH);
// but since V = N => VoH == NoH
ggx.pdf /= 4.0;
return ggx;
}
// NDF
float D_Ashikhmin(float NdotH, float roughness)
{
float alpha = roughness * roughness;
// Ashikhmin 2007, "Distribution-based BRDFs"
float a2 = alpha * alpha;
float cos2h = NdotH * NdotH;
float sin2h = 1.0 - cos2h;
float sin4h = sin2h * sin2h;
float cot2 = -cos2h / (a2 * sin2h);
return 1.0 / (UX3D_MATH_PI * (4.0 * a2 + 1.0) * sin4h) * (4.0 * exp(cot2) + sin4h);
}
// NDF
float D_Charlie(float sheenRoughness, float NdotH)
{
sheenRoughness = max(sheenRoughness, 0.000001); //clamp (0,1]
float invR = 1.0 / sheenRoughness;
float cos2h = NdotH * NdotH;
float sin2h = 1.0 - cos2h;
return (2.0 + invR) * pow(sin2h, invR * 0.5) / (2.0 * UX3D_MATH_PI);
}
MicrofacetDistributionSample Charlie(vec2 xi, float roughness)
{
MicrofacetDistributionSample charlie;
float alpha = roughness * roughness;
charlie.sinTheta = pow(xi.y, alpha / (2.0*alpha + 1.0));
charlie.cosTheta = sqrt(1.0 - charlie.sinTheta * charlie.sinTheta);
charlie.phi = 2.0 * UX3D_MATH_PI * xi.x;
// evaluate Charlie pdf (for half vector)
charlie.pdf = D_Charlie(alpha, charlie.cosTheta);
// Apply the Jacobian to obtain a pdf that is parameterized by l
charlie.pdf /= 4.0;
return charlie;
}
MicrofacetDistributionSample Lambertian(vec2 xi, float roughness)
{
MicrofacetDistributionSample lambertian;
// Cosine weighted hemisphere sampling
// http://www.pbr-book.org/3ed-2018/Monte_Carlo_Integration/2D_Sampling_with_Multidimensional_Transformations.html#Cosine-WeightedHemisphereSampling
lambertian.cosTheta = sqrt(1.0 - xi.y);
lambertian.sinTheta = sqrt(xi.y); // equivalent to `sqrt(1.0 - cosTheta*cosTheta)`;
lambertian.phi = 2.0 * UX3D_MATH_PI * xi.x;
lambertian.pdf = lambertian.cosTheta / UX3D_MATH_PI; // evaluation for solid angle, therefore drop the sinTheta
return lambertian;
}
// getImportanceSample returns an importance sample direction with pdf in the .w component
vec4 getImportanceSample(int sampleIndex, vec3 N, float roughness)
{
// generate a quasi monte carlo point in the unit square [0.1)^2
vec2 xi = hammersley2d(sampleIndex, int(pFilterParameters.sampleCount));
MicrofacetDistributionSample importanceSample;
// generate the points on the hemisphere with a fitting mapping for
// the distribution (e.g. lambertian uses a cosine importance)
if(pFilterParameters.distribution == cLambertian)
{
importanceSample = Lambertian(xi, roughness);
}
else if(pFilterParameters.distribution == cGGX)
{
// Trowbridge-Reitz / GGX microfacet model (Walter et al)
// https://www.cs.cornell.edu/~srm/publications/EGSR07-btdf.html
importanceSample = GGX(xi, roughness);
}
else if(pFilterParameters.distribution == cCharlie)
{
importanceSample = Charlie(xi, roughness);
}
// transform the hemisphere sample to the normal coordinate frame
// i.e. rotate the hemisphere to the normal direction
vec3 localSpaceDirection = normalize(vec3(
importanceSample.sinTheta * cos(importanceSample.phi),
importanceSample.sinTheta * sin(importanceSample.phi),
importanceSample.cosTheta
));
mat3 TBN = generateTBN(N);
vec3 direction = TBN * localSpaceDirection;
return vec4(direction, importanceSample.pdf);
}
// Mipmap Filtered Samples (GPU Gems 3, 20.4)
// https://developer.nvidia.com/gpugems/gpugems3/part-iii-rendering/chapter-20-gpu-based-importance-sampling
// https://cgg.mff.cuni.cz/~jaroslav/papers/2007-sketch-fis/Final_sap_0073.pdf
float computeLod(float pdf)
{
// // Solid angle of current sample -- bigger for less likely samples
// float omegaS = 1.0 / (float(FilterParameters.sampleCoun) * pdf);
// // Solid angle of texel
// // note: the factor of 4.0 * UX3D_MATH_PI
// float omegaP = 4.0 * UX3D_MATH_PI / (6.0 * float(pFilterParameters.width) * float(pFilterParameters.width));
// // Mip level is determined by the ratio of our sample's solid angle to a texel's solid angle
// // note that 0.5 * log2 is equivalent to log4
// float lod = 0.5 * log2(omegaS / omegaP);
// babylon introduces a factor of K (=4) to the solid angle ratio
// this helps to avoid undersampling the environment map
// this does not appear in the original formulation by Jaroslav Krivanek and Mark Colbert
// log4(4) == 1
// lod += 1.0;
// We achieved good results by using the original formulation from Krivanek & Colbert adapted to cubemaps
// https://cgg.mff.cuni.cz/~jaroslav/papers/2007-sketch-fis/Final_sap_0073.pdf
float lod = 0.5 * log2( 6.0 * float(pFilterParameters.width) * float(pFilterParameters.width) / (float(pFilterParameters.sampleCount) * pdf));
return lod;
}
vec3 filterColor(vec3 N)
{
//return textureLod(uCubeMap, N, 3.0).rgb;
vec3 color = vec3(0.f);
float weight = 0.0f;
for(int i = 0; i < int(pFilterParameters.sampleCount); ++i)
{
vec4 importanceSample = getImportanceSample(i, N, pFilterParameters.roughness);
vec3 H = vec3(importanceSample.xyz);
float pdf = importanceSample.w;
// mipmap filtered samples (GPU Gems 3, 20.4)
float lod = computeLod(pdf);
// apply the bias to the lod
lod += pFilterParameters.lodBias;
if(pFilterParameters.distribution == cLambertian)
{
// sample lambertian at a lower resolution to avoid fireflies
vec3 lambertian = textureLod(uCubeMap, H, lod).rgb;
//// the below operations cancel each other out
// lambertian *= NdotH; // lamberts law
// lambertian /= pdf; // invert bias from importance sampling
// lambertian /= UX3D_MATH_PI; // convert irradiance to radiance https://seblagarde.wordpress.com/2012/01/08/pi-or-not-to-pi-in-game-lighting-equation/
color += lambertian;
}
else if(pFilterParameters.distribution == cGGX || pFilterParameters.distribution == cCharlie)
{
// Note: reflect takes incident vector.
vec3 V = N;
vec3 L = normalize(reflect(-V, H));
float NdotL = dot(N, L);
if (NdotL > 0.0)
{
if(pFilterParameters.roughness == 0.0)
{
// without this the roughness=0 lod is too high
lod = pFilterParameters.lodBias;
}
vec3 sampleColor = textureLod(uCubeMap, L, lod).rgb;
color += sampleColor * NdotL;
weight += NdotL;
}
}
}
if(weight != 0.0f)
{
color /= weight;
}
else
{
color /= float(pFilterParameters.sampleCount);
}
return color.rgb ;
}
// From the filament docs. Geometric Shadowing function
// https://google.github.io/filament/Filament.html#toc4.4.2
float V_SmithGGXCorrelated(float NoV, float NoL, float roughness) {
float a2 = pow(roughness, 4.0);
float GGXV = NoL * sqrt(NoV * NoV * (1.0 - a2) + a2);
float GGXL = NoV * sqrt(NoL * NoL * (1.0 - a2) + a2);
return 0.5 / (GGXV + GGXL);
}
// https://github.com/google/filament/blob/master/shaders/src/brdf.fs#L136
float V_Ashikhmin(float NdotL, float NdotV)
{
return clamp(1.0 / (4.0 * (NdotL + NdotV - NdotL * NdotV)), 0.0, 1.0);
}
// Compute LUT for GGX distribution.
// See https://blog.selfshadow.com/publications/s2013-shading-course/karis/s2013_pbs_epic_notes_v2.pdf
vec3 LUT(float NdotV, float roughness)
{
// Compute spherical view vector: (sin(phi), 0, cos(phi))
vec3 V = vec3(sqrt(1.0 - NdotV * NdotV), 0.0, NdotV);
// The macro surface normal just points up.
vec3 N = vec3(0.0, 0.0, 1.0);
// To make the LUT independant from the material's F0, which is part of the Fresnel term
// when substituted by Schlick's approximation, we factor it out of the integral,
// yielding to the form: F0 * I1 + I2
// I1 and I2 are slighlty different in the Fresnel term, but both only depend on
// NoL and roughness, so they are both numerically integrated and written into two channels.
float A = 0.0;
float B = 0.0;
float C = 0.0;
for(int i = 0; i < int(pFilterParameters.sampleCount); ++i)
{
// Importance sampling, depending on the distribution.
vec4 importanceSample = getImportanceSample(i, N, roughness);
vec3 H = importanceSample.xyz;
// float pdf = importanceSample.w;
vec3 L = normalize(reflect(-V, H));
float NdotL = saturate(L.z);
float NdotH = saturate(H.z);
float VdotH = saturate(dot(V, H));
if (NdotL > 0.0)
{
if (pFilterParameters.distribution == cGGX)
{
// LUT for GGX distribution.
// Taken from: https://bruop.github.io/ibl
// Shadertoy: https://www.shadertoy.com/view/3lXXDB
// Terms besides V are from the GGX PDF we're dividing by.
float V_pdf = V_SmithGGXCorrelated(NdotV, NdotL, roughness) * VdotH * NdotL / NdotH;
float Fc = pow(1.0 - VdotH, 5.0);
A += (1.0 - Fc) * V_pdf;
B += Fc * V_pdf;
C += 0.0;
}
if (pFilterParameters.distribution == cCharlie)
{
// LUT for Charlie distribution.
float sheenDistribution = D_Charlie(roughness, NdotH);
float sheenVisibility = V_Ashikhmin(NdotL, NdotV);
A += 0.0;
B += 0.0;
C += sheenVisibility * sheenDistribution * NdotL * VdotH;
}
}
}
// The PDF is simply pdf(v, h) -> NDF * <nh>.
// To parametrize the PDF over l, use the Jacobian transform, yielding to: pdf(v, l) -> NDF * <nh> / 4<vh>
// Since the BRDF divide through the PDF to be normalized, the 4 can be pulled out of the integral.
return vec3(4.0 * A, 4.0 * B, 4.0 * 2.0 * UX3D_MATH_PI * C) / float(pFilterParameters.sampleCount);
}
// entry point
void panoramaToCubeMap()
{
for(int face = 0; face < 6; ++face)
{
vec3 scan = uvToXYZ(face, inUV*2.0-1.0);
vec3 direction = normalize(scan);
vec2 src = dirToUV(direction);
writeFace(face, texture(uPanorama, src).rgb);
}
}
// entry point
void filterCubeMap()
{
vec2 newUV = inUV * float(1 << (pFilterParameters.currentMipLevel));
newUV = newUV*2.0-1.0;
for(int face = 0; face < 6; ++face)
{
vec3 scan = uvToXYZ(face, newUV);
vec3 direction = normalize(scan);
direction.y = -direction.y;
writeFace(face, filterColor(direction));
//Debug output:
//writeFace(face, texture(uCubeMap, direction).rgb);
//writeFace(face, direction);
}
// Write LUT:
// x-coordinate: NdotV
// y-coordinate: roughness
if (pFilterParameters.currentMipLevel == 0)
{
outLUT = LUT(inUV.x, inUV.y);
}
}
)""