Tasmota is not showing more than 5 PWM Slider

[domehehe]

i use a ESP32-WROOM-32U and flashed it with the newest Tasmota.
i configurated 8x PWM Modules for GPIO18, GPIO19, GPIO20 ....
Tasmota never shows more than 5 PWM Channels. Also over the console i'm not able to user "Power6 ON"
I used the OPtion "SetOption68 = 1" to change the sliders from colour to PWM
According to ESP32, up to 16 PWM channels are possible
According to Tasmota release Notes they also increased the Maximum PWM-Channels
i would appreciate some help

[sfromis]

Only 5 PWM are available as "lights", which includes splitting into 5 channels with sliders.

The additional PWM channels can be used via the PWM command (where value 0 means off), and you could use Berry to create sliders in the web UI, which BTW is not really meant as where to manage daily operation anyway.

Here's a small Berry program demonstrating how a slider can be created:
http://sfromis.strangled.net/tasmota/berry/examples/slider.be

[domehehe]

thank you a lot for the response, but the website seems not to be working

[sfromis]

Strange, I actually tested before posting the link, and again now. Quick response with the code. Anyway:

class slider

  var id, title, value, min, max, action, globalname, started

  # Not needed for the main page already having JavaScript code doing the same
  # static sliderjs = "<script>function la(p){x=new XMLHttpRequest();x.open('GET','.?m=1'+(p||''),true);x.send();}</script>"

  def init(id, action)
    self.id = id ? id : "slider"
    self.action = action ? action : /value->print(f'Update {self.id} {self.value}')
    self.globalname = 'slider_instance_' + self.id
    self.title = ''
  end

  def start()
    if self.started return end
    if global.member(self.globalname) global.member(self.globalname).stop() end
    tasmota.add_driver(self)
    global.setmember(self.globalname, self)
    self.started = true
    if self.max   == nil self.setrange(0,100) end
    if self.value == nil self.setvalue(self.max/2) end
    return self
  end

  def stop()
    self.started = false
    tasmota.remove_driver(self)
    global.setmember(self.globalname, nil)
    return self
  end

  def web_sensor()
    import webserver
    if webserver.has_arg(self.id)
      self.setvalue(int(webserver.arg(self.id)))
    end
  end

  def settitle(title)    self.title = title  return self end
  def setrange(min, max) self.min = min self.max = max  return self end
  def setvalue(newvalue)
    self.start()
    self.value = newvalue
    var f = self.action
    tasmota.set_timer(0, /->f(self.id, self.value))
    return self
  end

  def web_add_main_button()
    import webserver
    webserver.content_send(f'{self.title}<input type="range" class="slider" id="{self.id}" min={self.min} max={self.max} value={self.value} onchange=la("&{self.id}="+value)>')
  end

end

pwm1duty = slider('pwm1duty',
  def (id, value)
    print(id, value)
    import gpio
    gpio.set_pwm(gpio.pin(gpio.PWM1, 5), value)   # PWM6
  end)
  .setrange(0,1023).setvalue(512).settitle('PWM6')

#-  Other examples:

test = slider('test').start()   # 0..100 and prints values

dacmv = slider('dacmv',
  def (id, millivolt)
    print(id, millivolt)
    gpio.pin_mode(25, gpio.DAC)   # DAC of "classic" ESP32 is gpio 25-26, or 17-18 for ESP32-S2
    gpio.dac_voltage(25, millivolt)
  end)
  .setrange(0,3300).setvalue(0)

pwm1freq = slider('pwm1freq',
  def (id, value)
    print(id, value)
    import gpio
    gpio.set_pwm_freq(gpio.pin(gpio.PWM1, 5), value)   # PWM6
  end)
  .setrange(0,1023).setvalue(440)

-#

[domehehe]

i used the pwm console command instead of the slider, which seams to work. Thanks for that.
but to be clear, i'm not able to user "Power8 on" console commands over the console for the pwm?

15:50:14.120 CMD: PWM1 512
15:50:14.125 RSL: RESULT = {"PWM":{"PWM1":512,"PWM2":15,"PWM3":32,"PWM4":20,"PWM5":61,"PWM6":0,"PWM7":0,"PWM8":0}}

[sfromis]

Right. I already told you:

(where value 0 means off)