From 2542e05220fd13f4dc35e423193b0501d2e066f9 Mon Sep 17 00:00:00 2001
From: GenericNerdyUsername <genericnerdyusername@proton.me>
Date: Sat, 28 Jan 2023 14:42:01 +0000
Subject: [PATCH] riscv-gnu-toolchain-rv32gc, riscv-gnu-toolchain-rv64gc,
 riscv-gnu-toolchain-rv64gc-linux: init at 2023.01.04

---
 .../compilers/riscv-gnu-toolchain/default.nix | 99 +++++++++++++++++++
 .../riscv-gnu-toolchain/no-dot-git.patch      | 14 +++
 pkgs/top-level/all-packages.nix               | 15 +++
 3 files changed, 128 insertions(+)
 create mode 100644 pkgs/development/compilers/riscv-gnu-toolchain/default.nix
 create mode 100644 pkgs/development/compilers/riscv-gnu-toolchain/no-dot-git.patch

diff --git a/pkgs/development/compilers/riscv-gnu-toolchain/default.nix b/pkgs/development/compilers/riscv-gnu-toolchain/default.nix
new file mode 100644
index 0000000000000..f0ed24adad46d
--- /dev/null
+++ b/pkgs/development/compilers/riscv-gnu-toolchain/default.nix
@@ -0,0 +1,99 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, fetchurl
+
+, gcc12
+, glibc
+, newlib
+, gdb
+, qemu
+, musl
+, spike
+, riscv-pk
+
+, autoconf
+, curl
+, automake
+, python3
+, libmpc
+, gawk
+, bison
+, flex
+, texinfo
+, gperf
+, libtool
+, expat
+, gmp
+, mpfr
+, flock
+, zlib
+
+, srcs ? {
+  binutils = {
+    url = "mirror://gnu/binutils/binutils-2.39.tar.bz2";
+    hash = "sha256-2iSoT+8iAQLdJAQt8G/eqFHCYUpTd/hu/6KPM7exYUg=";
+  };
+  dejagnu = {
+    url = "mirror://gnu/dejagnu/dejagnu-1.6.3.tar.gz";
+    hash = "sha256-h9rvrNeVi0pp+IxoVtvRY0JhljxBQHnQw3H1ic1mouM=";
+  };
+  gcc = gcc12.cc.src;
+  glibc = glibc.src;
+  newlib = newlib.src;
+  gdb = gdb.src;
+  qemu = qemu.src;
+  musl = musl.src;
+  spike = spike.src;
+  pk = riscv-pk.src;
+}
+
+, isa ? "rv64gc"
+, withLinux ? false
+}:
+let
+
+extract = file: stdenv.mkDerivation {
+  name = file.name + "-unpacked";
+  src = file;
+  dontPatch = true;
+  dontConfigure = true;
+  dontBuild = true;
+  installPhase = "cp -r . $out";
+  dontFixup = true;
+};
+
+srcs_fetched = lib.mapAttrs (name: value: if value ? outPath then value else fetchurl value) srcs;
+srcs_extracted = lib.mapAttrs (name: value: extract value) srcs_fetched;
+srcFlags = lib.mapAttrsToList (name: value: "--with-${name}-src=${value}") srcs_extracted;
+
+in stdenv.mkDerivation rec {
+  pname = "riscv-gnu-toolchain-" + isa;
+  version = "2023.01.04";
+
+  src = fetchFromGitHub {
+    owner = "riscv-collab";
+    repo = "riscv-gnu-toolchain";
+    rev = version;
+    hash = "sha256-PXPQ/ho+fOudZRErnyQZTVFdceWGBF+geo+3y0tkNm4=";
+  };
+
+  nativeBuildInputs = [ autoconf automake flock curl python3 gawk bison flex texinfo gperf ];
+  buildInputs = [ libmpc libtool expat gmp mpfr zlib ];
+  hardeningDisable = [ "format" ];
+
+  patches = [ ./no-dot-git.patch ];
+  configureFlags = [
+    "--with-arch=${isa}"
+  ]
+  ++ srcFlags
+  ++ lib.optional withLinux "--enable-linux";
+
+  meta = with lib; {
+    homepage = "https://github.com/riscv-collab/riscv-gnu-toolchain";
+    description = "RISC-V C and C++ cross-compiler";
+    maintainers = with maintainers; [ genericnerdyusername ];
+    license = with licenses; [ bsd3 gpl2 lgpl21 ];
+    broken = stdenv.isDarwin;
+  };
+}
diff --git a/pkgs/development/compilers/riscv-gnu-toolchain/no-dot-git.patch b/pkgs/development/compilers/riscv-gnu-toolchain/no-dot-git.patch
new file mode 100644
index 0000000000000..a6c60ffe08d59
--- /dev/null
+++ b/pkgs/development/compilers/riscv-gnu-toolchain/no-dot-git.patch
@@ -0,0 +1,14 @@
+diff --git a/Makefile.in b/Makefile.in
+index 71369ab..53f5e0d 100644
+--- a/Makefile.in
++++ b/Makefile.in
+@@ -279,9 +279,6 @@ GCCPKGVER :=
+ endif
+ 
+ $(srcdir)/%/.git:
+-	cd $(srcdir) && \
+-	flock `git rev-parse --git-dir`/config git submodule init $(dir $@) && \
+-	flock `git rev-parse --git-dir`/config git submodule update $(dir $@)
+ 
+ #
+ # GLIBC
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 1fd2742e8d96e..a3219d19fb1c2 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -27088,6 +27088,21 @@ with pkgs;
 
   rfkill_udev = callPackage ../os-specific/linux/rfkill/udev.nix { };
 
+  riscv-gnu-toolchain-rv64gc-linux = callPackage ../development/compilers/riscv-gnu-toolchain {
+    isa = "rv64gc";
+    withLinux = true;
+  };
+
+  riscv-gnu-toolchain-rv64gc = callPackage ../development/compilers/riscv-gnu-toolchain {
+    isa = "rv64gc";
+    withLinux = false;
+  };
+
+  riscv-gnu-toolchain-rv32gc = callPackage ../development/compilers/riscv-gnu-toolchain {
+    isa = "rv32gc";
+    withLinux = false;
+  };
+
   riscv-pk = callPackage ../misc/riscv-pk { };
 
   ristate = callPackage ../tools/misc/ristate { };