-
Notifications
You must be signed in to change notification settings - Fork 5
/
random.wat
732 lines (652 loc) · 22.1 KB
/
random.wat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
;;========================================================;;
;; NOISES AND RANDOMNESS IN HANDWRITTEN WEBASSEMBLY ;;
;; `random.wat` Lingdong Huang 2020 Public Domain ;;
;;========================================================;;
;; Uniform, Perlin, Gaussian, Exponential Randomness ;;
;;--------------------------------------------------------;;
(module
(memory $mem 1) ;; 64K
;; MEMORY LAYOUT (total 20,992 bytes)
;; -----------------------------------------
;; 4608 bytes | ziggurat lookup tables
;; -> i32 kn[128], ke[256]
;; -> f32 wn[128], fn[128],we[256],fe[256]
;; -----------------------------------------
;; 16384 bytes | perlin lookup table
;; -> f32 [4096]
;; -----------------------------------------
;; perlin noise constants
(global $PERLIN_YWRAPB i32 (i32.const 4 ))
(global $PERLIN_YWRAP i32 (i32.const 16 )) ;; 1<<PERLIN_YWRAPB
(global $PERLIN_ZWRAPB i32 (i32.const 8 ))
(global $PERLIN_ZWRAP i32 (i32.const 256 )) ;; 1<<PERLIN_ZWRAPB
(global $PERLIN_SIZE i32 (i32.const 4095)) ;; 2^?-1
;; math constants
(global $PI f32 (f32.const 3.1415926536))
(global $TAU f32 (f32.const 6.2831853072)) ;; 2*PI
(global $INV_TAU f32 (f32.const 0.1591549431)) ;; 1/(2*PI)
;; perlin configs
(global $PERLIN_OCTAVES (mut i32) (i32.const 4 ))
(global $PERLIN_AMP_FALLOFF (mut f32) (f32.const 0.5))
(global $perlin_ptr i32 (i32.const 4608)) ;; pointer to perlin table
;; first 1152 bytes reserved for ziggurat
;;====================================================================
;; Shared utils
;;====================================================================
;; shr3 random number generator seed
(global $jsr (mut i32) (i32.const 0x5EED))
(global $jz (mut i32) (i32.const 0))
;; other ziggurat globals
(global $iz (mut i32) (i32.const 0))
(global $hz (mut i32) (i32.const 0))
;; shr3 random number generator
(func $shr3 (result i32)
(global.set $jz (global.get $jsr))
(global.set $jsr (i32.xor (global.get $jsr) (i32.shl (global.get $jsr) (i32.const 13))))
(global.set $jsr (i32.xor (global.get $jsr) (i32.shr_u (global.get $jsr) (i32.const 17))))
(global.set $jsr (i32.xor (global.get $jsr) (i32.shl (global.get $jsr) (i32.const 5 ))))
(i32.add (global.get $jz) (global.get $jsr))
)
;; uniform randomness between [0,1]
(func $uni (result f32)
(f32.add
(f32.const 0.5)
(f32.mul (f32.convert_i32_s (call $shr3)) (f32.const 0.2328306e-9))
)
)
;; fast and crappy cosine approximation for [-pi,pi]
(func $cos_approx (param $x f32) (result f32)
;; adapted from https://stackoverflow.com/a/28050328
(local.set $x (f32.mul (local.get $x) (global.get $INV_TAU)))
(local.set $x (f32.sub (local.get $x) (f32.add
(f32.const 0.25)
(f32.floor (f32.add (local.get $x (f32.const 0.25))))
)))
(local.set $x (f32.mul (local.get $x) (f32.mul
(f32.const 16.0)
(f32.sub (f32.abs (local.get $x)) (f32.const 0.5) )
)))
(local.get $x)
)
;; float mod
(func $fmod (param $x f32) (param $y f32) (result f32)
(f32.sub (local.get $x) (f32.mul
(local.get $y)
(f32.trunc (f32.div (local.get $x) (local.get $y)))
))
)
;; consine function
;; use periodic property to fall in range [-pi,pi] for cos_approx
(func $cos (param $x f32) (result f32)
(f32.neg (call $cos_approx (f32.sub (call $fmod (local.get $x) (global.get $TAU)) (global.get $PI) ) ))
)
;; natural log ln(x) approximation
(func $log (param $x f32) (result f32)
;; https://gist.github.com/LingDong-/7e4c4cae5cbbc44400a05fba65f06f23
(local $bx i32)
(local $ex i32)
(local $t i32)
(local $s i32)
(local.set $bx (i32.reinterpret_f32 (local.get $x)))
(local.set $ex (i32.shr_u (local.get $bx) (i32.const 23)))
(local.set $t (i32.sub (local.get $ex) (i32.const 127)))
(local.set $s (local.get $t))
(if (i32.lt_s (local.get $t) (i32.const 0)) (then
(local.set $s (i32.sub (i32.const 0) (local.get $t) ))
))
(local.set $bx (i32.or
(i32.const 1065353216)
(i32.and (local.get $bx) (i32.const 8388607) )
))
(local.set $x (f32.reinterpret_i32 (local.get $bx) ))
(f32.add
(f32.add (f32.const -1.49278)
(f32.mul (f32.add (f32.const 2.11263)
(f32.mul (f32.add (f32.const -0.729104)
(f32.mul (f32.const 0.10969)
(local.get $x)))
(local.get $x)))
(local.get $x)))
(f32.mul
(f32.convert_i32_s (local.get $t))
(f32.const 0.6931471806)
)
)
)
;; natural exponent e^x approximation
(func $exp (param $x f32) (result f32)
;; adapted from https://stackoverflow.com/a/50425370
(local $m i32)
(local $i i32)
(local.set $i (i32.add
(i32.trunc_f32_s (f32.mul (local.get $x) (f32.const 12102203.0)) )
(i32.const 1065353216)
))
(local.set $m (i32.and
(i32.shr_u (local.get $i) (i32.const 7))
(i32.const 0xffff)
))
(local.set $i (i32.add (local.get $i)
(i32.sub (i32.shr_s (i32.mul
(i32.sub (i32.shr_s (i32.mul
(i32.add (i32.shr_s (i32.mul
(i32.const 1277 ) (local.get $m)) (i32.const 14))
(i32.const 14825)) (local.get $m)) (i32.const 14))
(i32.const 79749)) (local.get $m)) (i32.const 11))
(i32.const 626 ))
))
(f32.reinterpret_i32 (local.get $i))
)
;;====================================================================
;; Perlin noise
;; ADAPTED FROM:
;; https://github.com/processing/p5.js/blob/master/src/math/noise.js
;; WHICH WAS ADAPTED FROM:
;; https://www.kuehlbox.wtf/download/demos/farbrausch/fr010src.zip
;;====================================================================
(func $scaled_cos (param $i f32) (result f32)
(f32.mul
(f32.const 0.5)
( f32.sub (f32.const 1.0) (call $cos (f32.mul (global.get $PI) (local.get $i))) )
)
)
;; set perlin noise seed
;; fills a lookup table with random(0,1)
(func $pnseed (param $seed i32)
(local $i i32)
(local $n i32)
(local.set $n (i32.add (global.get $PERLIN_SIZE) (i32.const 1)))
(global.set $jsr (local.get $seed))
(local.set $i (i32.const 0))
loop $l0
(f32.store
(i32.add (global.get $perlin_ptr) (i32.shl (local.get $i) (i32.const 2)))
(call $uni)
)
(local.set $i (i32.add (local.get $i (i32.const 1))))
(br_if $l0 (i32.lt_u (local.get $i) (local.get $n)))
end
)
(func $pndetail (param $lod i32) (param $falloff f32)
(global.set $PERLIN_OCTAVES (local.get $lod))
(global.set $PERLIN_AMP_FALLOFF (local.get $falloff))
)
;; helper to read a float from lookup table
(func $perlin_lookup (param $i i32) (result f32)
(f32.load (i32.add (global.get $perlin_ptr) (i32.shl
(i32.and (local.get $i) (global.get $PERLIN_SIZE))
(i32.const 2)
)))
)
;; main perlin noise function:
;; sample noise at (x,y,z)
(func $pnoise (param $x f32) (param $y f32) (param $z f32) (result f32)
(local $xi i32) (local $yi i32) (local $zi i32)
(local $o i32) (local $of i32)
(local $xf f32) (local $yf f32) (local $zf f32)
(local $rxf f32) (local $ryf f32) (local $r f32) (local $ampl f32)
(local $n1 f32) (local $n2 f32) (local $n3 f32)
(local.set $x (f32.abs (local.get $x)))
(local.set $y (f32.abs (local.get $y)))
(local.set $z (f32.abs (local.get $z)))
(local.set $xi (i32.trunc_f32_u (local.get $x)))
(local.set $yi (i32.trunc_f32_u (local.get $y)))
(local.set $zi (i32.trunc_f32_u (local.get $z)))
(local.set $xf (f32.sub (local.get $x) (f32.trunc (local.get $x) ) ))
(local.set $yf (f32.sub (local.get $y) (f32.trunc (local.get $y) ) ))
(local.set $zf (f32.sub (local.get $z) (f32.trunc (local.get $z) ) ))
(local.set $r (f32.const 0))
(local.set $ampl (f32.const 0.5))
loop $l0
(local.set $of (i32.add
(i32.add (local.get $xi) (i32.shl (local.get $yi) (global.get $PERLIN_YWRAPB)))
(i32.shl (local.get $zi) (global.get $PERLIN_ZWRAPB))
))
(local.set $rxf (call $scaled_cos (local.get $xf)))
(local.set $ryf (call $scaled_cos (local.get $yf)))
(local.set $n1 (call $perlin_lookup (local.get $of) ))
(local.set $n1 (f32.add (local.get $n1)
(f32.mul
(local.get $rxf)
(f32.sub
(call $perlin_lookup (i32.add (local.get $of) (i32.const 1)) )
(local.get $n1)
)
)
))
(local.set $n2 (call $perlin_lookup (i32.add (local.get $of) (global.get $PERLIN_YWRAP)) ))
(local.set $n2 (f32.add (local.get $n2)
(f32.mul
(local.get $rxf)
(f32.sub
(call $perlin_lookup
(i32.add (i32.add (local.get $of) (global.get $PERLIN_YWRAP)) (i32.const 1))
)
(local.get $n2)
)
)
))
(local.set $n1 (f32.add (local.get $n1) (f32.mul
(local.get $ryf)
(f32.sub (local.get $n2) (local.get $n1))
)))
(local.set $of (i32.add (local.get $of) (global.get $PERLIN_ZWRAP) ))
(local.set $n2 (call $perlin_lookup (local.get $of)))
(local.set $n2 (f32.add (local.get $n2)
(f32.mul
(local.get $rxf)
(f32.sub
(call $perlin_lookup (i32.add (local.get $of) (i32.const 1)) )
(local.get $n2)
)
)
))
(local.set $n3 (call $perlin_lookup (i32.add (local.get $of) (global.get $PERLIN_YWRAP)) ))
(local.set $n3 (f32.add (local.get $n3)
(f32.mul
(local.get $rxf)
(f32.sub
(call $perlin_lookup
(i32.add (i32.add (local.get $of) (global.get $PERLIN_YWRAP)) (i32.const 1))
)
(local.get $n3)
)
)
))
(local.set $n2 (f32.add (local.get $n2) (f32.mul
(local.get $ryf)
(f32.sub (local.get $n3) (local.get $n2))
)))
(local.set $n1 (f32.add (local.get $n1)
(f32.mul
(call $scaled_cos (local.get $zf))
(f32.sub (local.get $n2) (local.get $n1))
)
))
(local.set $r (f32.add (local.get $r)
(f32.mul (local.get $n1) (local.get $ampl))
))
(local.set $ampl (f32.mul (local.get $ampl) (global.get $PERLIN_AMP_FALLOFF) ))
(local.set $xi (i32.shl (local.get $xi) (i32.const 1) ))
(local.set $yi (i32.shl (local.get $yi) (i32.const 1) ))
(local.set $zi (i32.shl (local.get $zi) (i32.const 1) ))
(local.set $xf (f32.mul (local.get $xf) (f32.const 2.0) ))
(local.set $yf (f32.mul (local.get $yf) (f32.const 2.0) ))
(local.set $zf (f32.mul (local.get $zf) (f32.const 2.0) ))
(if (f32.lt (local.get $xf) (f32.const 1.0)) (then) (else
(local.set $xi (i32.add (local.get $xi) (i32.const 1)))
(local.set $xf (f32.sub (local.get $xf) (f32.const 1)))
))
(if (f32.lt (local.get $yf) (f32.const 1.0)) (then) (else
(local.set $yi (i32.add (local.get $yi) (i32.const 1)))
(local.set $yf (f32.sub (local.get $yf) (f32.const 1)))
))
(if (f32.lt (local.get $zf) (f32.const 1.0)) (then) (else
(local.set $zi (i32.add (local.get $zi) (i32.const 1)))
(local.set $zf (f32.sub (local.get $zf) (f32.const 1)))
))
(local.set $o (i32.add (local.get $o (i32.const 1))))
(br_if $l0 (i32.lt_u (local.get $o) (global.get $PERLIN_OCTAVES)))
end
(local.get $r)
)
;;====================================================================
;; Gaussian and Exponential randomness using Ziggurat algorithm
;; ADAPTED FROM:
;; The Ziggurat Method for Generating Random Variables
;; George Marsaglia; Wai Wan Tsang (2000)
;; https://core.ac.uk/download/pdf/6287927.pdf
;;====================================================================
;; table reader and writers
;; kn : i32[128]
(func $kn_read (param $i i32) (result i32)
(i32.load
(i32.shl (local.get $i) (i32.const 2))
)
)
(func $kn_write (param $i i32) (param $v i32)
(i32.store
(i32.shl (local.get $i) (i32.const 2))
(local.get $v))
)
;; ke : i32[256]
(func $ke_read (param $i i32) (result i32)
(i32.load (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 512)
))
)
(func $ke_write (param $i i32) (param $v i32)
(i32.store (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 512)
) (local.get $v))
)
;; wn : f32[128]
(func $wn_read (param $i i32) (result f32)
(f32.load (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 1536)
))
)
(func $wn_write (param $i i32) (param $v f32)
(f32.store (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 1536)
) (local.get $v))
)
;; fn : f32[128]
(func $fn_read (param $i i32) (result f32)
(f32.load (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 2048)
))
)
(func $fn_write (param $i i32) (param $v f32)
(f32.store (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 2048)
) (local.get $v))
)
;; we : f32[256]
(func $we_read (param $i i32) (result f32)
(f32.load (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 2560)
))
)
(func $we_write (param $i i32) (param $v f32)
(f32.store (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 2560)
) (local.get $v))
)
;; fe : f32[256]
(func $fe_read (param $i i32) (result f32)
(f32.load (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 3584)
))
)
(func $fe_write (param $i i32) (param $v f32)
(f32.store (i32.add
(i32.shl (local.get $i) (i32.const 2))
(i32.const 3584)
) (local.get $v))
)
;; provides RNOR if $rnor cannot
(func $nfix (result f32)
(local $r f32)
(local $x f32)
(local $y f32)
(local $fhz f32)
(local.set $r (f32.const 3.442620))
loop $l0
(local.set $x (f32.mul
(f32.convert_i32_s (global.get $hz))
(call $wn_read (global.get $iz))
))
(if (i32.eqz (global.get $iz)) (then
loop $l1
(local.set $x (f32.mul (call $log (call $uni)) (f32.const -0.2904764)))
(local.set $y (f32.neg (call $log (call $uni))))
(br_if $l1 (f32.lt
(f32.add (local.get $y) (local.get $y) )
(f32.mul (local.get $x) (local.get $x) )
))
end
(if (i32.gt_s (global.get $hz) (i32.const 0) ) (then
(f32.add (local.get $r) (local.get $x))
return
)(else
(f32.neg (f32.add (local.get $r) (local.get $x)))
return
))
))
(if (f32.lt
(f32.add
(call $fn_read (global.get $iz))
(f32.mul
(call $uni)
(f32.sub
(call $fn_read (i32.sub (global.get $iz) (i32.const 1)))
(call $fn_read (global.get $iz))
)
)
)
(call $exp
(f32.mul (f32.mul (f32.const -0.5) (local.get $x)) (local.get $x))
)
)(then
(local.get $x)
return
))
(global.set $hz (call $shr3))
(global.set $iz (i32.and (global.get $hz) (i32.const 127)))
(local.set $fhz (f32.convert_i32_s (global.get $hz)))
(if (i32.lt_u
(i32.trunc_f32_u (f32.abs (local.get $fhz)))
(call $kn_read (global.get $iz))
)(then
(f32.mul
(local.get $fhz)
(call $wn_read (global.get $iz))
)
return
))
(br $l0)
end
(f32.const 0)
)
;;provides REXP if $rexp cannot
(func $efix (result f32)
(local $x f32)
loop $l0
(if (i32.eqz (global.get $iz))(then
(f32.sub (f32.const 7.69711) (call $log (call $uni)))
return
))
(local.set $x (f32.mul
(f32.convert_i32_u (global.get $jz))
(call $we_read (global.get $iz))
))
(if (f32.lt
(f32.add
(call $fe_read (global.get $iz))
(f32.mul
(call $uni)
(f32.sub
(call $fe_read (i32.sub (global.get $iz) (i32.const 1) ) )
(call $fe_read (global.get $iz) )
)
)
)
(call $exp (f32.neg (local.get $x)))
)(then
(local.get $x)
return
))
(global.set $jz (call $shr3))
(global.set $iz (i32.and (global.get $jz) (i32.const 255) ))
(if (i32.lt_u (global.get $jsr) (call $ke_read (global.get $iz) ) )(then
(f32.mul
(f32.convert_i32_u (global.get $jz))
(call $we_read (global.get $iz))
)
return
))
(br $l0)
end
(f32.const 0)
)
;; the main gaussian randomness function
(func $rnor (result f32)
(local $fhz f32)
(global.set $hz (call $shr3))
(global.set $iz (i32.and (global.get $hz) (i32.const 127) ))
(local.set $fhz (f32.convert_i32_s (global.get $hz)))
(if (i32.lt_u
(i32.trunc_f32_u (f32.abs (local.get $fhz)))
(call $kn_read (global.get $iz))
)(then
(f32.mul
(local.get $fhz)
(call $wn_read (global.get $iz))
)
return
)(else
(call $nfix)
return
))
(f32.const 0)
return
)
;; the main exponential randomness function
(func $rexp (result f32)
(global.set $jz (call $shr3))
(global.set $iz (i32.and (global.get $jz) (i32.const 255) ))
(if (i32.lt_u
(global.get $jz)
(call $kn_read (global.get $iz))
)(then
(f32.mul
(f32.convert_i32_u (global.get $jz))
(call $we_read (global.get $iz))
)
return
)(else
(call $efix)
return
))
(f32.const 0)
return
)
;; This procedure sets the seed and creates the tables
(func $zigset (param $jsrseed i32)
(local $m1 f32) (local $m2 f32)
(local $dn f32) (local $tn f32) (local $vn f32) (local $q f32)
(local $de f32) (local $te f32) (local $ve f32)
(local $i i32)
(local.set $m1 (f32.const 2147483648.0))
(local.set $m2 (f32.const 4294967296.0))
(local.set $dn (f32.const 3.442619855899))
(local.set $tn (local.get $dn))
(local.set $vn (f32.const 9.91256303526217e-3))
(local.set $de (f32.const 7.697117470131487))
(local.set $te (local.get $de))
(local.set $ve (f32.const 3.949659822581572e-3))
(global.set $jsr (local.get $jsrseed))
;; Tables for RNOR
(local.set $q (f32.div (local.get $vn)
(call $exp
(f32.mul (f32.mul (f32.const -0.5) (local.get $dn)) (local.get $dn))
)
))
(call $kn_write (i32.const 0)
(i32.trunc_f32_u (f32.mul
(f32.div (local.get $dn) (local.get $q))
(local.get $m1)
))
)
(call $kn_write (i32.const 1) (i32.const 0))
(call $wn_write (i32.const 0)
(f32.div (local.get $q) (local.get $m1) )
)
(call $wn_write (i32.const 127)
(f32.div (local.get $dn) (local.get $m1) )
)
(call $fn_write (i32.const 0) (f32.const 1.0))
(call $fn_write (i32.const 127)
(call $exp
(f32.mul (f32.mul (f32.const -0.5) (local.get $dn)) (local.get $dn))
)
)
(local.set $i (i32.const 126))
loop $l0
(local.set $dn
(f32.sqrt (f32.mul
(f32.const -2)
(call $log (f32.add
(f32.div (local.get $vn) (local.get $dn))
(call $exp
(f32.mul (f32.mul (f32.const -0.5) (local.get $dn)) (local.get $dn))
)
))
))
)
(call $kn_write (i32.add (local.get $i) (i32.const 1)) (i32.trunc_f32_u
(f32.mul (f32.div (local.get $dn) (local.get $tn)) (local.get $m1))
))
(local.set $tn (local.get $dn))
(call $fn_write (local.get $i)
(call $exp
(f32.mul (f32.mul (f32.const -0.5) (local.get $dn)) (local.get $dn))
)
)
(call $wn_write (local.get $i)
(f32.div (local.get $dn) (local.get $m1))
)
(local.set $i (i32.sub (local.get $i) (i32.const 1) ))
(br_if $l0 (i32.gt_s (local.get $i) (i32.const 0)))
end
;; Tables for REXP
(local.set $q (f32.div (local.get $ve)
(call $exp
(f32.neg (local.get $de))
)
))
(call $ke_write (i32.const 0)
(i32.trunc_f32_u (f32.mul
(f32.div (local.get $de) (local.get $q))
(local.get $m2)
))
)
(call $ke_write (i32.const 1) (i32.const 0))
(call $we_write (i32.const 0)
(f32.div (local.get $q) (local.get $m2) )
)
(call $we_write (i32.const 255)
(f32.div (local.get $de) (local.get $m2) )
)
(call $fe_write (i32.const 0) (f32.const 1.0))
(call $fe_write (i32.const 255)
(call $exp (f32.neg (local.get $de)))
)
(local.set $i (i32.const 254))
loop $l1
(local.set $de (f32.neg
(call $log (f32.add
(f32.div (local.get $ve) (local.get $de))
(call $exp (f32.neg (local.get $de)) )
))
))
(call $ke_write (i32.add (local.get $i) (i32.const 1) ) (i32.trunc_f32_u
(f32.mul (f32.div (local.get $de) (local.get $te) ) (local.get $m2) )
))
(local.set $te (local.get $de))
(call $fe_write (local.get $i) (call $exp (f32.neg (local.get $de))))
(call $we_write (local.get $i) (f32.div (local.get $de) (local.get $m2)))
(local.set $i (i32.sub (local.get $i) (i32.const 1) ))
(br_if $l1 (i32.gt_s (local.get $i) (i32.const 0)))
end
)
;; set random seed
(func $seed (param $jsrseed i32)
(global.set $jsr (local.get $jsrseed))
)
;; exported API's
(export "mem" (memory $mem ))
(export "fmod" (func $fmod ))
(export "log" (func $log ))
(export "cos" (func $cos ))
(export "exp" (func $exp ))
(export "shr3" (func $shr3 ))
(export "pnoise" (func $pnoise ))
(export "pnseed" (func $pnseed ))
(export "pndetail" (func $pndetail ))
(export "uni" (func $uni ))
(export "rnor" (func $rnor ))
(export "rexp" (func $rexp ))
(export "zigset" (func $zigset ))
(export "seed" (func $seed ))
)