build.gradle

plugins {
    id 'com.gradle.plugin-publish' version '1.2.0'
}

repositories {
    mavenCentral()
}

dependencies {
    implementation gradleApi()
    implementation "org.yaml:snakeyaml:${project.snakeyaml_version}"
    implementation "com.google.code.gson:gson:${project.gson_version}"
    implementation "com.google.guava:guava:${project.guava_version}"
    implementation "org.apache.commons:commons-lang3:${project.commons_lang3_version}"
}

javadoc {
    options.addStringOption('Xdoclint:none', '-quiet')
}

version = project.plugin_version
group = project.maven_group
archivesBaseName = project.archives_base_name

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

gradlePlugin {
    website = 'https://github.com/Fallen-Breath/yamlang'
    vcsUrl = 'https://github.com/Fallen-Breath/yamlang'
    plugins {
        yamlangPlugin {
            id = 'com.redenmc.yamlang'
            displayName = 'Yamlang'
            description = 'A gradle plugin to convert nestable yaml language file into plain json language file for Minecraft mods'
            implementationClass = 'me.fallenbreath.yamlang.YamlangPlugin'
            tags.set(['Minecraft', 'mod'])
        }
    }
}

def ENV = System.getenv()
publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }

    repositories {
        maven {
            url ENV.MAVEN_URL
            credentials {
                username ENV.MAVEN_USER
                password ENV.MAVEN_PASSWORD
            }
        }
    }
}