NRF24L01-RXDemo.spin2

{
----------------------------------------------------------------------------------------------------
    Filename:       NRF24L01-RXDemo.spin2
    Description:    nRF24L01+ Receive demo
        * Will display data from all 6 data pipes
    Author:         Jesse Burt
    Started:        Nov 23, 2019
    Updated:        Aug 26, 2024
    Copyright (c) 2024 - See end of file for terms of use.
----------------------------------------------------------------------------------------------------
}
#include "core.con.click.spin2"

CON

    _clkfreq    = 180_000_000
    _xtlfreq    = 20_000_000

' -- User-modifiable constants
    CLICK_BASE  = 0                             ' 0, 16, 32, 48
    CHANNEL     = 2                             ' 0..125
' --


OBJ

    ser:    "com.serial.terminal.ansi" | SER_BAUD=2_000_000

    { use with MikroE Click boards - define the CLICK_BASE I/O pin above and leave these as-is }
    radio:  "wireless.transceiver.nrf24l01" | CE=RES_PIN, CS=CS_PIN, SCK=SCK_PIN, MOSI=MOSI_PIN, MISO=MISO_PIN, SPI_FREQ=10_000_000

    { use custom I/O pins; comment out the line above and uncomment this one }
'    radio:  "wireless.transceiver.nrf24l01" | CE=0, CS=1, SCK=2, MOSI=3, MISO=4, SPI_FREQ=10_000_000


VAR

    byte _payload[32]
    byte _payld_len
    byte _syncwd[5]


PUB main() | payld_cnt, recv_pipe, pipe_nr

    setup()                                     ' start serial term. and nRF24

' -- User-modifiable settings (NOTE: These settings _must_ match the transmit side) }
    radio.channel(CHANNEL)

    _payld_len := 8                             ' 1..32

    { set syncword (note: order in string() is LSB, ..., MSB) }
    radio.set_pipe_nr(0)
    radio.set_syncwd(string($e7, $e7, $e7, $e7, $e7))

    ' choose a receive mode preset (250kbps, 1Mbps, 2Mbps)
    '   with optional Auto-Ack/ShockBurst  (power-on default)
'    radio.preset_rx250k()                       ' 250kbps
'    radio.preset_rx250k_noaa()                  ' 250kbps, No Auto-Ack
'    radio.preset_1m()                           ' 1Mbps
'    radio.preset_1m_noaa()                      ' 1Mbps, No Auto-Ack
    radio.preset_rx2m()                         ' 2Mbps
'    radio.preset_rx2m_noaa()                    ' 2Mbps, No Auto-Ack
' --

    { set all pipes to the same payload length }
    repeat pipe_nr from 0 to 5
        radio.set_pipe_nr(pipe_nr)
        radio.payld_len(_payld_len)

    ser.clear()
    ser.pos_xy(0, 0)
    ser.printf(@"Receive mode (channel %d)\n\r", radio.channel())
    ser.strln(@"Listening for transmitters...")

    payld_cnt := 0
    repeat
        { clear local buffer and wait until a payload is received }
        bytefill(@_payload, 0, 32)
        repeat
            ser.pos_xy(0, 3)
            ser.printf(@"Payloads received: %d ", payld_cnt)
        until radio.payld_rdy()

        { check which pipe the data was received in and retrieve the payload into local buffer }
        recv_pipe := radio.rx_pipe_pending()
        radio.syncwd(@_syncwd)
        radio.rx_payld(_payld_len, @_payload)
        payld_cnt++

        { display payload received through each pipe number on a separate line }
        ser.pos_xy(0, 5 + (recv_pipe * 4))
        ser.printf(@"Received packet on pipe %d ", recv_pipe)
        ser.printf(@"(%02.2x:%02.2x:%02.2x:%02.2x:%02.2x)\n\r", _syncwd[4], ...
                                                                _syncwd[3], ...
                                                                _syncwd[2], ...
                                                                _syncwd[1], ...
                                                                _syncwd[0])
        ser.hexdump(@_payload, 0, 4, _payld_len, _payld_len)

        { clear interrupt and receive buffer for next loop }
        radio.int_clear(radio.INT_PAYLD_RDY)
        radio.flush_rx()


PUB setup()

    ser.start()

    if ( radio.start() )
        ser.strln(@"nRF24L01+ driver started")
    else
        ser.strln(@"nRF24L01+ driver failed to start - halting")
        repeat

DAT
{
Copyright 2024 Jesse Burt

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge, publish, distribute,
sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or
substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT
NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,
DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT
OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
}