escape room project (Adafruit_NeoPixel to NeoPixelBus)

[rheinecatsin]

Hi!

So a few months ago someone asked me to do an escape room inside a 4story tall wizard tower. And I said yes.
Let put a locked chest on top and people will have to solve puzzles to remove magical protection on it before they can open it.

I didn't know how to code. I had never soldered. I had never used resin.
Not a single thing I did didnt hit the fan or took at least 3x the time it should've had.
Learning the hard way...

And now I have 3 different games that can open a lock chest.

But... one of them doesn't work. Well, it does. it's just that it can't send the data proving it does.
Of course, you know I'm talking about the one that uses neopixels.

Because Wifi and Neopixels don't mix well.

Until I found this librairy... 1 week before my deadline.
But I am so exhausted...

All I want is to move my code from the Neopixel standard librairy (not even using fastLed) to neopixelbus.
My code is very ugly cause I'm a nurse, not a coder.
But it's simple. 5 neopixels strips with 6-8 LEDs, incased in a resin crystal. Each are of different color and attached to a potentiometer and all is cast inside a wooden box.
Once you adjust lights and find the proper combinaison, all lights turn to white, a marker is flagged and data is sent via ESPNOW to receiver to remove one layer of magical protection from the chest.

Or so I thought.
CAuse, ofc, it's not working.
Espnow gives datafailure debug message all the time.

But... there is a new hope!

NeoPixelBus!!!

Can anyone PLEASE help me migrate my code from the standard librairy to NPB? It should be real easy.... i'm just really exhausted.
And probably tell me if i need to adjust the wiring (pots from GPIO 32,33,34,35,39 and Neopixels GPIO 5, 16,17,18,19)
I'm using and ESP32-DevKitC-32UE v4.

Thank you !

[rheinecatsin]

ACtually, in this version, the leds start blinking when the proper combination is entered.

