NRF24L01-TXDemo.spin

{
----------------------------------------------------------------------------------------------------
    Filename:       NRF24L01-TXDemo.spin
    Description:    nRF24L01+ Transmit demo
    Author:         Jesse Burt
    Started:        Nov 23, 2019
    Updated:        Aug 26, 2024
    Copyright (c) 2024 - See end of file for terms of use.
----------------------------------------------------------------------------------------------------
}

CON

    _clkmode    = xtal1+pll16x
    _xinfreq    = 5_000_000

' -- User-modifiable constants
    CHANNEL     = 2                             ' 0..125
' --


OBJ

    str:    "string"
    time:   "time"
    ser:    "com.serial.terminal.ansi" | SER_BAUD=115_200
    radio:  "wireless.transceiver.nrf24l01" | CE=0, CS=1, SCK=2, MOSI=3, MISO=4


VAR

    byte _payload[32]
    byte _payld_len
    byte _syncwd[5]


PUB main() | payld_cnt, max_retrans, pkts_retrans, lost_pkts

    setup()                                     ' start serial term. and nRF24
    longfill(@payld_cnt, 0, 4)                  ' init vars to 0

' -- User-modifiable settings (NOTE: These settings _must_ match the receive side) }
    radio.channel(CHANNEL)

    ' choose a transmit mode preset (250kbps, 1Mbps, 2Mbps)
    '   with optional Auto-Ack/ShockBurst (power-on default)
'    radio.preset_tx250k()                       ' 250kbps
'    radio.preset_tx250k_noaa()                  ' 250kbps, no Auto-Ack
'    radio.preset_tx1m()                         ' 1Mbps
'    radio.preset_tx1m_noaa()                    ' 1Mbps, no Auto-Ack
    radio.preset_tx2m()                         ' 2Mbps
'    radio.preset_tx2m_noaa()                    ' 2Mbps, no Auto-Ack

    radio.tx_pwr(0)                             ' -18, -12, -6, 0 (dBm)

    _payld_len := 8                             ' 1..32

    { set syncword (note: order in string() is LSB, ..., MSB) }
    radio.set_syncwd(string($e7, $e7, $e7, $e7, $e7))

' --

    radio.set_pipe_nr(0)
    radio.payld_len(_payld_len)
    radio.syncwd(@_syncwd)

    ser.clear()
    ser.pos_xy(0, 0)
    ser.printf1(@"Transmit mode (channel %d)\n\r", radio.channel())

    repeat
        { payload to transmit }
        str.sprintf1(@_payload, @"TEST%04.4d", payld_cnt++)

        { collect and display some packet statistics }
        max_retrans := radio.max_retrans_reached()
        pkts_retrans := radio.pkts_retrans()
        lost_pkts := radio.lost_pkts()
        ser.pos_xy(0, 2)
        ser.str(@"Max retransmissions reached? ")
        ser.strln(lookupz(||(max_retrans): @"No ", @"Yes"))
        ser.printf1(@"Packets retransmitted: %2.2d\n\r", pkts_retrans)
        ser.printf1(@"Lost packets: %2.2d\n\r", lost_pkts)

        { display payload and transmit it }
        ser.pos_xy(0, 6)
        ser.printf5(@"Transmitting packet (to %02.2x:%02.2x:%02.2x:%02.2x:%02.2x)\n\r", ...
                        _syncwd[4], _syncwd[3], _syncwd[2], _syncwd[1], _syncwd[0])
        ser.hexdump(@_payload, 0, 4, _payld_len, 16 <# _payld_len)
        radio.tx_payld(_payld_len, @_payload)

        { check for transmission error limits and clear them so transmission can continue }
        if (max_retrans)
            radio.int_clear(radio.INT_MAX_RETRANS)
        if (lost_pkts => 15)
            radio.channel(CHANNEL)

        { optional delay between transmissions - use as necessary to avoid abuse of the airwaves }
        time.msleep(1000)


PUB setup()

    ser.start()
    time.msleep(30)
    ser.clear()

    if ( radio.start() )
        ser.strln(@"nRF24L01+ driver started")
    else
        ser.strln(@"nRF24L01+ driver failed to start - halting")
        repeat


DAT
{
Copyright 2024 Jesse Burt

Permission is hereby granted, free of charge, to any person obtaining a copy of this software and
associated documentation files (the "Software"), to deal in the Software without restriction,
including without limitation the rights to use, copy, modify, merge, publish, distribute,
sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in all copies or
substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT
NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM,
DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT
OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
}