-
Notifications
You must be signed in to change notification settings - Fork 1
/
BuildAll.cmd
53 lines (45 loc) · 1.21 KB
/
BuildAll.cmd
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
@echo off
rem ************************************************************
rem
rem Script to build all solutions for Debug and/or Release
rem targets.
rem
rem NB: See Build.cmd for notes about setting the environment
rem variables up first.
rem
rem ************************************************************
setlocal enabledelayedexpansion
:handle_help_request
if /i "%~1" == "-?" call :usage & exit /b 0
if /i "%~1" == "--help" call :usage & exit /b 0
:check_args
if /i "%~1" == "" call :usage & exit /b 1
:verify_toolchain
if /i "%TOOLCHAIN%" == "" (
echo ERROR: Compiler environment variables not set. Run 'SetVars' first.
exit /b 1
)
set build=%~1
:do_builds
for /r %%i in (*.sln) do (
echo ============================================================
echo Building '%%i'
echo ============================================================
call "%~dp0Build.cmd" %build% "%%i"
if errorlevel 1 (
echo.
echo ERROR: Failed to build solution.
exit /b 1
)
)
:success
exit /b 0
rem ************************************************************
rem Functions
rem ************************************************************
:usage
echo.
echo Usage: %~n0 [debug ^| release ^| all]
echo.
echo e.g. %~n0 debug
goto :eof