`// Include Libraries
  #include <esp_now.h>
  #include <WiFi.h>
  #include <Arduino.h>
  #include <Adafruit_NeoPixel.h>

  #define NUM_STRIPS 5
  const int ledPins[NUM_STRIPS] = {5, 16, 17, 18, 19};
  const int potentiometerPins[NUM_STRIPS] = {33, 32, 35, 34, 39};
  const int brightnessDivisor = 512;
  const int blinkDelay = 500; // Delay between LED blinks

  // Number of LEDs per strip
  const int numLEDs = 8;

  // Window thresholds for each potentiometer
  const int windowMin[NUM_STRIPS] = {1, 4, 7, 3, 2};
  const int windowMax[NUM_STRIPS] = {1, 4, 7, 3, 2};

  // Variables for test data
  int ident = 1;
  bool bool_value = false;

  // MAC Address of responder - edit as required
  uint8_t broadcastAddress[] = {0xe0, 0x5a, 0x1b, 0x6b, 0x85, 0x08};

  // Define a data structure
  typedef struct struct_message {
    int b;
    bool d;
  } struct_message;

  // Create a structured object
  struct_message myData;

// NeoPixel strip initialization
Adafruit_NeoPixel strip[NUM_STRIPS] = {
  Adafruit_NeoPixel(numLEDs, ledPins[0], NEO_GRB + NEO_KHZ800),
  Adafruit_NeoPixel(numLEDs, ledPins[1], NEO_GRB + NEO_KHZ800),
  Adafruit_NeoPixel(numLEDs, ledPins[2], NEO_GRB + NEO_KHZ800),
  Adafruit_NeoPixel(numLEDs, ledPins[3], NEO_GRB + NEO_KHZ800),
  Adafruit_NeoPixel(numLEDs, ledPins[4], NEO_GRB + NEO_KHZ800)
};

  // LED state array
  bool ledState[NUM_STRIPS][numLEDs] = {{0}};


  // Peer info
  esp_now_peer_info_t peerInfo;

  // Callback function called when data is sent
  void OnDataSent(const uint8_t *mac_addr, esp_now_send_status_t status) {
    Serial.print("\r\nLast Packet Send Status:\t");
    Serial.println(status == ESP_NOW_SEND_SUCCESS ? "Delivery Success" : "Delivery Fail");
  }

  void setup() {
    // Set up Serial Monitor
    Serial.begin(115200);

    // Set ESP32 as a Wi-Fi Station
    WiFi.mode(WIFI_STA);

    // Initialize ESP-NOW
    if (esp_now_init() != ESP_OK) {
      Serial.println("Error initializing ESP-NOW");
      return;
    }

    // Register the send callback
    esp_now_register_send_cb(OnDataSent);

    // Register peer
    memcpy(peerInfo.peer_addr, broadcastAddress, 6);
    peerInfo.channel = 0;
    peerInfo.encrypt = false;

    // Add peer
    if (esp_now_add_peer(&peerInfo) != ESP_OK) {
      Serial.println("Failed to add peer");
      return;
    }

    // Initialize NeoPixel strips
    for (int i = 0; i < NUM_STRIPS; i++) {
      strip[i].begin();
      strip[i].show(); // Initialize all pixels in the strip to off
    }
  }

  bool updatePotentiometers() {
    bool allInWindow = true; // Flag to check if all potentiometer values are within their respective windows
    int potentiometerValues[NUM_STRIPS];

    for (int i = 0; i < NUM_STRIPS; i++) {
      potentiometerValues[i] = analogRead(potentiometerPins[i]); // Read the analog value from the potentiometer pin

      if ((potentiometerValues[i] / brightnessDivisor) < windowMin[i] || (potentiometerValues[i] / brightnessDivisor) > windowMax[i]) {
        // Potentiometer value is outside the window
        allInWindow = false; // Set the flag to false indicating that at least one potentiometer value is outside its window
      }

      Serial.print("Potentiometer ");
      Serial.print(i + 1);
      Serial.print(" value: ");
      Serial.println(potentiometerValues[i]); // Print the potentiometer value to the serial monitor
    }

    bool const blinkIsOn = (millis() / blinkDelay) % 2 == 0; // Alternate blink by dividing current millis and checking if result is even or odd
    for (int i = 0; i < NUM_STRIPS; i++) {
      if (allInWindow) {
        // Only blink LEDs that are already lit up based on the brightness variable
        for (int j = 0; j < numLEDs; j++) {
          if (ledState[i][j]) {
            if (blinkIsOn) {
          //strip[i].setPixelColor(j, 255, 255, 255); // Set the LEDs in the strip to white for the lit up LEDs
            strip[0].setPixelColor(j, 255, 0, 0);   // Red color for the first strip
            strip[1].setPixelColor(j, 0, 255, 0);   // Green color for the second strip
            strip[2].setPixelColor(j, 0, 0, 255);   // Blue color for the third strip
            strip[3].setPixelColor(j, 255, 255, 0); // Yellow color for the fourth strip
            strip[4].setPixelColor(j, 255, 0, 255); // Magenta color for the fifth strip
                        } 
            else {
              strip[i].setPixelColor(j, 0, 0, 0); // Set the LEDs in the strip to off for the lit up LEDs
            }
          }
        }
        strip[i].show(); // Update the strip with the new LED colors
      } else {
        int brightness = potentiometerValues[i] / brightnessDivisor; // Calculate the number of LEDs to light based on the potentiometer value
        for (int j = 0; j < numLEDs; j++) {
          if (j < brightness) {
            strip[0].setPixelColor(j, 255, 0, 0);   // Red color for the first strip
            strip[1].setPixelColor(j, 0, 255, 0);   // Green color for the second strip
            strip[2].setPixelColor(j, 0, 0, 255);   // Blue color for the third strip
            strip[3].setPixelColor(j, 255, 255, 0); // Yellow color for the fourth strip
            strip[4].setPixelColor(j, 255, 0, 255); // Magenta color for the fifth strip
            ledState[i][j] = true; // Update the LED state to lit up
          } else {
            strip[i].setPixelColor(j, 0, 0, 0); // Set the remaining LEDs in the strip to off
            ledState[i][j] = false; // Update the LED state to off
          }
        }
        strip[i].show(); // Update the strip with the new LED colors
        Serial.print("Brightness ");
        Serial.print(i + 1);
        Serial.print(": ");
        Serial.println(brightness); // Print the calculated brightness to the serial monitor
      }
    }
    return allInWindow;
  }

  void loop() {
    // Create test data
    bool isInRange = updatePotentiometers();
    // Invert the boolean value
    bool_value = isInRange;

    // Format structured data
    myData.b = ident;
    myData.d = bool_value;

    // Send message via ESP-NOW
    esp_err_t result = esp_now_send(broadcastAddress, (uint8_t *)&myData, sizeof(myData));

    if (result == ESP_OK) {
      Serial.println("Sending confirmed");
    } else {
      Serial.println("Sending error");
    }

    Serial.print("isInRange: ");
    Serial.println(isInRange ? "true" : "false"); // Update this line

    delay(250);
  }`

