-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathSwanBraggScat.ftn90
1491 lines (1491 loc) · 55.2 KB
/
SwanBraggScat.ftn90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
! This file contains data and routines for Bragg scattering
!
module SwanBraggScat
!
! --|-----------------------------------------------------------|--
! | Delft University of Technology |
! | Faculty of Civil Engineering and Geosciences |
! | Environmental Fluid Mechanics Section |
! | P.O. Box 5048, 2600 GA Delft, The Netherlands |
! | |
! | Programmers: The SWAN team |
! --|-----------------------------------------------------------|--
!
!
! SWAN (Simulating WAves Nearshore); a third generation wave model
! Copyright (C) 1993-2024 Delft University of Technology
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
!
!
! Authors
!
! 41.80: Dirk Rijnsdorp and Ad Reniers
!
! Updates
!
! 41.80, September 2021: New module
!
! Purpose
!
! Contains data with respect to Bragg scattering
!
! Method
!
! MODULE construct
!
! Modules used
!
implicit none
!
! Module variables
!
integer :: mkbx ! size of wave number space in x-direction related to bottom spectrum
integer :: mkby ! size of wave number space in y-direction related to bottom spectrum
!
real :: dkbx ! resolution of wave number space in x-direction related to bottom spectrum
real :: dkby ! resolution of wave number space in y-direction related to bottom spectrum
!
real, dimension(:,:) , save, allocatable :: botspc ! bottom spectrum provided by the user
real, dimension(:) , save, allocatable :: dpmean ! mean depth at computational grid points
real, dimension(:,:,:) , save, allocatable :: fb ! bed elevation spectrum at computational grid points
real, dimension(:,:,:,:), save, allocatable :: fbdxy ! bottom spectrum at wave number difference k - k' for all computational grid points
!
! Source text
!
contains
!
subroutine SWBRBOT
!
! --|-----------------------------------------------------------|--
! | Delft University of Technology |
! | Faculty of Civil Engineering and Geosciences |
! | Environmental Fluid Mechanics Section |
! | P.O. Box 5048, 2600 GA Delft, The Netherlands |
! | |
! | Programmers: The SWAN team |
! --|-----------------------------------------------------------|--
!
!
! SWAN (Simulating WAves Nearshore); a third generation wave model
! Copyright (C) 1993-2024 Delft University of Technology
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
!
!
! Authors
!
! 41.80: Dirk Rijnsdorp and Ad Reniers
!
! Updates
!
! 41.80, September 2021: New subroutine
!
! Purpose
!
! Computes the mean depth and bed elevation spectrum at computational grid point from surrounding points on depth grid
!
! Modules used
!
use ocpcomm4
use swcomm2
use swcomm3, only: pbrag, PI, MXC, MYC, MCGRD
use m_genarr, only: DEPTH, XCGRID, YCGRID, KGRPNT
use SwanGriddata, only: nverts, xcugrd, ycugrd
!
implicit none
!
! Local variables
!
integer :: ic ! computational grid counter
integer, save :: ient = 0 ! number of entries in this subroutine
integer :: ierr ! error indicator
integer :: ip ! pointer in array DEPTH
integer :: ish ! shift level for shifting matrix
integer :: istat ! indicate status of allocation
integer :: ix ! loop counter over region of depth points in x-direction
integer :: ixc ! loop counter over computational grid in x-direction
integer :: ixe ! end x-index of region of depth points around the computational point
integer :: ixg ! index of computational point in depth grid in x-direction
integer :: ixs ! start x-index of region of depth points around the computational point
integer :: iy ! loop counter over region of depth points in y-direction
integer :: iyc ! loop counter over computational grid in y-direction
integer :: iye ! end y-index of region of depth points around the computational point
integer :: iyg ! index of computational point in depth grid in y-direction
integer :: iys ! start y-index of region of depth points around the computational point
integer :: k ! counter
integer :: lensav ! size of work array wsave (FFT)
integer :: lenwrk ! size of work array work (FFT)
integer :: n ! squared size region
integer :: nreg ! size of region of depth points around computational grid point for computing mean depth and bottom spectrum
!
real :: ixf ! distance to origin of depth grid divided by mesh size in x-direction (fractional number)
real :: iyf ! distance to origin of depth grid divided by mesh size in y-direction (fractional number)
real*8 :: p0 ! polynomial fit coefficient
real*8 :: p1 ! polynomial fit coefficient
real*8 :: p2 ! polynomial fit coefficient
real :: s ! sum of surrounding depths
real :: vard ! variance of small scale bed elevation
real :: vars ! variance of bed elevation spectrum
real :: xpc ! x-coordinate of computational grid point
real :: ypc ! y-coordinate of computational grid point
!
logical :: filb ! indicate whether bottom spectrum is available through file or not
logical :: ingrd ! Boolean variable to determine whether point is in depth grid or not
logical :: EQREAL ! indicate whether two reals are equal or not
!
character(80) :: msgstr ! string to pass message
!
real (kind=8), dimension(:) , allocatable :: x ! work array (bi-linear fit)
real (kind=8), dimension(:) , allocatable :: y ! work array (bi-linear fit)
real (kind=8), dimension(:) , allocatable :: z ! work array (bi-linear fit)
!
complex(kind=8), dimension(:,:), allocatable :: c ! Fourier coefficients (FFT)
real (kind=8), dimension(:,:), allocatable :: r ! input data (FFT)
real (kind=8), dimension(:) , allocatable :: work ! work array (FFT)
real (kind=8), dimension(:) , allocatable :: wsave ! work array (FFT)
!
! Structure
!
! Description of the pseudo code
!
! Source text
!
if (ltrace) call strace (ient,'SWBRBOT')
!
! check if bottom spectrum is available
!
if ( allocated(botspc) ) then
filb = .true.
else
filb = .false.
endif
!
nreg = int(pbrag(1))
n = nreg * nreg
!
! allocate data for bi-linear fit
!
allocate ( x(n) )
allocate ( y(n) )
allocate ( z(n) )
!
! allocate and initialize mean depth and bed elevation spectrum
!
istat = 0
if ( .not.allocated(dpmean) ) allocate(dpmean( MCGRD), stat = istat)
if ( istat == 0 .and. .not.allocated(fb ) ) allocate(fb (mkbx,mkby,MCGRD), stat = istat)
if ( istat /= 0 ) then
write (msgstr, '(a,i6)') 'allocation problem: Bragg scattering data and return code is ',istat
call msgerr ( 4, trim(msgstr) )
return
endif
!
dpmean = 0.
fb = 0.
!
ierr = 0
!
! do some preparation for FFT, if necessary
!
if ( .not.filb ) then
!
ish = nreg/2 + mod(nreg,2)
!
dkbx = 2.*PI * 1./dxg(1) / pbrag(1)
dkby = 2.*PI * 1./dyg(1) / pbrag(1)
!
! allocate work arrays for FFT
!
lenwrk = 2 * n
lensav = 2 * nreg + int( log(pbrag(1)) / log(2.) ) + 4
lensav = 2 * lensav
!
allocate ( r(nreg,nreg) )
allocate ( c(nreg,nreg) )
!
allocate ( work (lenwrk) )
allocate ( wsave(lensav) )
!
! initialization FFT
!
call cfft2i ( nreg, nreg, wsave, lensav, ierr )
if ( ierr /= 0 ) goto 10
!
endif
!
! compute mean depth and bed elevation spectrum in all active grid points
!
! --- rectilinear / curvilinear computational grid
!
do ixc = 1, MXC
do iyc = 1, MYC
!
ic = KGRPNT(ixc,iyc)
if ( ic == 1 ) cycle
!
xpc = XCGRID(ixc,iyc)
ypc = YCGRID(ixc,iyc)
!
ingrd = .true.
!
! find computational point in depth grid
!
ixf = ( ( xpc - xpg(1) ) * cospg(1) + ( ypc - ypg(1) ) * sinpg(1) ) / dxg(1)
!
if ( ixf <= 0. ) then
ixg = 1
if ( ixf < -0.1 ) ingrd = .false.
else if ( ixf >= float(mxg(1)-1) ) then
ixg = mxg(1) - 1
if ( ixf > float(mxg(1))-0.9 ) ingrd = .false.
else
ixg = int(ixf) + 1
endif
!
if ( myg(1) > 1 ) then
!
iyf = ( -( xpc - xpg(1) ) * sinpg(1) + ( ypc - ypg(1) ) * cospg(1) ) / dyg(1)
!
if ( iyf <= 0. ) then
iyg = 1
if ( iyf < -0.1 ) ingrd = .false.
else if ( iyf >= float(myg(1)-1) ) then
iyg = myg(1) - 1
if ( iyf > float(myg(1))-0.9 ) ingrd = .false.
else
iyg = int(iyf) + 1
endif
!
else
!
iyg = 1
!
endif
!
! determine region of surronding points with respect to computational point
!
ixs = max( 1,ixg - (nreg-1)/2)
ixe = min(mxg(1),ixg + (nreg-1)/2)
!
iys = max( 1,iyg - (nreg-1)/2)
iye = min(myg(1),iyg + (nreg-1)/2)
!
! compute the mean depth and bottom spectrum in given region
!
if ( ingrd ) then
!
k = 0
s = 0.
!
do ix = ixs, ixe
do iy = iys, iye
ip = ix + (iy-1) * mxg(1)
if ( .not.EQREAL(DEPTH(ip),excfld(1)) ) then
k = k + 1
x(k) = xpg(1) + cospg(1)*(ix-1)*dxg(1) - sinpg(1)*(iy-1)*dyg(1)
y(k) = ypg(1) + sinpg(1)*(ix-1)*dxg(1) + cospg(1)*(iy-1)*dyg(1)
z(k) = DEPTH(ip)
s = s + z(k)
endif
enddo
enddo
!
if ( k == 0 ) then
dpmean(ic) = excfld(1)
cycle
else
dpmean(ic) = s / real(k)
endif
!
if ( .not. filb ) then
!
! bi-linear fit
call fit2(x,y,z,k,p0,p1,p2,ierr)
if ( ierr /= 0 ) cycle
!
k = 0
r = 0.
!
! compute modulation (small scale bathymetry)
!
do ix = ixs, ixe
do iy = iys, iye
ip = ix + (iy-1) * mxg(1)
if ( .not.EQREAL(DEPTH(ip),excfld(1)) ) then
k = k + 1
r(ix-ixs+1,iy-iys+1) = DEPTH(ip) - p0 - p1*x(k) - p2*y(k)
endif
enddo
enddo
!
vard = sum(r*r) / pbrag(1) / pbrag(1)
!
c = cmplx(r)
!
! compute amplitudes
!
call cfft2b ( nreg, nreg, nreg, c, wsave, lensav, work, lenwrk, ierr ) ! use back transform to prevent normalization!
if ( ierr /= 0 ) exit
!
! compute bed elevation spectrum
!
c = cshift(c, shift=ish, dim=2 )
c = cshift(c, shift=ish, dim=1 )
!
r = 0.5 * abs(c)**2
!
vars = sum(r) * dkbx * dkby
!
! scale to get the correct variance
!
if ( vars /= 0. ) r = r * vard / vars
!
fb(:,:,ic) = r(:,:)
!
else
!
fb(:,:,ic) = botspc(:,:)
!
endif
!
endif
!
enddo
enddo
!
! --- unstructured computational grid
!
do ic = 1, nverts
!
xpc = xcugrd(ic)
ypc = ycugrd(ic)
!
ingrd = .true.
!
! find computational point in depth grid
!
ixf = ( ( xpc - xpg(1) ) * cospg(1) + ( ypc - ypg(1) ) * sinpg(1) ) / dxg(1)
!
if ( ixf <= 0. ) then
ixg = 1
if ( ixf < -0.1 ) ingrd = .false.
else if ( ixf >= float(mxg(1)-1) ) then
ixg = mxg(1) - 1
if ( ixf > float(mxg(1))-0.9 ) ingrd = .false.
else
ixg = int(ixf) + 1
endif
!
if ( myg(1) > 1 ) then
!
iyf = ( -( xpc - xpg(1) ) * sinpg(1) + ( ypc - ypg(1) ) * cospg(1) ) / dyg(1)
!
if ( iyf <= 0. ) then
iyg = 1
if ( iyf < -0.1 ) ingrd = .false.
else if ( iyf >= float(myg(1)-1) ) then
iyg = myg(1) - 1
if ( iyf > float(myg(1))-0.9 ) ingrd = .false.
else
iyg = int(iyf) + 1
endif
!
else
!
iyg = 1
!
endif
!
! determine region of surronding points with respect to computational point
!
ixs = max( 1,ixg - (nreg-1)/2)
ixe = min(mxg(1),ixg + (nreg-1)/2)
!
iys = max( 1,iyg - (nreg-1)/2)
iye = min(myg(1),iyg + (nreg-1)/2)
!
! compute the mean depth and bottom spectrum in given region
!
if ( ingrd ) then
!
k = 0
s = 0.
!
do ix = ixs, ixe
do iy = iys, iye
ip = ix + (iy-1) * mxg(1)
if ( .not.EQREAL(DEPTH(ip),excfld(1)) ) then
k = k + 1
x(k) = xpg(1) + cospg(1)*(ix-1)*dxg(1) - sinpg(1)*(iy-1)*dyg(1)
y(k) = ypg(1) + sinpg(1)*(ix-1)*dxg(1) + cospg(1)*(iy-1)*dyg(1)
z(k) = DEPTH(ip)
s = s + z(k)
endif
enddo
enddo
!
if ( k == 0 ) then
dpmean(ic) = excfld(1)
cycle
else
dpmean(ic) = s / real(k)
endif
!
if ( .not. filb ) then
!
! bi-linear fit
call fit2(x,y,z,k,p0,p1,p2,ierr)
if ( ierr /= 0 ) cycle
!
k = 0
r = 0.
!
! compute modulation (small scale bathymetry)
!
do ix = ixs, ixe
do iy = iys, iye
ip = ix + (iy-1) * mxg(1)
if ( .not.EQREAL(DEPTH(ip),excfld(1)) ) then
k = k + 1
r(ix-ixs+1,iy-iys+1) = DEPTH(ip) - p0 - p1*x(k) - p2*y(k)
endif
enddo
enddo
!
vard = sum(r*r) / pbrag(1) / pbrag(1)
!
c = cmplx(r)
!
! compute amplitudes
!
call cfft2b ( nreg, nreg, nreg, c, wsave, lensav, work, lenwrk, ierr ) ! use back transform to prevent normalization!
if ( ierr /= 0 ) exit
!
! compute bed elevation spectrum
!
c = cshift(c, shift=ish, dim=2 )
c = cshift(c, shift=ish, dim=1 )
!
r = 0.5 * abs(c)**2
!
vars = sum(r) * dkbx * dkby
!
! scale to get the correct variance
!
if ( vars /= 0. ) r = r * vard / vars
!
fb(:,:,ic) = r(:,:)
!
else
!
fb(:,:,ic) = botspc(:,:)
!
endif
!
endif
!
enddo
!
10 continue
if ( .not.filb ) deallocate ( r, c, work, wsave )
deallocate ( x, y, z )
!
if ( ierr /= 0 ) then
write (msgstr, '(a,i6)') 'something went wrong with the Fourier transform - return code is ',ierr
call msgerr ( 4, trim(msgstr) )
return
endif
!
contains
!
subroutine fit2(x,y,z,n,a,b,c,ierr)
integer n, ierr
real*8 a,b,c,x(n),y(n),z(n)
integer i
real*8 ss, sx, sy, sz, sxx, sxy, sxz, syy, syz, d
ierr=1
ss=dble(n)
sx=0.
sy=0.
sz=0.
sxx=0.
sxy=0.
sxz=0.
syy=0.
syz=0.
do i=1,n
sx=sx+x(i)
sy=sy+y(i)
sz=sz+z(i)
sxx=sxx+x(i)*x(i)
sxy=sxy+x(i)*y(i)
sxz=sxz+x(i)*z(i)
syy=syy+y(i)*y(i)
syz=syz+y(i)*z(i)
enddo
d=ss*sxx*syy+sy*sx*sxy+sx*sxy*sy-sy*sxx*sy-ss*sxy*sxy-sx*sx*syy
if (d.ne.0d0) then
ierr=0
a=(sz*sxx*syy+syz*sx*sxy+sxz*sxy*sy-syz*sxx*sy-sz*sxy*sxy-sxz*sx*syy)/d
b=(ss*sxz*syy+sy*sz*sxy+sx*syz*sy-sy*sxz*sy-ss*syz*sxy-sx*sz*syy)/d
c=(ss*sxx*syz+sy*sx*sxz+sx*sxy*sz-sy*sxx*sz-ss*sxy*sxz-sx*sx*syz)/d
endif
return
end subroutine fit2
!
end subroutine SWBRBOT
!
subroutine SWFBXY ( dep2, mudl2, spcsig, spcdir )
!
! --|-----------------------------------------------------------|--
! | Delft University of Technology |
! | Faculty of Civil Engineering and Geosciences |
! | Environmental Fluid Mechanics Section |
! | P.O. Box 5048, 2600 GA Delft, The Netherlands |
! | |
! | Programmers: The SWAN team |
! --|-----------------------------------------------------------|--
!
!
! SWAN (Simulating WAves Nearshore); a third generation wave model
! Copyright (C) 1993-2024 Delft University of Technology
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
!
!
! Authors
!
! 41.80: Dirk Rijnsdorp and Ad Reniers
!
! Updates
!
! 41.80, September 2021: New subroutine
!
! Purpose
!
! Computes bottom spectrum density at wave number difference k - k' for the whole computational grid
!
! Method
!
! Bi-linear interpolation in the wave number space
!
! Modules used
!
use ocpcomm4
use swcomm2
use swcomm3
!
implicit none
!
! Argument variables
!
real, dimension(MCGRD), intent(in) :: dep2 ! water depth at current time level
real, dimension(MCGRD), intent(in) :: mudl2 ! mud thickness at current time level
real, dimension(MDC,6), intent(in) :: spcdir ! (*,1): spectral direction bins (radians)
! (*,2): cosine of spectral directions
! (*,3): sine of spectral directions
! (*,4): cosine^2 of spectral directions
! (*,5): cosine*sine of spectral directions
! (*,6): sine^2 of spectral directions
real, dimension(MSC), intent(in) :: spcsig ! relative frequency bins
!
! Local variables
!
integer :: ic ! loop counter over computational grid points
integer :: id ! loop counter over direction bins
integer :: ida ! loop counter over direction bins
integer, save :: ient = 0 ! number of entries in this subroutine
integer :: ik ! x-index in wave number space
integer :: is ! loop counter over frequency bins
integer :: istat ! indicate status of allocation
integer :: jk ! y-index in wave number space
!
real, dimension(MSC) :: arr ! auxiliary array
real :: d ! local depth
real :: dm ! local mud layer
real :: fmax ! maximum value of bottom spectrum at a computational point
real :: ikb ! broken coordinate for given point lx in wave number space
real :: jkb ! broken coordinate for given point ly in wave number space
real :: k ! frequency-dependent wave number
real, dimension(MSC) :: kwave ! wave numbers for all frequencies
real :: kcoff2 ! squared cutoff to bottom wave number
real :: kcuti ! inverse of cutoff to k/l
real :: kd ! = k * d
real :: kxo ! x-origin of wave number space
real :: kyo ! y-origin of wave number space
real :: lx ! x-component of wave number difference k - k'
real :: ly ! y-component of wave number difference k - k'
real :: sxk1 ! first weight factor for distance in x-direction
real :: sxk2 ! second weight factor for distance in x-direction
real :: syk1 ! first weight factor for distance in y-direction
real :: syk2 ! second weight factor for distance in y-direction
!
character(80) :: msgstr ! string to pass message
!
! Structure
!
! Description of the pseudo code
!
! Source text
!
if (ltrace) call strace (ient,'SWFBXY')
!
! allocate and initialize bed elevation spectrum at wave number difference
!
istat = 0
if (.not.allocated(fbdxy)) allocate(fbdxy(MDC,MDC,MSC,MCGRD), stat = istat)
if ( istat /= 0 ) then
write (msgstr, '(a,i6)') 'allocation problem: bottom spectrum and return code is ',istat
call msgerr ( 4, trim(msgstr) )
return
endif
!
fbdxy = 0.
!
kcuti = 1. / pbrag(2)
!
! origin wave number space based on Nyquist
kxo = -0.5 * mkbx * dkbx
if ( mod(mkbx,2)/=0 ) kxo = kxo + 0.5 * dkbx
!
kyo = -0.5 * mkby * dkby
if ( mod(mkby,2)/=0 ) kyo = kyo + 0.5 * dkby
!
do ic = 1, MCGRD
!
fmax = maxval(abs(fb(:,:,ic)))
if ( .not. fmax > 1.e-6 ) cycle
!
d = dep2(ic)
!
if ( .not. d > DEPMIN ) cycle
!
if (VARMUD) then
dm = mudl2(ic)
else
dm = PMUD(1)
endif
!
! compute wave number for all frequencies
!
call KSCIP1 ( MSC, spcsig, d, kwave, arr, arr, arr )
if ( IMUD == 1 ) call KSCIP2 ( MSC, spcsig, d, kwave, arr, arr, arr, arr, dm )
!
do is = 1, MSC
!
k = kwave(is)
kd = k * d
!
if ( kd < 5. ) then
!
kcoff2 = ( kcuti * k )**2
!
do id = 1, MDC
do ida = 1, MDC
!
lx = k * ( spcdir(id,2) - spcdir(ida,2) )
ly = k * ( spcdir(id,3) - spcdir(ida,3) )
!
if ( lx*lx + ly*ly > kcoff2 ) then
!
ikb = ( lx - kxo ) / dkbx
jkb = ( ly - kyo ) / dkby
!
if ( .not. ikb > 0. ) then
ik = 1
sxk2 = 0.
else if ( .not. ikb < real(mkbx-1) ) then
ik = mkbx - 1
sxk2 = 1.
else
ik = int(ikb)
sxk2 = ikb - real(ik)
ik = ik + 1
endif
!
if ( .not. jkb > 0.) then
jk = 1
syk2 = 0.
else if ( .not. jkb < real(mkby-1) ) then
jk = mkby - 1
syk2 = 1.
else
jk = int(jkb)
syk2 = jkb - real(jk)
jk = jk + 1
endif
!
sxk1 = 1.- sxk2
syk1 = 1.- syk2
!
fbdxy(ida,id,is,ic) = sxk1*syk1*fb(ik,jk,ic) + sxk1*syk2*fb(ik,jk+1,ic) + sxk2*syk1*fb(ik+1,jk,ic) + sxk2*syk2*fb(ik+1,jk+1,ic)
!
endif
!
enddo
!
enddo
!
endif
!
enddo
!
enddo
!
end subroutine SWFBXY
!
subroutine SWFB ( fbd, dep2, kwave, ecos, esin )
!
! --|-----------------------------------------------------------|--
! | Delft University of Technology |
! | Faculty of Civil Engineering and Geosciences |
! | Environmental Fluid Mechanics Section |
! | P.O. Box 5048, 2600 GA Delft, The Netherlands |
! | |
! | Programmers: The SWAN team |
! --|-----------------------------------------------------------|--
!
!
! SWAN (Simulating WAves Nearshore); a third generation wave model
! Copyright (C) 1993-2024 Delft University of Technology
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
!
!
! Authors
!
! 41.80: Dirk Rijnsdorp and Ad Reniers
!
! Updates
!
! 41.80, September 2021: New subroutine
!
! Purpose
!
! Computes bottom spectrum density at wave number difference k - k'
!
! Method
!
! Bi-linear interpolation in the wave number space
!
! Modules used
!
use ocpcomm4
use swcomm3
!
implicit none
!
! Argument variables
!
real, dimension(MCGRD), intent(in) :: dep2 ! water depth at current time level
real, dimension(MDC), intent(in) :: ecos ! help array containing cosine of spectral directions
real, dimension(MDC), intent(in) :: esin ! help array containing sine of spectral directions
real, dimension(MDC,MDC,MSC), intent(out) :: fbd ! bottom spectrum at wave number difference k - k'
real, dimension(MSC,MICMAX), intent(in) :: kwave ! wave number
!
! Local variables
!
integer :: id ! loop counter over direction bins
integer :: ida ! loop counter over direction bins
integer, save :: ient = 0 ! number of entries in this subroutine
integer :: ik ! x-index in wave number space
integer :: is ! loop counter over frequency bins
integer :: jk ! y-index in wave number space
!
real :: d ! local depth
real :: fmax ! maximum value of bottom spectrum
real :: ikb ! broken coordinate for given point lx in wave number space
real :: jkb ! broken coordinate for given point ly in wave number space
real :: k ! local wave number
real :: kcoff2 ! squared cutoff to bottom wave number
real :: kcuti ! inverse of cutoff to k/l
real :: kd ! = k * d
real :: kxo ! x-origin of wave number space
real :: kyo ! y-origin of wave number space
real :: lx ! x-component of wave number difference k - k'
real :: ly ! y-component of wave number difference k - k'
real :: sxk1 ! first weight factor for distance in x-direction
real :: sxk2 ! second weight factor for distance in x-direction
real :: syk1 ! first weight factor for distance in y-direction
real :: syk2 ! second weight factor for distance in y-direction
!
! Structure
!
! Description of the pseudo code
!
! Source text
!
if (ltrace) call strace (ient,'SWFB')
!
fbd = 0.
!
fmax = maxval(abs(fb(:,:,KCGRD(1))))
if ( .not. fmax > 1.e-6 ) return
!
d = dep2(KCGRD(1))
!
kcuti = 1. / pbrag(2)
!
! origin wave number space based on Nyquist
kxo = -0.5 * mkbx * dkbx
if ( mod(mkbx,2)/=0 ) kxo = kxo + 0.5 * dkbx
!
kyo = -0.5 * mkby * dkby
if ( mod(mkby,2)/=0 ) kyo = kyo + 0.5 * dkby
!
do is = 1, MSC
!
k = kwave(is,1)
kd = k * d
!
if ( kd < 5. ) then
!
kcoff2 = ( kcuti * k )**2
!
do id = 1, MDC
do ida = 1, MDC
!
lx = k * ( ecos(id) - ecos(ida) )
ly = k * ( esin(id) - esin(ida) )
!
if ( lx*lx + ly*ly > kcoff2 ) then
!
ikb = ( lx - kxo ) / dkbx
jkb = ( ly - kyo ) / dkby
!
if ( .not. ikb > 0. ) then
ik = 1
sxk2 = 0.
else if ( .not. ikb < real(mkbx-1) ) then
ik = mkbx - 1
sxk2 = 1.
else
ik = int(ikb)
sxk2 = ikb - real(ik)
ik = ik + 1
endif
!
if ( .not. jkb > 0.) then
jk = 1
syk2 = 0.
else if ( .not. jkb < real(mkby-1) ) then
jk = mkby - 1
syk2 = 1.
else
jk = int(jkb)
syk2 = jkb - real(jk)
jk = jk + 1
endif
!
sxk1 = 1.- sxk2
syk1 = 1.- syk2
!
fbd(ida,id,is) = sxk1*syk1*fb(ik,jk,KCGRD(1)) + sxk1*syk2*fb(ik,jk+1,KCGRD(1)) + sxk2*syk1*fb(ik+1,jk,KCGRD(1)) + sxk2*syk2*fb(ik+1,jk+1,KCGRD(1))
!
endif
!
enddo
!
enddo
!
endif
!
enddo
!
end subroutine SWFB
!
subroutine SWBRAGG1 ( imatra, ac2, dep2, kwave, cgo, spcsig, idcmin, idcmax, isstop, ecos, esin, plbrag, redc0 )
!
! --|-----------------------------------------------------------|--
! | Delft University of Technology |
! | Faculty of Civil Engineering and Geosciences |
! | Environmental Fluid Mechanics Section |
! | P.O. Box 5048, 2600 GA Delft, The Netherlands |
! | |
! | Programmers: The SWAN team |
! --|-----------------------------------------------------------|--
!
!
! SWAN (Simulating WAves Nearshore); a third generation wave model
! Copyright (C) 1993-2024 Delft University of Technology
!
! This program is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
!
!
! Authors
!
! 41.80: Dirk Rijnsdorp and Ad Reniers
!
! Updates
!
! 41.80, September 2021: New subroutine
!
! Purpose
!
! Computation of the source term due to forward Bragg scattering per sweep direction
!
! Method
!
! See the JFM paper of Ardhuin and Herbers (2002)
! in particular, Eqs. (2.48) and (2.49)
!
! Modules used
!
use ocpcomm4
use swcomm3
use swcomm4
!
implicit none
!
! Argument variables
!
integer, intent(in) :: isstop ! maximum frequency that is propagated within a sweep
!
integer, dimension(MSC), intent(in) :: idcmax ! maximum frequency-dependent counter in directional space