build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'maven-publish'

sourceCompatibility = 8
targetCompatibility = 8

version = '0.7.2.2'
group = 'com.github.imcdonagh'

repositories {
  mavenCentral()
}

dependencies {  
  testImplementation 'junit:junit:4.12'
}

def getDate() {
  def date = new Date()
  def formattedDate = date.format('yyyy-MM-dd HH:mm')
  return formattedDate
}

java {
    withJavadocJar()
    withSourcesJar()
}

jar {
  manifest {
    attributes "Build-Date": getDate()
    attributes "Implementation-Version": version
  }
}

tasks.withType(JavaCompile) { options.encoding = "UTF-8" }
tasks.withType(Javadoc).all { enabled = false }

sourceSets {  
  main {
    java {   
      srcDirs = ['src']
      include '**/*.java'
    }
    resources {
      srcDirs = ['src']
      exclude '**/*.java'
    }
  }
  
  test {
    java {   
      srcDirs = ['test']
      include '**/*.java'
    }
    resources {
      srcDirs = ['test']
      exclude '**/*.java'
    }
  }
}
publishing {
  repositories {
    maven {
      name = "PrivateRepo"
	  url = "${nexusRepo}"
	  credentials {
        username = "${nexusUser}"
        password = "${nexusPassword}"
      }
    }
    maven {
      name = "GitHubPackages"
      url = uri("https://maven.pkg.github.com/Schmidor/image4j")
      credentials {
        username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_USERNAME")
        password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
      }
    }
  }
  publications {
	maven(MavenPublication) {
	  artifactId = 'image4j'
	  from components.java
	  
	  pom {
	    name = 'image4J'
	    description ='The image4j library allows you to read and write certain image formats in 100% pure Java.'
        url = 'https://github.com/Schmidor/image4j'
        licenses {
          license {
            name = 'GNU Lesser General Public License, version 2.1'
            url = 'https://www.gnu.org/licenses/old-licenses/lgpl-2.1.html'
          }
        }
        scm {
          connection = 'git@github.com:Schmidor/image4j.git'
          developerConnection = 'git@github.com:Schmidor/image4j.git'
          url = 'https://github.com/Schmidor/image4j'
        }
      }
	}
  }
}