build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    repositories {
        mavenCentral()
        google()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:7.0.3"
        classpath 'com.vanniktech:gradle-maven-publish-plugin:0.18.0'
    }
}

allprojects {
    repositories {
        mavenCentral()
        google()
    }
    plugins.withId("com.vanniktech.maven.publish") {
        mavenPublish {
            sonatypeHost = "S01"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

subprojects {
    afterEvaluate {
        if (plugins.hasPlugin('com.vanniktech.maven.publish')) {
            if (it.parent == rootProject) {
                group = "${groupIdBase}"
            } else {
                group = "${groupIdBase}.${it.parent.name}"
            }
            version = android.defaultConfig.versionName
            println("${it.displayName}: ${group}:${it.name}:${version}")
        }
    }
}

ext {
    groupIdBase = "dev.rikka.ndk.thirdparty"

    POM_INCEPTION_YEAR = "2021"
    POM_PACKAGING = "aar"

    POM_URL = "https://github.com/RikkaW/libcxx-prefab"
    POM_SCM_URL = "https://github.com/RikkaW/libcxx-prefab"
    POM_SCM_CONNECTION = "scm:git@github.com:RikkaW/libcxx-prefab.git"
    POM_SCM_DEV_CONNECTION = "scm:git@github.com:RikkaW/libcxx-prefab.git"

    POM_LICENCE_NAME = "Apache License v2.0"
    POM_LICENCE_URL = "https://github.com/topjohnwu/libcxx/blob/master/LICENSE.TXT"
    POM_LICENCE_DIST = "repo"

    POM_DEVELOPER_ID = "rikka"
    POM_DEVELOPER_NAME = "Rikka"
    POM_DEVELOPER_URL = "https://github.com/RikkaW"
}