forked from ichiban/prolog
-
Notifications
You must be signed in to change notification settings - Fork 0
/
bootstrap.pl
259 lines (179 loc) · 4.81 KB
/
bootstrap.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
/*
* bootstrap script
*/
% Operators
:-(op(1200, xfx, [:-, -->])).
:-(op(1200, fx, [:-, ?-])).
:-(op(1105, xfy, '|')).
:-(op(1100, xfy, ;)).
:-(op(1050, xfy, ->)).
:-(op(1000, xfy, ',')).
:-(op(900, fy, \+)).
:-(op(700, xfx, [=, \=])).
:-(op(700, xfx, [==, \==, @<, @=<, @>, @>=])).
:-(op(700, xfx, =..)).
:-(op(700, xfx, [is, =:=, =\=, <, =<, >, >=])).
:-(op(600, xfy, :)).
:-(op(500, yfx, [+, -, /\, \/])).
:-(op(400, yfx, [*, /, //, div, rem, mod, <<, >>])).
:-(op(200, xfx, **)).
:-(op(200, xfy, ^)).
:-(op(200, fy, [+, -, \])).
% Control constructs
true.
fail :- \+true.
! :- !.
P, Q :- call((P, Q)).
If -> Then; _ :- If, !, Then.
_ -> _; Else :- !, Else.
P; Q :- call((P; Q)).
If -> Then :- If, !, Then.
% Term unification
X \= Y :- \+(X = Y).
% Type testing
atomic(X) :-
nonvar(X),
\+compound(X).
nonvar(X) :- \+var(X).
number(X) :- float(X).
number(X) :- integer(X).
callable(X) :- atom(X).
callable(X) :- compound(X).
ground(X) :- term_variables(X, []).
% Term comparison
X @=< Y :- compare(=, X, Y).
X @=< Y :- compare(<, X, Y).
X == Y :- compare(=, X, Y).
X \== Y :- \+(X == Y).
X @< Y :- compare(<, X, Y).
X @> Y :- compare(>, X, Y).
X @>= Y :- compare(>, X, Y).
X @>= Y :- compare(=, X, Y).
% Clause creation and destruction
retractall(Head) :-
retract((Head :- _)),
fail.
retractall(_).
% Stream selection and control
open(Filename, Mode, Stream) :-
open(Filename, Mode, Stream, []).
close(Stream) :- close(Stream, []).
flush_output :-
current_output(S),
flush_output(S).
at_end_of_stream :-
current_input(S),
at_end_of_stream(S).
at_end_of_stream(Stream) :-
stream_property(Stream, end_of_stream(E)), !,
(E = at; E = past).
% Character input/output
get_char(Char) :-
current_input(S),
get_char(S, Char).
get_code(Code) :-
current_input(S),
get_code(S, Code).
get_code(Stream, Code) :-
get_char(Stream, Char),
(Char = end_of_file -> Code = -1; char_code(Char, Code)).
peek_char(Char) :-
current_input(S),
peek_char(S, Char).
peek_code(Code) :-
current_input(S),
peek_code(S, Code).
peek_code(Stream, Code) :-
peek_char(Stream, Char),
(Char = end_of_file -> Code = -1; char_code(Char, Code)).
put_char(Char) :-
current_output(S),
put_char(S, Char).
put_code(Code) :-
current_output(S),
put_code(S, Code).
put_code(S, Code) :-
char_code(Char, Code),
put_char(S, Char).
nl :-
current_output(S),
nl(S).
nl(S) :-
put_char(S, '\n').
% Byte input/output
get_byte(Byte) :-
current_input(S),
get_byte(S, Byte).
peek_byte(Byte) :-
current_input(S),
peek_byte(S, Byte).
put_byte(Byte) :-
current_output(S),
put_byte(S, Byte).
% Term input/output
read_term(Term, Options) :-
current_input(S),
read_term(S, Term, Options).
read(Term) :-
current_input(S),
read(S, Term).
read(Stream, Term) :- read_term(Stream, Term, []).
write_term(Term, Options) :-
current_output(S),
write_term(S, Term, Options).
write(Term) :-
current_output(S),
write(S, Term).
write(Stream, Term) :- write_term(Stream, Term, [numbervars(true)]).
writeq(Term) :-
current_output(S),
writeq(S, Term).
writeq(Stream, Term) :- write_term(Stream, Term, [quoted(true), numbervars(true)]).
write_canonical(Term) :-
current_output(S),
write_canonical(S, Term).
write_canonical(Stream, Term) :- write_term(Stream, Term, [quoted(true), ignore_ops(true)]).
% Logic and control
once(P) :- P, !.
false :- fail.
% Atomic term processing
% Implementation defined hooks
halt :- halt(0).
% Consult
[H|T] :- consult([H|T]).
% Definite clause grammar
phrase(GRBody, S0) :- phrase(GRBody, S0, []).
% Prolog prologue
member(X, [X|_]).
member(X, [_|Xs]) :- member(X, Xs).
select(E, [E|Xs], Xs).
select(E, [X|Xs], [X|Ys]) :-
select(E, Xs, Ys).
maplist(_Cont_1, []).
maplist(Cont_1, [E1|E1s]) :-
call(Cont_1, E1),
maplist(Cont_1, E1s).
maplist(_Cont_2, [], []).
maplist(Cont_2, [E1|E1s], [E2|E2s]) :-
call(Cont_2, E1, E2),
maplist(Cont_2, E1s, E2s).
maplist(_Cont_3, [], [], []).
maplist(Cont_3, [E1|E1s], [E2|E2s], [E3|E3s]) :-
call(Cont_3, E1, E2, E3),
maplist(Cont_3, E1s, E2s, E3s).
maplist(_Cont_4, [], [], [], []).
maplist(Cont_4, [E1|E1s], [E2|E2s], [E3|E3s], [E4|E4s]) :-
call(Cont_4, E1, E2, E3, E4),
maplist(Cont_4, E1s, E2s, E3s, E4s).
maplist(_Cont_5, [], [], [], [], []).
maplist(Cont_5, [E1|E1s], [E2|E2s], [E3|E3s], [E4|E4s], [E5|E5s]) :-
call(Cont_5, E1, E2, E3, E4, E5),
maplist(Cont_5, E1s, E2s, E3s, E4s, E5s).
maplist(_Cont_6, [], [], [], [], [], []).
maplist(Cont_6, [E1|E1s], [E2|E2s], [E3|E3s], [E4|E4s], [E5|E5s], [E6|E6s]) :-
call(Cont_6, E1, E2, E3, E4, E5, E6),
maplist(Cont_6, E1s, E2s, E3s, E4s, E5s, E6s).
maplist(_Cont_7, [], [], [], [], [], [], []).
maplist(Cont_7, [E1|E1s], [E2|E2s], [E3|E3s], [E4|E4s], [E5|E5s], [E6|E6s], [E7|E7s]) :-
call(Cont_7, E1, E2, E3, E4, E5, E6, E7),
maplist(Cont_7, E1s, E2s, E3s, E4s, E5s, E6s, E7s).