build.gradle

buildscript {

    repositories {
        jcenter()
        mavenCentral()
        maven { url 'https://dl.bintray.com/kotlin/kotlin-eap' }
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "gradle.plugin.org.jetbrains.intellij.plugins:gradle-intellij-plugin:0.2.5"
    }
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'idea'
apply plugin: 'org.jetbrains.intellij'

group 'de.monticore.lang.montisecarc.generator'
version '1.0-SNAPSHOT'

intellij {
    pluginName name
    version ideaVersion

    downloadSources Boolean.valueOf(downloadIdeaSources)
    updateSinceUntilBuild = false

    sandboxDirectory = "${rootProject.buildDir}/idea-sandbox"

    plugins = ['de.monticore.lang.montisecarc.MontiSecArcLanguagePlugin:0.8.10.SNAPSHOT', 'com.neueda4j.intellij.plugin.cypher:2.4.1']
}

sourceCompatibility = 1.8

sourceSets {
    main {
        java.srcDirs "gen", "src/java"
        kotlin.srcDirs "src/kotlin"
        resources.srcDir "resources"
    }
}

project.afterEvaluate {

    def prepareSandboxTask = project.tasks.findByName("prepareSandbox")
    prepareSandboxTask.doLast {

        def libFiles = new File("$prepareSandboxTask.destinationDir/${project.name}/lib/")
        libFiles.listFiles().each {

            if (it.name.contains("kotlin")) {
                delete(it)
            }
        }
    }
}

tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlinVersion"
    testCompile group: 'junit', name: 'junit', version: '4.11'

    compile project(':IntelliJ_MSA')
}