TCB0 Interrupts

[CreativeRobotics]

I'm new to the whole tiny AVR thing so I thought I would ask if I am doing something wrong in my code.

I am trying to use TCB0 to generate a periodic interrupt. I've got it configured and running, but the ISR doesn't seem to ever get called. Have I misunderstood what I am supposed to be doing here?

//ATTiny3217 (Curiosity Nano)
//8mhz clock
//a few constants for setting cntrla
const uint8_t TCB_CNTRLA_ON_8MHZ = 0x01;//Enabled, no prescaling, nothing else
const uint8_t TCB_CNTRLA_OFF_8MHZ = 0x00;
const uint8_t TCB_CNTRLA_ON_4MHZ = 0x11;
const uint8_t TCB_CNTRLA_OFF_4MHZ = 0x10;

volatile uint16_t isrCount;

void setup() {
  Serial.begin(115200);

  TCB0.CTRLA = TCB_CNTRLA_OFF_4MHZ; //starting configuration;
  TCB0.CTRLB = TCB_CNTMODE_INT_gc; //periodic int
  TCB0.CCMP = 0xFFFF; // Count all the way up to 0xFFFF
  TCB0.INTCTRL = 0x01; // enable periodic int
  TCB0.CTRLA = TCB_CNTRLA_ON_4MHZ; // enable the timer
  delay(500); //wait for serial port to reconnect
}

uint8_t n = 0;

void loop() {
  while(n < 10){
    //grab the count value
    uint16_t res = TCB0.CNT;
    n++;
    //Print the number of ISR's and the count value
    Serial.print("ISRs ");
    Serial.print(isrCount);
    Serial.print(" CNT ");
    Serial.println(res);
    delay(10);
  }
}

ISR(TCB0_INT_vect) {
  TCB0.INTFLAGS = 0x01;
  isrCount++;
}

[CreativeRobotics]

And just as I posted this I tried something and got it working - my TCB_CNTRLA_ON_8MHZ and TCB_CNTRLA_ON_4MHZ bit settings are wrong. If I set it to TCB_CNTRLA_ON_8MHZ then it suddenly starts working.

[hmeijdam]

Does it make any difference if you add

sei(); // turn on interrupts

at the end of setup?

I am just curious that you apparently don't need to do that.

[CreativeRobotics]

SEI() has no effect.
If I use these values for CNTRLA then it works:

const uint8_t TCB_CNTRLA_ON_8MHZ = 0x01;//Enabled, no prescaling, nothing else
const uint8_t TCB_CNTRLA_OFF_8MHZ = 0x00;
const uint8_t TCB_CNTRLA_ON_4MHZ = 0x101;
const uint8_t TCB_CNTRLA_OFF_4MHZ = 0x100;

BUT - neither option has any effect on the clock rate for the timer.

This is the result when using 8Mhz then 4Mhz

---------------START------------------
ISRs 61 CNT 7014
ISRs 183 CNT 18709
ISRs 305 CNT 31587
ISRs 427 CNT 44511
ISRs 549 CNT 57396
ISRs 672 CNT 4786
ISRs 794 CNT 17006
ISRs 916 CNT 29857
ISRs 1038 CNT 42745
ISRs 1160 CNT 56308
---------------START------------------
ISRs 61 CNT 7014
ISRs 183 CNT 18709
ISRs 305 CNT 31587
ISRs 427 CNT 44511
ISRs 549 CNT 57396
ISRs 672 CNT 4786
ISRs 794 CNT 17006
ISRs 916 CNT 29857
ISRs 1038 CNT 42745
ISRs 1160 CNT 56308

I'm wondering if I misunderstood something about the prescaler, or if there is some errata relating to the prescaler ...?

[CreativeRobotics]

I tried it with a 16Mhz internal clock instead of 8 and nothing changed apart from the isr counts doubled in size.

[hmeijdam]

I am confused what you try to accomplish here.

const uint8_t TCB_CNTRLA_ON_8MHZ = 0x01;//Enabled, no prescaling, nothing else
const uint8_t TCB_CNTRLA_OFF_8MHZ = 0x00;
const uint8_t TCB_CNTRLA_ON_4MHZ = 0x101;
const uint8_t TCB_CNTRLA_OFF_4MHZ = 0x100;

Or do you mean B00000101 where you type 0x101 ? The hexadecimal value 0x101 equates to the binary value 100000001 (decimal 257), which is bigger than the 8bit register you cast it into.

