shell.nix

#TODO create bcc dev guide 
# This file is used by nix-shell.
# It just takes the shell attribute from default.nix.
{ config ? {}
, sourcesOverride ? {}
, withHoogle ? true
, pkgs ? import ./nix {
    inherit config sourcesOverride;
  }
}:

with pkgs;
let
  # This provides a development environment that can be used with nix-shell or
  # lorri. See https://The-Blockchain-Company.github.io/haskell.nix/user-guide/development/
  shell = bccShellHaskellPackages.shellFor {
    name = "cabal-dev-shell";

    # If shellFor local packages selection is wrong,
    # then list all local packages then include source-repository-package that cabal complains about:
    packages = ps: with ps; [
       ps.bcc-shell
       ps.bcc-launcher
    ];

    # These programs will be available inside the nix-shell.
    buildInputs = (with haskellPackages; [
      profiteur
      weeder
    ]) ++ (with pkgs; [
      cabal-install
      ghcid
      git
      hlint
      niv
      nix
      pkgconfig
      sqlite-interactive
      tmux
    ]);

    # Prevents cabal from choosing alternate plans, so that
    # *all* dependencies are provided by Nix.
    exactDeps = true;

    inherit withHoogle;

    GIT_SSL_CAINFO = "${cacert}/etc/ssl/certs/ca-bundle.crt";
  };

  devops = pkgs.stdenv.mkDerivation {
    name = "devops-shell";
    buildInputs = [
      niv
    ];
    shellHook = ''
      echo "DevOps Tools" \
      | ${figlet}/bin/figlet -f banner -c \
      | ${lolcat}/bin/lolcat

      echo "NOTE: you may need to export GITHUB_TOKEN if you hit rate limits with niv"
      echo "Commands:
        * niv update <package> - update package

      "
    '';
  };

  localPkgs = import ./. { };

in

 shell // { inherit devops; }  // { inherit (localPkgs) runCoveralls; }