[Makuna]

First thing, how to convert the strip definition from Adafruit to NeoPixelBus.
These sections of existing code,

#include <Adafruit_NeoPixel.h>

...

// NeoPixel strip initialization
Adafruit_NeoPixel strip[NUM_STRIPS] = {
Adafruit_NeoPixel(numLEDs, ledPins[0], NEO_GRB + NEO_KHZ800),
Adafruit_NeoPixel(numLEDs, ledPins[1], NEO_GRB + NEO_KHZ800),
Adafruit_NeoPixel(numLEDs, ledPins[2], NEO_GRB + NEO_KHZ800),
Adafruit_NeoPixel(numLEDs, ledPins[3], NEO_GRB + NEO_KHZ800),
Adafruit_NeoPixel(numLEDs, ledPins[4], NEO_GRB + NEO_KHZ800)
};

Will change to this...

#include <NeoPixelBus.h>

...

// NeoPixel strip initialization
typedef NeoPixelBus<NeoGrbFeature,NeoEsp32I2s1X8Ws2812xMethod>  NeoPixel;
NeoPixel strip[NUM_STRIPS] = {
NeoPixel(numLEDs, ledPins[0]),
NeoPixel(numLEDs, ledPins[1]),
NeoPixel(numLEDs, ledPins[2]),
NeoPixel(numLEDs, ledPins[3]),
NeoPixel(numLEDs, ledPins[4])
};

[Makuna]

Next, general method names are the same, but NeoPixelBus methods will start with a capital letter.
strip.show() becomes strip.Show(). strip.begin() becomes strip.Begin()

The last thing is that the method SetPixelColor takes a color object instead of separate RGB values. Not really a big deal as you just wrap those parameters with the RgbColor constructor. So...

strip[0].setPixelColor(j, 255, 0, 0);   // Red color for the first strip

will become...

strip[0].SetPixelColor(j, RgbColor(255, 0, 0));   // Red color for the first strip

I think that covers it.

[rheinecatsin]

Thank you!!!!

I did the change you suggested.
Code is working, but i'm still getting a delivery fail status.
I tried to increase delay between dataSent package, and didn't work either.
I tried not to use any ADC2 GPIO.

Do you know what else would i need to change that could create conflict with Neopixel and WiFi?

[Makuna]

NeoPixelBus should never effect WiFi, it's the other way around, using WiFi "could" effect NeoPixelBus.
If you are getting WiFi issues, then first narrow the scope of the issue. Comment out different "pieces". Like comment out the "Show()" calls and see what happens.
Sounds like you already tried doing this with the ADC.

[Makuna]

@rheinecatsin Did you confirm that the Mac Address was updated to the one that your receiver has?

This line needs to be changed to one that your receiver board has.

  uint8_t broadcastAddress[] = {0xe0, 0x5a, 0x1b, 0x6b, 0x85, 0x08};

Note, while not critical, it usually not a good idea to share mac addresses publicly. ;-)

The examples have a few things your sketch does not. They have the following between the WiFi.mode(WIFI_STA); and the esp_now_init()