You are also setting the TCB0.CTRLA register twice during setup, so the second time you overwrite what you set the first time.

[CreativeRobotics]

Aghh! Yes. Stupid me! I had written them as binary, then switched to hex values - but kept writing them as binary like the dyslexic fool I am.

Thanks!

[hmeijdam]

This is probably what you want

//8mhz clock

volatile uint16_t isrCount;
uint8_t n = 0;

void setup() {
  Serial.begin(57600);
  TCB0_CTRLB = TCB_CNTMODE_INT_gc; //periodic int
  TCB0_CCMP = 0xFFFF; // Count all the way up to 0xFFFF
  TCB0_INTCTRL = TCB_CAPT_bm; // enable periodic int
//  TCB0_CTRLA = TCB_CLKSEL_CLKDIV2_gc | TCB_ENABLE_bm; //prescaler factor 2 | start timer;
  TCB0_CTRLA = TCB_CLKSEL_CLKDIV1_gc | TCB_ENABLE_bm; //No prescaler factor | start timer;
  delay(500); //wait for serial port to reconnect
}

void loop() {
  while(n < 20){
    //grab the count value
    uint16_t res = TCB0_CNT;
    n++;
    //Print the number of ISR's and the count value
    Serial.print("ISRs ");
    Serial.print(isrCount);
    Serial.print(" CNT ");
    Serial.println(res);
    delay(10);
  }
}

ISR(TCB0_INT_vect) {
  isrCount++;
  TCB0_INTFLAGS = 0x01;
}

[SpenceKonde]

Soundsl ike this is mostly sorted?

Do also note - if you're ever printing values and you want to get hexadecimal, you can pass a number to Serial.printHex() and Serial.printHexln() to get it printed out as hex. Depending on the datatype you pass it, it will pad it with zeros as appropriate. For datatypes larger than a byte, there's an optional second argument to swap the endianness too if you're getting bytes printed in the reverse of the order you want :-)

It's documented with all the other extensions to the Serial API in https://github.com/SpenceKonde/megaTinyCore/blob/master/megaavr/extras/Ref_Serial.md (I've exposed damned near every feature except 9-bit mode (too much overhead for people not using it), lin-constrained autobaud (because cars are life-safety critical and Arduino is not an appropriately rated for such applications; since the only application of LIN is in automotive stuff, supporting that mode would amount to encouraging unsafe operation that could endanger the user and those around them) and IRDA pulse encoding mode (didn't IRDA die decades ago?). We do support putting it into IRDA mode to use event input theoretically - it's never been tested AFAIK (and you have to do the event routing still. But, I think that this can remap rx to any pin, (and you can remap TX to any CCL output by using CCL.LUTnCTRLB = 0x08 and TRUTHn = 0x02 for USART0 (0x80 and 0x04 for USART1) assuming 2-series - I think the number is different on 1-series). And yeeah I think everything else the hardware can do is exposed through the API and I made it take up less space - though the effect is not visible on tiny0/1 on tiny2, the difference is small (it gets larger for each USART present - they had a copy of the ISR for each serial port, and the ISRs are not the smallest things around (though they're as small as I could get them as hand optimized assembly now) - and instead of having up to 6 identical USART ISRs, the ISR itself is declared as a naked, used function so it goes in if serial is used at all, but the thing pointed to by the vector? That's just a stub - it pushes a register or two so it can load a pointer to the USART struct, then rjmps to the single copy of the ISR which is tightly hand optimized, and which works around the errata impacting inconsistent sync field detection and the SFDEN bug too (you have to turn off SFDEN before reading the received data). The second RS232 mode (the one that they removed - at least on paper) where XDIR acts as an input, and control;s whether TX is enabled, has not been tested either. I suspect the reason it was dropped was because it didn't work all that well. It raises a bunch of paradoxes about how the chip should behave under corner cases, and thinking about it, I couldn't decide which one was less wrong. But you basically got a menu of bad options

[CreativeRobotics]

Yes, sorted thanks - just me being an idiot. I've only recently started using the ATTiny devices and MegaTinyCore but so far it looks like a fantastic distribution and I suspect I'll be using it quite a lot in the future so thanks for all the work you have put into it!
This project is me trying to get a Microchip DALI control gear lighting library to work, which needs two timers ...