-
Notifications
You must be signed in to change notification settings - Fork 29
/
build.gradle
207 lines (172 loc) · 6.76 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: 'signing'
sourceCompatibility = 8
targetCompatibility = 8
repositories {
mavenCentral()
}
dependencies {
// https://mvnrepository.com/artifact/org.apache.jmeter/ApacheJMeter_core
implementation('org.apache.jmeter:ApacheJMeter_core:3.1') {
transitive = false // Just avoid downloading half the internet
}
implementation('org.apache.jmeter:ApacheJMeter_components:3.1') {
transitive = false // Just avoid downloading half the internet
}
implementation('org.apache.jmeter:ApacheJMeter_http:3.1') {
transitive = false // Just avoid downloading half the internet
}
// https://mvnrepository.com/artifact/org.apache.jmeter/jorphan
implementation('org.apache.jmeter:jorphan:3.1') {
transitive = false
}
// https://mvnrepository.com/artifact/logkit/logkit
implementation('logkit:logkit:2.0') {
transitive = false
}
// https://mvnrepository.com/artifact/commons-io/commons-io
implementation('commons-io:commons-io:2.5') {
transitive = false
}
testImplementation('junit:junit:4.12')
testImplementation('org.mockito:mockito-core:2.2.15')
testImplementation('avalon-framework:avalon-framework:4.1.4')
testImplementation('org.assertj:assertj-core:3.8.0')
}
sourceSets {
main {
resources {
srcDir "${buildDir}/generated"
exclude 'sources/**'
}
}
}
version = 'dev'
task determineVersion {
doLast {
def proc = "git describe --exact-match HEAD".execute()
proc.waitFor()
if (proc.exitValue()) {
logger.quiet("Building development version.")
} else {
def versionTag = proc.in.readLines()[0]
// Check that tag matches format like v0.1.2.beta or 1.0 (OSGi version syntax)
if (versionTag ==~ /v?[0-9]+(\.\d+){1,2}(\.[\w\d_-]+)?/) {
if (versionTag.startsWith("v")) {
versionTag = versionTag[1..-1]
}
logger.quiet("Building version ${versionTag}.")
project.version = versionTag
ext.versionDir = new File("${buildDir}", "generated/eu/luminis/jmeter/wssampler")
versionDir.mkdirs()
new File(versionDir, "version.properties").text = versionTag
} else {
logger.error("Version tag '${versionTag}' does not contain a valid version.");
}
}
}
}
compileJava.dependsOn (determineVersion, processResources)
test {
testLogging {
afterSuite { desc, result ->
if (!desc.parent) { // will match the outermost suite
println "Test results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
}
}
}
}
task publishToJMeterLocal(dependsOn: jar) {
def pluginName = rootProject.name // "JMeterWebSocketSamplers"
doLast {
def jmeterHome = System.getenv('JMETER_HOME') // Gradle has case sensitivity
if (jmeterHome == null || jmeterHome.trim().isEmpty()) {
throw new GradleException("To install the plugin please specify `JMETER_HOME` enviroment variable")
} else {
logger.quiet("jmeter_home: " + jmeterHome)
}
def jmeterExtPath = java.nio.file.Paths.get(jmeterHome, "lib", "ext")
if (!java.nio.file.Files.exists(jmeterExtPath)) {
throw new GradleException("Please specify valid `JMETER_HOME` enviroment variable, lib/ext subdirectory " +
"should exist but it's not: " + jmeterExtPath)
}
def jmeterExtDir = jmeterExtPath.toAbsolutePath().toString()
def installedProdVersion = java.nio.file.Files.list(jmeterExtPath)
.map { path -> path.toFile() }
.filter { file -> file.isFile() }
.filter { file -> file.name.matches(pluginName + ".*\\.jar") }
.filter {file -> !file.name.equalsIgnoreCase(pluginName + "-dev.jar") }
.collect()
if (!installedProdVersion.isEmpty()) {
def prodFilesNames = installedProdVersion.stream().map { file -> file.name }.collect()
throw new GradleException('Found other versions of the plugin in lib/ext directory, collision may ocure: '
+ prodFilesNames + ". It's recommended to remove them from " + jmeterExtPath + " before publising current dev version.")
}
logger.quiet("installing the plugin into " + jmeterExtDir)
copy {
from "build/libs"
into jmeterExtDir
include "*-dev.jar"
}
}
}
configure(publishToJMeterLocal) {
group = 'publishing'
description = 'Publish development version into local JMeter'
}
group = 'net.luminis.jmeter'
java {
withJavadocJar()
withSourcesJar()
}
javadoc {
options.addStringOption('link', 'https://docs.oracle.com/javase/8/docs/api/')
}
publishing {
publications {
mavenJava(MavenPublication) {
artifactId = 'jmeter-websocket-samplers'
from components.java
pom {
name = 'JMeter WebSocket Samplers'
description = 'JMeter add-on that defines a number of samplers for load testing WebSocket applications.'
url = 'https://bitbucket.org/pjtr/jmeter-websocket-samplers'
licenses {
license {
name = 'GNU Lesser General Public License v3'
url = 'https://www.gnu.org/licenses/lgpl-3.0-standalone.html'
distribution = 'repo'
}
}
developers {
developer {
id = 'peterd'
name = 'Peter Doornbosch'
email = 'peter.doornbosch@luminis.eu'
organization = 'Luminis'
organizationUrl = 'http://www.luminis.eu'
}
}
scm {
connection = 'scm:git:git://bitbucket.org/pjtr/jmeter-websocket-samplers.git'
developerConnection = 'scm:git:ssh://bitbucket.org:pjtr/jmeter-websocket-samplers.git'
url = 'https://bitbucket.org/pjtr/jmeter-websocket-samplers/src'
}
}
}
}
repositories {
maven {
url = "https://oss.sonatype.org/service/local/staging/deploy/maven2/"
credentials {
username = project.properties.ossrhUsername
password = project.properties.ossrhPassword
}
}
}
}
signing {
sign publishing.publications.mavenJava
}