The aws sdk and libtorch build failed

[cl1218]

Describe the bug

The bug manifests as undefined references to specific functions in the AWS SDK during the linking stage of your project build.

Expected Behavior

I expect the project to be built successfully.

Current Behavior

[ 50%] Building CXX object CMakeFiles/http_predict.dir/downLoad.cpp.o
[100%] Linking CXX executable http_predict
CMakeFiles/http_predict.dir/downLoad.cpp.o:(.data.rel.ro._ZTVN3Aws2S39S3RequestE[_ZTVN3Aws2S39S3RequestE]+0x30): undefined reference to `Aws::AmazonWebServiceRequest::GetAdditionalCustomHeaders() const'
CMakeFiles/http_predict.dir/downLoad.cpp.o:(.data.rel.ro._ZTVN3Aws2S39S3RequestE[_ZTVN3Aws2S39S3RequestE]+0x38): undefined reference to `Aws::AmazonWebServiceRequest::SetAdditionalCustomHeaderValue(std::string const&, std::string const&)'
CMakeFiles/http_predict.dir/downLoad.cpp.o:(.data.rel.ro._ZTVN3Aws2S38Endpoint18S3EndpointProviderE[_ZTVN3Aws2S38Endpoint18S3EndpointProviderE]+0x28): undefined reference to `Aws::Endpoint::DefaultEndpointProvider<Aws::S3::S3ClientConfiguration, Aws::S3::Endpoint::S3BuiltInParameters, Aws::S3::Endpoint::S3ClientContextParameters>::OverrideEndpoint(std::string const&)'
collect2: error: ld returned 1 exit status
make[2]: *** [http_predict] Error 1
make[1]: *** [CMakeFiles/http_predict.dir/all] Error 2
make: *** [all] Error 2

Reproduction Steps

CMakeLists.txt :

cmake_minimum_required(VERSION 3.13)
project(http_predict)
find_package(AWSSDK REQUIRED COMPONENTS s3)
message(STATUS "AWS SDK version: ${AWSSDK_LIBRARIES}")
# Set the C++ compiler based on the build target
if(BUILD_FOR_ARM)
    set(CMAKE_CXX_COMPILER aarch64-linux-gnu-gcc)
else()
    set(CMAKE_CXX_COMPILER gcc)
endif()
# Set additional library and include directories
set(EXTRA_LIB_DIR -L../lib)
set(EXTRA_INCLUDE_DIR -I../include)
file(GLOB AWSDOC_S3_HEADERS
    "include/s3download.h"
)
set(VTK_DIR "/usr/local/lib64/cmake/vtk-8.2")
set(Torch_DIR "/home/ec2-user/libtorch/share/cmake/Torch")

find_package(VTK REQUIRED)
find_package(Torch REQUIRED)
find_package(X11 REQUIRED)
# Set source files
set(SRC_DEMO downLoad.cpp)

# Set library dependencies
set(LIB -lsecurec -lstdc++)

# Add executable target
add_executable(http_predict ${SRC_DEMO})

# Set additional compile options
#target_compile_options(http_predict PRIVATE -g -fstack-protector --param ssp-buffer-size=4 -Wstack-protector)
target_link_libraries(http_predict PRIVATE ${VTK_LIBRARIES} ${TORCH_LIBRARIES}   ${X11_LIBRARIES} ${EXTRA_LIB_DIR} ${LIB} pthread aws-cpp-sdk-s3 aws-cpp-sdk-core)

# Set linking options
target_link_options(http_predict PRIVATE -Wl,--disable-new-dtags,--rpath ../lib -Wl,-z,relro,-z,now -Wl,-z,noexecstack -fPIC)

Possible Solution

No response

Additional Information/Context

Only aws getobject is used in the actual source code.There is no problem when aws and libtorch build projects separately,This problem arises when the combination comes together.libtorch is available in version 1.7.0

AWS CPP SDK version used

AWS CPP SDK-1.11.237

Compiler and Version used

gcc-7.3.1

Operating System and version

centos

[sbiscigl]

find_package(AWSSDK REQUIRED COMPONENTS s3)

how are you installing the SDK? this error to me indicates that you have drift in your installation where you are including a header that expects these functions to be present but are using a binary where they are not present. Those specific functions were added in a 1.10 version a while ago. My guess if you clean installed the SDK install to a specific directory, you would not see this problem

during the linking stage of your project build.

also just for clarity this is not the linking stage of our project, this is during the linking of your build when http_predict/downLoad.cpp is linked against the SDK. is this file part of your source?

[github-actions]

Greetings! It looks like this issue hasn’t been active in longer than a week. We encourage you to check if this is still an issue in the latest release. Because it has been longer than a week since the last update on this, and in the absence of more information, we will be closing this issue soon. If you find that this is still a problem, please feel free to provide a comment or add an upvote to prevent automatic closure, or if the issue is already closed, please feel free to open a new one.

[cl1218]

Build S3 part of aws-sdk-cpp:
git clone --recurse-submodules https://github.com/aws/aws-sdk-cpp
cd aws-ask-cpp
mkdir build
cd build
cmake .. -DCMAKE_BUILD_TYPE=Release -DCMAKE_PREFIX_PATH=/usr/local/ -DCMAKE_INSTALL_PREFIX=/usr/local/ -DBUILD_ONLY="s3"
make -j4
make install

http_predict/downLoad.cpp example code:

// Copyright Amazon.com, Inc. or its affiliates. All Rights Reserved.
// SPDX-License-Identifier: Apache-2.0

#include "torch/torch.h"
#include "torch/script.h"
#include <iostream>
#include <aws/core/Aws.h>
#include <aws/s3/S3Client.h>
#include <aws/s3/model/GetObjectRequest.h>
#include <fstream>
#include "s3download.h"


bool AwsDoc::S3::GetObject(const Aws::String &objectKey,
                           const Aws::String &fromBucket,
                           const Aws::Client::ClientConfiguration &clientConfig) {
    Aws::S3::S3Client client(clientConfig);

    Aws::S3::Model::GetObjectRequest request;
    request.SetBucket(fromBucket);
    request.SetKey(objectKey);

    Aws::S3::Model::GetObjectOutcome outcome =
            client.GetObject(request);

    if (!outcome.IsSuccess()) {
        const Aws::S3::S3Error &err = outcome.GetError();
        std::cerr << "Error: GetObject: " <<
                  err.GetExceptionName() << ": " << err.GetMessage() << std::endl;
    }
    else {
        std::cout << "Successfully retrieved '" << objectKey << "' from '"
                  << fromBucket << "'." << std::endl;
    }

    return outcome.IsSuccess();
}


#ifndef TESTING_BUILD

int main() {
    Aws::SDKOptions options;
    Aws::InitAPI(options);
    {
        //TODO(user): Change bucketName to the name of a bucket in your account.
        const Aws::String bucketName = "<Enter bucket name>";

        //TODO(user): Change objectName to the name of an object in the bucket.
        //See create_bucket.cpp and put_object.cpp to create a bucket and load an object into that bucket.
        const Aws::String objectName = "<Enter object name>";

        Aws::Client::ClientConfiguration clientConfig;
        // Optional: Set to the AWS Region in which the bucket was created (overrides config file).
        // clientConfig.region = "us-east-1";

        AwsDoc::S3::GetObject(objectName, bucketName, clientConfig);
    }
    Aws::ShutdownAPI(options);

    return 0;
}

#endif // TESTING_BUILD

s3download.h:

#include <aws/core/Aws.h>
#include <aws/s3/S3Client.h>
#include <aws/s3/model/BucketLocationConstraint.h>

namespace AwsDoc {
    namespace S3 {

        bool GetObject(const Aws::String &objectKey,
                       const Aws::String &fromBucket,
                       const Aws::Client::ClientConfiguration &clientConfig);


        extern std::mutex upload_mutex;

        extern std::condition_variable upload_variable;
    } // namespace S3
} // namespace AwsDoc

[jmklix]

Can you please clean your build and install folders and then try rebuilding this sdk?

[DavidEnriqueNieves]

@jmklix
I have also encountered this issue. Using a fresh install of the AWS C++ SDK and libtorch, the issue occurs in my build file when including the line ${TORCH_LIBRARIES} and proceeding to run cmake .. and then make.

I made sure to build both libtorch and the AWS C++ SDK in Debug mode.

By any chance, does anyone have any ideas on what could be causing this?

I also tried looking for conflicting symbols in libtorch by using the nm command, but none of the symbols seemed to even partially match those found in the error found below.

Operating System

Ubuntu 20.04.5 LTS

Compiler Version used

Ubuntu 9.4.0-1ubuntu1~20.04.2

AWS SDK Version

AWS CPP SDK - 1.11.361

Libtorch Build Version

2.5.0.dev20240701+cpu

CMakeLists.txt

cmake_minimum_required(VERSION 3.13)
project(example-app)

set(CMAKE_CXX_STANDARD 20)
# set(CMAKE_BUILD_TYPE Debug)
include(CTest)

if(NOT BUILD_SHARED_LIBS)
    set(BUILD_SHARED_LIBS ON)
endif()

# Set the path to the AWS SDK and other libraries
# set(AWS_SDK_PATH "/home/davidn/aws-sdk-cpp/build/AWSSDK")
set(AWS_SDK_PATH "/home/davidn/ml-c++/libs/aws-sdk-cpp-out-debug")
set(LIBTORCH_PATH "$ENV{HOME}/ml-c++/libs/libtorch-debug")

# Set CMAKE_MODULE_PATH to help find the custom AWS SDK
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${AWS_SDK_PATH}/lib/cmake/AWSSDK")
set(CMAKE_PREFIX_PATH ${AWS_SDK_PATH} ${LIBTORCH_PATH})

# Ensure CMake uses the custom path for AWS SDK
set(AWSSDK_ROOT_DIR ${AWS_SDK_PATH})
set(AWSSDK_INCLUDE_DIR ${AWS_SDK_PATH}/include)
set(AWSSDK_LIB_DIR ${AWS_SDK_PATH}/lib)

# Find AWS SDK
find_package(AWSSDK REQUIRED COMPONENTS s3-crt HINTS ${AWS_SDK_PATH} NO_DEFAULT_PATH)
# Find other required packages
find_package(Torch REQUIRED)
find_package(CURL)


# Add RapidJSON
add_library(rapidjson INTERFACE)
target_include_directories(rapidjson INTERFACE 
    $ENV{HOME}/autolabel-anything-c++/libs/rapidjson/include
)

file(GLOB AWSDOC_S3CRT_HEADERS
    "include/awsdoc/s3-crt/*.h"
)

add_executable("test1" "s3-crt-demo.cpp" "wavreader.c" ${AWSDOC_S3CRT_HEADERS})

# Include directories
target_include_directories("test1" PRIVATE 
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:include>
    $ENV{HOME}/ml-c++/libs/LibrosaCpp/librosa/eigen3/Eigen
    $ENV{HOME}/ml-c++/libs/LibrosaCpp
)

# Link libraries
target_link_libraries("test1"
PRIVATE
    # ${TORCH_LIBRARIES}
    ${AWSSDK_LINK_LIBRARIES}
    ${AWSSDK_LIBRARIES}
    rapidjson
    CURL::libcurl
)

# Set verbose output
set(CMAKE_VERBOSE_MAKEFILE ON)

# Print AWS SDK details
message(STATUS "AWSSDK_FOUND: ${AWSSDK_FOUND}")
message(STATUS "AWSSDK_INCLUDE_DIRS: ${AWSSDK_INCLUDE_DIRS}")
message(STATUS "AWSSDK_LIBRARIES: ${AWSSDK_LIBRARIES}")

# Print all variables
# get_cmake_property(_variableNames VARIABLES)
# list (SORT _variableNames)
# foreach (_variableName ${_variableNames})
#     message(STATUS "${_variableName}=${${_variableName}}")
# endforeach()

Error output

The error is the following:

/usr/bin/ld: CMakeFiles/test1.dir/s3-crt-demo.cpp.o: in function `main':
s3-crt-demo.cpp:(.text+0x3223): undefined reference to `Aws::Utils::UUID::operator std::string() const'
/usr/bin/ld: s3-crt-demo.cpp:(.text+0x3247): undefined reference to `Aws::Utils::StringUtils::ToLower(char const*)'
/usr/bin/ld: s3-crt-demo.cpp:(.text+0x3332): undefined reference to `Aws::S3Crt::Model::BucketLocationConstraintMapper::GetBucketLocationConstraintForName(std::string const&)'
/usr/bin/ld: CMakeFiles/test1.dir/s3-crt-demo.cpp.o:(.data.rel.ro._ZTVN3Aws5S3Crt12S3CrtRequestE[_ZTVN3Aws5S3Crt12S3CrtRequestE]+0x30): undefined reference to `Aws::AmazonWebServiceRequest::GetAdditionalCustomHeaders() const'
/usr/bin/ld: CMakeFiles/test1.dir/s3-crt-demo.cpp.o:(.data.rel.ro._ZTVN3Aws5S3Crt12S3CrtRequestE[_ZTVN3Aws5S3Crt12S3CrtRequestE]+0x38): undefined reference to `Aws::AmazonWebServiceRequest::SetAdditionalCustomHeaderValue(std::string const&, std::string const&)'
collect2: error: ld returned 1 exit status
make[2]: *** [CMakeFiles/test1.dir/build.make:138: test1] Error 1
make[2]: Leaving directory '/home/davidn/ml-c++/aws-lambda-cpp-hello/build'
make[1]: *** [CMakeFiles/Makefile2:842: CMakeFiles/test1.dir/all] Error 2
make[1]: Leaving directory '/home/davidn/ml-c++/aws-lambda-cpp-hello/build'
make: *** [Makefile:104: all] Error 2

Upon deleting all files in the build directory and running cmake .. followed by make while still inside the build directory, the build proceeds successfully and I'm able to run the example code referenced in this example of using s3-crt.

Output:

make[2]: Leaving directory '/home/davidn/ml-c++/aws-lambda-cpp-hello/build'                                                                                                      
[100%] Built target test1                                                                                                                                                                        
make[1]: Leaving directory '/home/davidn/ml-c++/aws-lambda-cpp-hello/build'                                                                                                      
/usr/bin/cmake -E cmake_progress_start /home/davidn/ml-c++/aws-lambda-cpp-hello/build/CMakeFiles 0 

[DavidEnriqueNieves]

I also get the same error with a fresh install of the AWS C++ SDK using S3 only instead of S3-CRT as done previously.

[DavidEnriqueNieves]

@cl1218 Did you ever resolve this?

[DavidEnriqueNieves]

I also just tried it out with an older version of the AWS C++ SDK, namely tag 1.11.234. I unfortunately still run into the same issue.

[SergeyRyabinin]

Hi @DavidEnriqueNieves
thank you for listing your cmake script.

# Set the path to the AWS SDK and other libraries
# set(AWS_SDK_PATH "/home/davidn/aws-sdk-cpp/build/AWSSDK")
set(AWS_SDK_PATH "/home/davidn/ml-c++/libs/aws-sdk-cpp-out-debug")
set(LIBTORCH_PATH "$ENV{HOME}/ml-c++/libs/libtorch-debug")

# Set CMAKE_MODULE_PATH to help find the custom AWS SDK
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${AWS_SDK_PATH}/lib/cmake/AWSSDK")
set(CMAKE_PREFIX_PATH ${AWS_SDK_PATH} ${LIBTORCH_PATH})

# Ensure CMake uses the custom path for AWS SDK
set(AWSSDK_ROOT_DIR ${AWS_SDK_PATH})
set(AWSSDK_INCLUDE_DIR ${AWS_SDK_PATH}/include)
set(AWSSDK_LIB_DIR ${AWS_SDK_PATH}/lib)

# Find AWS SDK
find_package(AWSSDK REQUIRED COMPONENTS s3-crt HINTS ${AWS_SDK_PATH} NO_DEFAULT_PATH)

I can see it quite deviates from our example app cmake script and our local test app within the main repo.
Your application is compiled successfully, but fails to be linked (because sdk libraries are not added to the linker input (or wrong libs added).

I'm not entirely sure why you are manually setting certain cmake variables (such as AWSSDK_ROOT_DIR, AWSSDK_INCLUDE_DIR, AWSSDK_LIB_DIR). I can also see that both CMAKE_PREFIX_PATH and CMAKE_MODULE_PATH are set with the SDK install path.

Typically we recommend setting only the CMAKE_PREFIX_PATH to contain an install path of the SDK, and then calling

find_package(AWSSDK REQUIRED COMPONENTS s3-crt)

I'm not sure what will happen if the SDK install path is pushed into different cmake package/library search variables, as well as manually set AWSSDK_LIB_DIR. Please let us know if there is a specific reason for your approach and you would have any suggestion what to update in our cmake script.

[DavidEnriqueNieves]

Hi @DavidEnriqueNieves thank you for listing your cmake script.

# Set the path to the AWS SDK and other libraries
# set(AWS_SDK_PATH "/home/davidn/aws-sdk-cpp/build/AWSSDK")
set(AWS_SDK_PATH "/home/davidn/ml-c++/libs/aws-sdk-cpp-out-debug")
set(LIBTORCH_PATH "$ENV{HOME}/ml-c++/libs/libtorch-debug")

# Set CMAKE_MODULE_PATH to help find the custom AWS SDK
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${AWS_SDK_PATH}/lib/cmake/AWSSDK")
set(CMAKE_PREFIX_PATH ${AWS_SDK_PATH} ${LIBTORCH_PATH})

# Ensure CMake uses the custom path for AWS SDK
set(AWSSDK_ROOT_DIR ${AWS_SDK_PATH})
set(AWSSDK_INCLUDE_DIR ${AWS_SDK_PATH}/include)
set(AWSSDK_LIB_DIR ${AWS_SDK_PATH}/lib)

# Find AWS SDK
find_package(AWSSDK REQUIRED COMPONENTS s3-crt HINTS ${AWS_SDK_PATH} NO_DEFAULT_PATH)

I can see it quite deviates from our example app cmake script and our local test app within the main repo. Your application is compiled successfully, but fails to be linked (because sdk libraries are not added to the linker input (or wrong libs added).

I'm not entirely sure why you are manually setting certain cmake variables (such as AWSSDK_ROOT_DIR, AWSSDK_INCLUDE_DIR, AWSSDK_LIB_DIR). I can also see that both CMAKE_PREFIX_PATH and CMAKE_MODULE_PATH are set with the SDK install path.

Typically we recommend setting only the CMAKE_PREFIX_PATH to contain an install path of the SDK, and then calling

find_package(AWSSDK REQUIRED COMPONENTS s3-crt)

I'm not sure what will happen if the SDK install path is pushed into different cmake package/library search variables, as well as manually set AWSSDK_LIB_DIR. Please let us know if there is a specific reason for your approach and you would have any suggestion what to update in our cmake script.

Well, I tried this out with the example CMakeLists.txt file that you linked from here. My reasoning for manually setting the directories was to isolate and ensure that only the directories that I was pointing it to were used for linking the libraries. However, it seems that this approach was flawed due to some unforeseen details. I still don't fully understand everything that's going on under the hood with CMake, but I suppose that's for me to find out.

For anyone who needs reference, this CMakeLists.txt file worked for me:

# Copyright Amazon.com, Inc. or its affiliates. All Rights Reserved.
# SPDX-License-Identifier: Apache-2.0

cmake_minimum_required(VERSION 3.13)
# -- Preamble --
project("sample_app"
        LANGUAGES CXX
        VERSION 1.0
        DESCRIPTION "A testing app using AWS SDK for C++"
        )

# -- Project wide setup --
# Setting C++ minimum requirements
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

set(LIBTORCH_PATH "$ENV{HOME}/autolabel-anything-c++/libs/libtorch-debug")
set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} "/home/davidn/autolabel-anything-c++/libs/aws-sdk-cpp-1.11.234_out_debug")
set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH} ${LIBTORCH_PATH})

# Setting build to hide symbols in targets by default
set(CMAKE_CXX_VISIBILITY_PRESET hidden)
set(CMAKE_VISIBILITY_INLINES_HIDDEN YES)

# Preventing writes to package registry by default
set(CMAKE_EXPORT_NO_PACKAGE_REGISTRY YES)

# Validating config type and setting default if needed
get_property(is_multi_conf_build GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
if (NOT is_multi_conf_build)
    set(allowed_build_types Debug Release RelWithDebInfo MinSizeRel)
    # cmake-gui helper
    set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${allowed_build_types}")
    if (NOT CMAKE_BUILD_TYPE)
        message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
        set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Choose the type of build." FORCE)
    elseif (NOT CMAKE_BUILD_TYPE IN_LIST allowed_build_types)
        message(FATAL_ERROR "Unknown build type: ${CMAKE_BUILD_TYPE}")
    endif ()
endif ()

# -- Dependencies --
find_package(AWSSDK REQUIRED COMPONENTS s3)
find_package(Torch)

# -- main build target --
add_executable(app "aws-s3-fetch.cpp")
target_link_libraries(app ${AWSSDK_LINK_LIBRARIES} ${TORCH_LIBRARIES})
target_include_directories(app PRIVATE ${AWSSDK_INCLUDE_DIRS} "/home/davidn/autolabel-anything-c++/aws-lambda-cpp-hello/include")

# -- install target --
include(GNUInstallDirs)
set(CMAKE_INSTALL_DOCDIR ${CMAKE_INSTALL_DATAROOTDIR}/doc/${PROJECT_NAME})

install(TARGETS app
        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
        )

Thank you for your suggestion.

[jmklix]

@DavidEnriqueNieves I glade that you were able to get it working. Closing this issue as there is a working solution. Please let me know if you run into more problems when using this sdk with libtorch.

[github-actions]

This issue is now closed. Comments on closed issues are hard for our team to see.
If you need more assistance, please open a new issue that references this one.