-
Notifications
You must be signed in to change notification settings - Fork 0
/
flake.nix
321 lines (282 loc) · 9.46 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
{
description = "Chris' scripts, dev shells, home-manager config, and nixOS configs";
nixConfig = {
extra-substituters = [ "https://chrisportela-dotfiles.cachix.org" ];
extra-trusted-public-keys = [ "chrisportela-dotfiles.cachix.org-1:e3UVWzLbmS6YLEUaY1BQt124GENPRF74YMgwV/6+Li4=" ];
};
inputs = {
nixos.url = "github:nixos/nixpkgs/nixos-24.05";
nixpkgs.url = "github:nixos/nixpkgs/release-24.05";
nixos-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
nixpkgs-unstable.url = "github:nixos/nixpkgs/nixpkgs-unstable";
nixpkgs-darwin.url = "github:nixos/nixpkgs/nixpkgs-24.05-darwin";
home-manager.url = "github:nix-community/home-manager/release-24.05";
home-manager-master.url = "github:nix-community/home-manager/release-24.05";
darwin = {
url = "github:lnl7/nix-darwin/master";
inputs.nixpkgs.follows = "nixpkgs-darwin";
};
disko = {
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
nixos-hardware.url = "github:NixOS/nixos-hardware/master";
agenix.url = "github:ryantm/agenix";
deploy-rs.url = "github:serokell/deploy-rs";
vscode-server.url = "github:nix-community/nixos-vscode-server";
rust-overlay.url = "github:oxalica/rust-overlay";
# For installer target
nixos-generators.url = "github:nix-community/nixos-generators";
};
outputs = inputs @ { self, nixpkgs, darwin, home-manager, ... }:
let
linuxSystems = [
"x86_64-linux" # 64-bit Intel/AMD Linux
"aarch64-linux" # 64-bit ARM Linux
];
darwinSystems = [
"x86_64-darwin" # 64-bit Intel macOS
"aarch64-darwin" # 64-bit ARM macOS
];
# Systems supported
allSystems = linuxSystems ++ darwinSystems;
importPkgs = (system: import nixpkgs {
inherit system;
});
# Helper to provide system-specific attributes
forEachSystem = systems: f: nixpkgs.lib.genAttrs systems (system: f {
inherit system;
pkgs = (import nixpkgs {
inherit system;
overlays = [ self.overlays.terraform ];
config.allowUnfreePredicate = pkg: builtins.elem (nixpkgs.lib.getName pkg) [
"terraform"
];
});
});
forAllSystems = forEachSystem allSystems;
forAllLinuxSystems = forEachSystem linuxSystems;
forAllDarwinSystems = forEachSystem darwinSystems;
forAllSystemsShell = (systems: f: nixpkgs.lib.genAttrs systems (system: f {
inherit system;
pkgs = (import nixpkgs {
inherit system;
overlays = with self.overlays; [
rust
rustToolchain
deploy-rs
terraform
];
config.allowUnfreePredicate = pkg: builtins.elem (nixpkgs.lib.getName pkg) [
"terraform"
];
});
})) allSystems;
homeConfig = ({ pkgs
, home ? ./home/default.nix
, username ? "cmp"
, allowUnfree ? [ ]
, options ? { }
}:
home-manager.lib.homeManagerConfiguration {
inherit pkgs;
modules = [
({ pkgs, lib, ... }: {
home.username = username;
nixpkgs.config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) allowUnfree;
})
home
options
];
});
in
{
lib = {
inherit allSystems importPkgs forAllSystems forAllDarwinSystems forAllLinuxSystems;
};
packages = forAllSystems ({ pkgs, system }: rec {
terraform = pkgs.terraformFull;
default = self.legacyPackages.${system}.homeConfigurations.cmp.activationPackage;
});
legacyPackages = ((nixpkgs.lib.foldl (a: b: nixpkgs.lib.recursiveUpdate a b) { }) [
(forAllSystems ({ pkgs, system }: {
homeConfigurations = let
adaConfig = homeConfig {
inherit pkgs;
allowUnfree = [
"vault-bin"
"vscode"
"discord"
"obsidian"
"cider"
];
options = { pkgs, lib, ... }: {
programs = {
vscode.enable = true;
chromium.enable = true;
mpv.enable = true;
};
services.ssh-agent.enable = true;
home.packages = with pkgs; [
beekeeper-studio
cider
discord
jrnl
obsidian
ollama
onlyoffice-bin_latest
signal-desktop
sqlitebrowser
trayscale
];
home.shellAliases = {
# "cb" = "${pkgs.nodePackages.clipboard-cli}/bin/clipboard";
};
nixpkgs = { };
};
};
in {
"cmp" = homeConfig {
inherit pkgs;
allowUnfree = [ "vault-bin" ];
};
"cmp@flamme" = adaConfig;
"cmp@ada" = adaConfig;
};
}))
(forAllLinuxSystems ({ pkgs, system }: {
installer-iso = self.nixosConfigurations.installer.config.formats.iso;
}))
]);
overlays = {
rust = (import inputs.rust-overlay);
# Provides a `rustToolchain` attribute for Nixpkgs that we can use to
# create a Rust environment
rustToolchain = (final: prev: {
rustToolchain = prev.rust-bin.stable.latest.default;
});
deploy-rs = (final: prev: {
deploy-rs = inputs.deploy-rs.defaultPackage.${final.stdenv.system};
});
terraform = (final: prev: {
terraformFull = final.terraform.withPlugins (p: [
p.cloudflare
p.aws
p.google
p.google-beta
]);
});
};
homeConfigurations = {
"deck@steamdeck" = homeConfig {
username = "deck";
pkgs = importPkgs "x86_64-linux";
allowUnfree = [ "vault-bin" ];
};
};
nixosModules = (import ./lib/nixos/modules/default.nix);
nixosConfigurations = {
installer = (import ./lib/nixos/configurations/installer.nix) {
inherit inputs self;
nixpkgs = inputs.nixpkgs;
};
builder = (import ./lib/nixos/configurations/builder.nix) {
nixpkgs = inputs.nixpkgs;
nixosModules = self.nixosModules;
};
ada = (import ./lib/nixos/configurations/ada.nix) {
inherit inputs;
nixosModules = self.nixosModules;
};
flamme = (import ./lib/nixos/configurations/flamme.nix) {
inherit inputs;
nixosModules = self.nixosModules;
};
};
darwinModules = {
common = ./lib/darwin/common.nix;
nixpkgs = ./lib/darwin/nixpkgs.nix;
};
darwinConfigurations = {
lux = darwin.lib.darwinSystem {
system = "aarch64-darwin";
specialArgs = {
inherit inputs;
overlays = with self.overlays; [ deploy-rs ];
nixpkgs = inputs.nixpkgs;
};
modules = with self.darwinModules; [
common
./lib/darwin/configurations/mba.nix
];
};
};
devShells = forAllSystemsShell ({ pkgs, system }: {
dotfiles = pkgs.mkShell {
packages = (with pkgs; [
cachix
nixd
nixpkgs-fmt
shellcheck
shfmt
]);
};
dev = pkgs.mkShell {
RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
nativeBuildInputs = with pkgs; [
pkg-config
openssl
stdenv.cc.cc.lib
];
# shellHook = ''
# export LD_LIBRARY_PATH=$LD_LIBRARY_PATH:${pkgs.stdenv.cc.cc.lib}/lib
# '';
# The Nix packages provided in the environment
packages = (with pkgs; [
rustToolchain
python311
nodejs_20
]) ++ pkgs.lib.optionals pkgs.stdenv.isDarwin (with pkgs; [
# libiconv
# darwin.apple_sdk.frameworks.SystemConfiguration
])
++ pkgs.lib.optionals pkgs.stdenv.isLinux (with pkgs; [ ]);
};
devops = pkgs.mkShell {
# The Nix packages provided in the environment
packages = (with pkgs; [
python311
nodejs_20
terraformer
terraforming
awscli2
google-cloud-sdk
terraformFull
]) ++ pkgs.lib.optionals pkgs.stdenv.isDarwin (with pkgs; [ ])
++ pkgs.lib.optionals pkgs.stdenv.isLinux (with pkgs; [ ]);
};
default = self.devShells.${system}.dotfiles;
});
checks = forAllSystems ({ pkgs, system }: {
shell-functions =
let
script = ./home/shell_functions.sh;
in
pkgs.stdenvNoCC.mkDerivation {
name = "shell-functions-check";
dontBuild = true;
src = script;
nativeBuildInputs = with pkgs; [ alejandra shellcheck shfmt ];
unpackPhase = ":";
checkPhase = ''
shfmt -d -s -i 2 -ci ${script}
alejandra -c .
shellcheck -x ${script}
'';
installPhase = ''
mkdir "$out"
'';
};
});
};
}