forked from pret/pokered
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathfade.asm
73 lines (66 loc) · 1.27 KB
/
fade.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
; These routines manage gradual fading
; (e.g., entering a doorway)
LoadGBPal::
ld a, [wMapPalOffset] ; tells if wCurMap is dark (requires HM5_FLASH?)
ld b, a
ld hl, FadePal4
ld a, l
sub b
ld l, a
jr nc, .ok
dec h
.ok
ld a, [hli]
ldh [rBGP], a
ld a, [hli]
ldh [rOBP0], a
ld a, [hli]
ldh [rOBP1], a
ret
GBFadeInFromBlack::
ld hl, FadePal1
ld b, 4
jr GBFadeIncCommon
GBFadeOutToWhite::
ld hl, FadePal6
ld b, 3
GBFadeIncCommon:
ld a, [hli]
ldh [rBGP], a
ld a, [hli]
ldh [rOBP0], a
ld a, [hli]
ldh [rOBP1], a
ld c, 8
call DelayFrames
dec b
jr nz, GBFadeIncCommon
ret
GBFadeOutToBlack::
ld hl, FadePal4 + 2
ld b, 4
jr GBFadeDecCommon
GBFadeInFromWhite::
ld hl, FadePal7 + 2
ld b, 3
GBFadeDecCommon:
ld a, [hld]
ldh [rOBP1], a
ld a, [hld]
ldh [rOBP0], a
ld a, [hld]
ldh [rBGP], a
ld c, 8
call DelayFrames
dec b
jr nz, GBFadeDecCommon
ret
FadePal1:: db %11111111, %11111111, %11111111
FadePal2:: db %11111110, %11111110, %11111000
FadePal3:: db %11111001, %11100100, %11100100
FadePal4:: db %11100100, %11010000, %11100000
; rBGP rOBP0 rOBP1
FadePal5:: db %11100100, %11010000, %11100000
FadePal6:: db %10010000, %10000000, %10010000
FadePal7:: db %01000000, %01000000, %01000000
FadePal8:: db %00000000, %00000000, %00000000