A Rotated Tiles Proof of Concept

[ProjectMobius13]

A proof of concept showing collision tiles rotated in the room editor working after a little tweaking. Full disclosure: there may be some edge cases I haven't found that result in some wonky behavior. It's also not the cleanest code, and there is likely a more elegant solution. But it works!

Here are the changes to the scripts needed to make this work:

function tile_get_width(_tiledata, _y)
{
	var _index = tile_get_index(_tiledata) % ENGINE_TILE_COUNT;
	
	if _index <= 0
	{
		return 0;
	}
	
	// Calculate width index
	var _width_index;
	
	var _tile_mode = tile_get_rotate(_tiledata) + (10*tile_get_mirror(_tiledata)) + (100*tile_get_flip(_tiledata));
	switch (_tile_mode)
	{
		/*
			Bits: [ Flip | Mirror | Rotate ]
		*/
		case 000: //Normal
		case 010: //Mirrored Horizontally: Height = Reverse Height
		case 001: //Rotated: Width = Height; Height = Reversed Width
		case 101: //Flipped and Rotated: Width = Height; Height = Width
			_width_index = _y % ENGINE_TILE_SIZE;
		break;
		
		case 100: //Flipped vertically: Width = Reverse Width
		case 110: //Flipped and Mirrored: Width = Reverse Width; Height = Reverse Height
		case 011: //Mirrored and Rotated: Width = Reversed Height; Height = Reversed Width
		case 111: //Flipped, Mirrored, and Rotated: Width = Reversed Height; Height = Width;
			_width_index = ENGINE_TILE_SIZE - 1 - _y % ENGINE_TILE_SIZE;
		break;
	}
	
	if tile_get_rotate(_tiledata)
	{
		return c_framework.collision.tile_height[_index][_width_index];
	}
	else
	{
		return c_framework.collision.tile_width[_index][_width_index];
	}
}

function tile_get_height(_tiledata, _x)
{
	var _index = tile_get_index(_tiledata) % ENGINE_TILE_COUNT;
	
	if _index <= 0
	{
		return 0;
	}
	
	// Calculate height index
	var _height_index;
	
	var _tile_mode = tile_get_rotate(_tiledata) + (10*tile_get_mirror(_tiledata)) + (100*tile_get_flip(_tiledata));
	switch (_tile_mode)
	{
		/*
			Bits: [ Flip | Mirror | Rotate ]
		*/
		case 000: //Normal
		case 100: //Flipped Vertically
		case 101: //Flipped and Rotated: Width = Height; Height = Width
		case 111: //Flipped, Mirrored, and Rotated: Width = Reversed Height; Height = Width;
			_height_index = _x % ENGINE_TILE_SIZE;
		break;
			
		case 010: //Mirrored Horizontally: Height = Reverse Height
		case 110: //Flipped and Mirrored: Height = Reverse Height
		case 001: //Rotated: Width = Height; Height = Reversed Width
		case 011: //Mirrored and Rotated: Width = Reversed Height; Height = Reversed Width
			_height_index = ENGINE_TILE_SIZE - 1 - _x % ENGINE_TILE_SIZE;
		break;
	}
	
	if tile_get_rotate(_tiledata)
	{
		return c_framework.collision.tile_width[_index][_height_index];
	}
	else
	{
		return c_framework.collision.tile_height[_index][_height_index];
	}
}

In both tile_find_h and tile_find_v, you will find this block of code:

	// Calculate final distance and angle
	var _flip = tile_get_flip(_tiledata);
	var _mirror = tile_get_mirror(_tiledata);
	var _ang = tile_get_angle(_tiledata);
	
	if _ang != ANGLE_EMPTY
	{
		if _ang > 0
		{
			if _flip
			{
				_ang = (540 - _ang) % 360;
			}
			if _mirror
			{
				_ang = 360 - _ang;
			}
		}
		else
		{
			_ang = _dir == DIRECTION.POSITIVE ? 90 : 270;
		}
	}

Replace it with:

	// Calculate final distance and angle
	var _flip = tile_get_flip(_tiledata);
	var _mirror = tile_get_mirror(_tiledata);
	var _ang = tile_get_angle(_tiledata);
	var _rot = tile_get_rotate(_tiledata);
	
	if _ang != ANGLE_EMPTY
	{
		if _ang > 0
		{
			if _flip
			{
				_ang = (540 - _ang) % 360;
			}
			if _mirror
			{
				_ang = 360 - _ang;
			}
			if _rot
			{
				_ang = (360 + _ang - 90) % 360;
			}
		}
		else
		{
			_ang = _dir == DIRECTION.POSITIVE ? 90 : 270;
		}
	}

And voilà! No more breaking when tiles are rotated in the room editor.

[TrianglyRU]

Oh wow, good stuff! Really clever usage of a bitmask

[ProjectMobius13]

Thanks!