-
Notifications
You must be signed in to change notification settings - Fork 0
/
space_2d.pl
252 lines (189 loc) · 9.65 KB
/
space_2d.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Point representation in 2d space with integer coordinates %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%point(?X, ?Y)
point(X, Y) :-
(integer(X); var(X)),
(integer(Y); var(Y)).
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Projection of the vector point(X0,Y0) -> point(X,Y) on N,S,W,E axes %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%projection_north(+point(X0,Y0), +point(X,Y), -Projection)
projection_north(point(_,Y0), point(_,Y), Projection) :- nonvar(Y0), nonvar(Y), Projection is Y - Y0, !. % green cut
%projection_north(+point(X0,Y0), -point(X,Y), +Projection)
projection_north(point(_,Y0), point(_,Y), Projection) :- nonvar(Y0), nonvar(Projection), Y is Y0 + Projection.
%projection_south(+point(X0,Y0), +point(X,Y), -Projection)
projection_south(point(_,Y0), point(_,Y), Projection) :- nonvar(Y0), nonvar(Y), Projection is Y0 - Y, !. % green cut
%projection_south(+point(X0,Y0), -point(X,Y), +Projection)
projection_south(point(_,Y0), point(_,Y), Projection) :- nonvar(Y0), nonvar(Projection), Y is Y0 - Projection.
%projection_east(+point(X0,Y0), +point(X,Y), -Projection)
projection_east(point(X0,_), point(X,_), Projection) :- nonvar(X0), nonvar(X), Projection is X - X0, !. % green cut
%projection_east(+point(X0,Y0), -point(X,Y), +Projection)
projection_east(point(X0,_), point(X,_), Projection) :- nonvar(X0), nonvar(Projection), X is X0 + Projection.
%projection_west(+point(X0,Y0), +point(X,Y), -Projection)
projection_west(point(X0,_), point(X,_), Projection) :- nonvar(X0), nonvar(X), Projection is X0 - X, !. % green cut
%projection_west(+point(X0,Y0), -point(X,Y), +Projection)
projection_west(point(X0,_), point(X,_), Projection) :- nonvar(X0), nonvar(Projection), X is X0 - Projection.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Moving some steps towards one particular direction (N,S,W,E) %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% By design, "Steps" > 0.
%steps_north(+P0, ?P, ?Steps)
steps_north(P0, P, Steps) :-
projection_north(P0, P, Steps),
projection_east(P0, P, 0),
Steps > 0.
%steps_south(+P0, ?P, ?Steps)
steps_south(P0, P, Steps) :-
projection_south(P0, P, Steps),
projection_east(P0, P, 0),
Steps > 0.
%steps_east(+P0, ?P, ?Steps)
steps_east(P0, P, Steps) :-
projection_east(P0, P, Steps),
projection_north(P0, P, 0),
Steps > 0.
%steps_west(+P0, ?P, ?Steps)
steps_west(P0, P, Steps) :-
projection_west(P0, P, Steps),
projection_north(P0, P, 0),
Steps > 0.
%steps_north_east(+P0, ?P, ?Steps)
steps_north_east(P0, P, Steps) :-
projection_north(P0, P, Steps),
projection_east(P0, P, Steps),
Steps > 0.
%steps_north_west(+P0, ?P, ?Steps)
steps_north_west(P0, P, Steps) :-
projection_north(P0, P, Steps),
projection_west(P0, P, Steps),
Steps > 0.
%steps_south_east(+P0, ?P, ?Steps)
steps_south_east(P0, P, Steps) :-
projection_south(P0, P, Steps),
projection_east(P0, P, Steps),
Steps > 0.
%steps_south_west(+P0, ?P, ?Steps)
steps_south_west(P0, P, Steps) :-
projection_south(P0, P, Steps),
projection_west(P0, P, Steps),
Steps > 0.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Relevant alignements between two points %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%aligned_north(+P0, +P)
aligned_north(P0, P) :- steps_north(P0, P, _).
%aligned_south(+P0, +P)
aligned_south(P0, P) :- steps_south(P0, P, _).
%aligned_east(+P0, +P)
aligned_east(P0, P) :- steps_east(P0, P, _).
%aligned_west(+P0, +P)
aligned_west(P0, P) :- steps_west(P0, P, _).
%aligned_north_east(+P0, +P)
aligned_north_east(P0, P) :- steps_north_east(P0, P, _).
%aligned_north_west(+P0, +P)
aligned_north_west(P0, P) :- steps_north_west(P0, P, _).
%aligned_east(point(+P0, +P)
aligned_south_east(P0, P) :- steps_south_east(P0, P, _).
%aligned_west(point(+P0, +P)
aligned_south_west(P0, P) :- steps_south_west(P0, P, _).
%aligned_vertically(+P0, +P)
aligned_vertically(P0, P) :- aligned_north(P0, P), !. % green cut
aligned_vertically(P0, P) :- aligned_south(P0, P).
%aligned_horizontally(+P0, +P)
aligned_horizontally(P0, P) :- aligned_east(P0, P), !. % green cut
aligned_horizontally(P0, P) :- aligned_west(P0, P).
%aligned_main_diagonal(+P0, +P)
aligned_main_diagonal(P0, P) :- aligned_north_west(P0, P), !. % green cut
aligned_main_diagonal(P0, P) :- aligned_south_east(P0, P).
%aligned_anti_diagonal(+P0, +P)
aligned_anti_diagonal(P0, P) :- aligned_north_east(P0, P), !. % green cut
aligned_anti_diagonal(P0, P) :- aligned_south_west(P0, P).
%aligned_axis(+P0, +P)
aligned_axis(P0, P) :- aligned_vertically(P0, P), !. % green cut
aligned_axis(P0, P) :- aligned_horizontally(P0, P).
%aligned_diagonal(+P0, +P)
aligned_diagonal(P0, P) :- aligned_main_diagonal(P0, P), !. % green cut
aligned_diagonal(P0, P) :- aligned_anti_diagonal(P0, P).
%aligned(+P0, +P)
aligned(P0, P) :- aligned_axis(P0, P), !. % green cut
aligned(P0, P) :- aligned_diagonal(P0, P).
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Lists of points between two (aligned) points %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%in_between_north(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_north(point(X0,Y0), point(X0,Y), [point(X0,Yi)]) :- Yi is Y0 + 1, Yi is Y - 1, !. % green cut
in_between_north(point(X0,Y0), point(X0,Y), [point(X0,Yi) | Other_points]) :-
Yi is Y0 + 1, Yi < Y,
in_between_north(point(X0,Yi), point(X0,Y), Other_points).
%in_between_south(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_south(point(X0,Y0), point(X0,Y), [point(X0,Yi)]) :- Yi is Y0 - 1, Yi is Y + 1, !. % green cut
in_between_south(point(X0,Y0), point(X0,Y), [point(X0,Yi) | Other_points]) :-
Yi is Y0 - 1, Yi > Y,
in_between_south(point(X0,Yi), point(X0,Y), Other_points).
%in_between_east(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_east(point(X0,Y0), point(X,Y0), [point(Xi,Y0)]) :- Xi is X0 + 1, Xi is X - 1, !. % green cut
in_between_east(point(X0,Y0), point(X,Y0), [point(Xi,Y0) | Other_points]) :-
Xi is X0 + 1, Xi < X,
in_between_east(point(Xi,Y0), point(X,Y0), Other_points).
%in_between_west(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_west(point(X0,Y0), point(X,Y0), [point(Xi,Y0)]) :- Xi is X0 - 1, Xi is X + 1, !. % green cut
in_between_west(point(X0,Y0), point(X,Y0), [point(Xi,Y0) | Other_points]) :-
Xi is X0 - 1, Xi > X,
in_between_west(point(Xi,Y0), point(X,Y0), Other_points).
%in_between_north_east(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_north_east(point(X0,Y0), point(X,Y), [point(Xi,Yi)]) :-
Xi is X0 + 1, Xi is X - 1,
Yi is Y0 + 1, Yi is Y - 1, !. % green cut
in_between_north_east(point(X0,Y0), point(X,Y), [point(Xi,Yi) | Other_points]) :-
Xi is X0 + 1, Xi < X,
Yi is Y0 + 1, Yi < Y,
in_between_north_east(point(Xi,Yi), point(X,Y), Other_points).
%in_between_north_west(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_north_west(point(X0,Y0), point(X,Y), [point(Xi,Yi)]) :-
Xi is X0 - 1, Xi is X + 1,
Yi is Y0 + 1, Yi is Y - 1, !. % green cut
in_between_north_west(point(X0,Y0), point(X,Y), [point(Xi,Yi) | Other_points]) :-
Xi is X0 - 1, Xi > X,
Yi is Y0 + 1, Yi < Y,
in_between_north_west(point(Xi,Yi), point(X,Y), Other_points).
%in_between_south_east(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_south_east(point(X0,Y0), point(X,Y), [point(Xi,Yi)]) :-
Xi is X0 + 1, Xi is X - 1,
Yi is Y0 - 1, Yi is Y + 1, !. % green cut
in_between_south_east(point(X0,Y0), point(X,Y), [point(Xi,Yi) | Other_points]) :-
Xi is X0 + 1, Xi < X,
Yi is Y0 - 1, Yi > Y,
in_between_south_east(point(Xi,Yi), point(X,Y), Other_points).
%in_between_south_west(point(+X0,+Y0), point(+X,+Y), -Points)
in_between_south_west(point(X0,Y0), point(X,Y), [point(Xi,Yi)]) :-
Xi is X0 - 1, Xi is X + 1,
Yi is Y0 - 1, Yi is Y + 1, !. % green cut
in_between_south_west(point(X0,Y0), point(X,Y), [point(Xi,Yi) | Other_points]) :-
Xi is X0 - 1, Xi > X,
Yi is Y0 - 1, Yi > Y,
in_between_south_west(point(Xi,Yi), point(X,Y), Other_points).
%in_between(+P0, +P, -Points)
in_between(P0, P, Points) :- in_between_north(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_south(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_east(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_west(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_north_east(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_north_west(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_south_east(P0, P, Points), !. % green cut
in_between(P0, P, Points) :- in_between_south_west(P0, P, Points).
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Miscellaneous %%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%adjacent(+point(X0,Y0), ?point(X,Y))
adjacent(point(X0,Y0), point(X,Y)) :-
(X is X0 - 1; X is X0; X is X0 + 1),
(Y is Y0 - 1; Y is Y0; Y is Y0 + 1),
not (X = X0, Y = Y0). % comment out this subgoal to include the soultion where point(X,Y) is the same as point(X0,Y0)
%l_pattern(+point(X0,Y0), ?point(X,Y))
l_pattern(point(X0,Y0), point(X,Y)) :-
(X is X0 + 2; X is X0 - 2),
(Y is Y0 + 1; Y is Y0 - 1).
l_pattern(point(X0,Y0), point(X,Y)) :-
(X is X0 + 1; X is X0 - 1),
(Y is Y0 + 2; Y is Y0 - 2).