Add new verbs and new syntax for existing ones

[heasm66]

    Verb 'tighten' 'tweak' 'unwind' 'wind' 'wrench'
        * noun                                              -> Turn
        * noun 'with' noun                                  -> TurnWith;

    Verb 'board' 'embark'
        * noun                                              -> Enter;

    Verb 'hang' 'mount'
        * noun 'on' noun                                    -> Insert
        * noun 'onto' noun                                  -> Insert
        * 'up' noun 'on' noun                               -> Insert
        * 'up' noun 'onto' noun                             -> Insert
        * noun 'up' 'on' noun                               -> Insert
        * noun 'up' 'onto' noun                             -> Insert;

    Verb 'kick'
        * noun                                              -> Attack;

    Extend 'dig' first
        *                                                   -> Dig;

    Extend 'dig' last
        * special                                           -> Dig;
        
    Extend 'drink' first
        *                                                   -> Drink;

   Extend 'attach' replace
        * noun                                              -> Repair
        * noun 'to' noun                                    -> Repair;

    Extend 'buy' first
        * special                                           -> Buy;

    Extend 'answer' first
        * 'lagach' 'to' noun                                -> Lagach;

    Extend 'answer' first
        *                                                   -> Shout;
        
    Extend 'attack' last
        * noun 'with' held                                  -> Kill;

    Extend 'turn' last
        * noun 'inside' 'out'                               -> Turn;

    Extend 'turn' last
        * noun 'around'                                     -> Turn;
        
    Extend 'turn' last
        * 'round' noun                                      -> Turn;

    Extend 'turn' last
        * noun 'to' topic                                   -> Consult;
        
    Extend 'lie' first
        *                                                   -> Lie;

    Extend 'lie' last
        * 'down' 'on' noun                                  -> Enter;

    Extend 'look' last
        * 'up' topic 'on' noun                              -> Consult;

    Extend 'look' last
        * 'up' topic                                        -> LookUp;

    Extend 'display' last
        * 'off'                                             -> Sing;

    Extend 'close' last
        * noun 'with' noun                                  -> CloseWith;

[ LieSub ;      
    "Whatever happened to truthfulness...";
];

[ ShoutSub ;    
    "Try ~help~ for details of how to speak to people.";
];

[ CloseWithSub ;      
    R_Process(##PutOn,second,noun);
    rtrue;
];

[ ConsultDefault o ;    
    if (Meldrewes_History in o) return Meldrewes_History;
    if (classical_dictionary in o) return classical_dictionary;
    if (ancient_prayer_book in o) return ancient_prayer_book;
    if (tourist_map in o) return tourist_map;
    return nothing;
];

[ LookUpSub o n ;       
    n = TryNumber(consult_from);
    if (n >= 0 && (tourist_map in player || tourist_map in location)) o = tourist_map;
    if (n >= 0 && (ancient_prayer_book in player || ancient_prayer_book in location)) o = ancient_prayer_book;
    if (o == nothing) o = ConsultDefault(player);
    if (o == nothing) o = ConsultDefault(location);
    if (o == nothing) "I can't see what you wish to consult.";
    print "(consulting ";
    Defart(o);
    print ")^";
    R_Process(##Consult,o);
    rtrue;
];