esp_wifi_set_channel(CHANNEL, WIFI_SECOND_CHAN_NONE);
WiFi.disconnect();

[rheinecatsin]

Yeah, MAC address is working, tested with another "white" EPS32 with very simple sketch. And no, the real one is not the one I posted ;) In anycase, its to be used in a no Internet access area (deep in the forest).

Yeah, Channel is defined somewhere else in the code (set to 0).
I've never user WiFi.disconnect(); and it has always worked. I have tried using the EXACT format ofmy esp-now code in this example as I did on another example for which the ESP-NOW protocol works just fine. Which do not use the wifi.disconnect fonction. So that's why I suspect something else than ESP-NOW config is buggy.

AFter triple checking it all, I asked ChatGPT if there was anything wrong with mycode and it didn't find anything wrong or different between the working code and the one that is not working. I am not good at spotting mistakes in code, not rigourus enough I guess. But still...

As I mentionned, i tried using another board to send the exact same data to the receiver but from a very simple sketch with no attachement to the ESP32 and that worked. So it's def not the mac adress and not the receiver getting data from more than 1 source or any received related reason. It really seems to be from the transmitter and I suspect it's not the code.

I was about to change board, just in case the wifi antenna is not working on that specific board that I used. But I have had connectivity issues for the last few weeks where IDE doesn't detect the boards sometime. It's so frustrating not being able to update code. I finally got tired of fighthing over this and I just bought 3 new ESP32 today and I didn't had that problem a few weeks agi. Ill see tomorow how they work. But I doubt the problem is such a basic hardward thing either.

Which leaves me to either a conflict between the neopixel code and the esp-now one. I really doupt it, as I am trying to do the exact same thing as I did on the other example (which uses RFID). Or a conflict which hardwares.

I read stories about people having problem as me (one youtube in particular about Neopixel and Esp-Now, but i don't like that guy very much, I don't think he is very good at it) which brought me to you as some guy linked NeoPixelBus as a way to resolve the problem.

Maybe increasing voltage (im not at 4.5V on the 5V entry of the ESP32, the neopixel works just fine).

Thanks alot for your support!

[Makuna]

Something else to consider, how are you powering your NeoPixels? Do not use the ESP32 boards 5v to power your pixels, use an external power connection, 8 pixels x 5 strips = 2000mA; so you will need a 2A power supply just for the NeoPixels. Most Arduinos react weird in sagging power, and the ESP32 will draw peaks of near 800ma when using WiFi radio itself.

[rheinecatsin]

yeah! I should really do this... I pretty much only ever have like... 18 leds at the same time since the game is to light up the right number of leds for each color (winning combination is 7 4 1 3 2) . So most LEDS are turned off most of the time, and lit up upon using the potentiometers. Board is currently working well on 4 1,5v hook directly in it. (now volt around 4,5) . So i will try using a secondary battery source just for the LED, just in case. Since this is what I need to do now! thanks for the advice.

[rheinecatsin]

So i bough a new board (a bit different but still an ESP32 with 40 pins).
Bought a new USB cable, cause you know...
And using the NeoPixelBus.

PLugged in only voltage from USB port and data was sending succesfully.
Started adding 1 pots+neopixel at a time.
I ended up with some delivery failure once upon a time. Especially when i brought 1 pots up to max value. Board didn't like it at all!
But after all five pots and neopixels were hooked up, data was still showed as sent successfully.
So i tried setting it to the winning configuration (1 4 7 3 2)...
And it worked!
The LED inside the chest (i.e. attached to the receiver board) turned off!!!
I repeated the experience while hooked up to batteries... neopixel didn'T adjust to pots... those are getting old.
So I replaced the batteries (4x1,5v) and every was now fine and dandy!!!

I suppose it really was the antenna... or the board itself.

In everycases, it is now WOKRING!!!!

Now i just hope my machines are going to survive the 2hours road trip awaiting them!!

Thank you very very very much Makuna for your support in this. I would've been devastated not to be able to do this game after spending soooooooooo many hours building it all up.

Well... until something else crashes again!

:)))