-
Notifications
You must be signed in to change notification settings - Fork 15
/
VirtualAccount.sol
168 lines (133 loc) · 5.86 KB
/
VirtualAccount.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import {SafeTransferLib} from "solady/utils/SafeTransferLib.sol";
import {ERC721} from "solmate/tokens/ERC721.sol";
import {ERC1155Receiver} from "@openzeppelin/contracts/token/ERC1155/utils/ERC1155Receiver.sol";
import {IERC1155Receiver} from "@openzeppelin/contracts/token/ERC1155/IERC1155Receiver.sol";
import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import {IVirtualAccount, Call, PayableCall} from "./interfaces/IVirtualAccount.sol";
import {IRootPort} from "./interfaces/IRootPort.sol";
/// @title VirtualAccount - Contract for managing a virtual user account on the Root Chain
contract VirtualAccount is IVirtualAccount, ERC1155Receiver {
using SafeTransferLib for address;
/// @inheritdoc IVirtualAccount
address public immutable override userAddress;
/// @inheritdoc IVirtualAccount
address public immutable override localPortAddress;
/*//////////////////////////////////////////////////////////////
CONSTRUCTOR
//////////////////////////////////////////////////////////////*/
/**
* @notice Constructor for Virtual Account.
* @param _userAddress Address of the user account.
* @param _localPortAddress Address of the root port contract.
*/
constructor(address _userAddress, address _localPortAddress) {
userAddress = _userAddress;
localPortAddress = _localPortAddress;
}
/*//////////////////////////////////////////////////////////////
FALLBACK FUNCTIONS
//////////////////////////////////////////////////////////////*/
receive() external payable {}
/*//////////////////////////////////////////////////////////////
EXTERNAL FUNCTIONS
//////////////////////////////////////////////////////////////*/
/// @inheritdoc IVirtualAccount
function withdrawNative(uint256 _amount) external override requiresApprovedCaller {
msg.sender.safeTransferETH(_amount);
}
/// @inheritdoc IVirtualAccount
function withdrawERC20(address _token, uint256 _amount) external override requiresApprovedCaller {
_token.safeTransfer(msg.sender, _amount);
}
/// @inheritdoc IVirtualAccount
function withdrawERC721(address _token, uint256 _tokenId) external override requiresApprovedCaller {
ERC721(_token).transferFrom(address(this), msg.sender, _tokenId);
}
/// @inheritdoc IVirtualAccount
function call(Call[] calldata calls) external override requiresApprovedCaller returns (bytes[] memory returnData) {
uint256 length = calls.length;
returnData = new bytes[](length);
for (uint256 i = 0; i < length;) {
bool success;
Call calldata _call = calls[i];
if (isContract(_call.target)) (success, returnData[i]) = _call.target.call(_call.callData);
if (!success) revert CallFailed();
unchecked {
++i;
}
}
}
/// @inheritdoc IVirtualAccount
function payableCall(PayableCall[] calldata calls) public payable returns (bytes[] memory returnData) {
uint256 valAccumulator;
uint256 length = calls.length;
returnData = new bytes[](length);
PayableCall calldata _call;
for (uint256 i = 0; i < length;) {
_call = calls[i];
uint256 val = _call.value;
// Humanity will be a Type V Kardashev Civilization before this overflows - andreas
// ~ 10^25 Wei in existence << ~ 10^76 size uint fits in a uint256
unchecked {
valAccumulator += val;
}
bool success;
if (isContract(_call.target)) (success, returnData[i]) = _call.target.call{value: val}(_call.callData);
if (!success) revert CallFailed();
unchecked {
++i;
}
}
// Finally, make sure the msg.value = SUM(call[0...i].value)
if (msg.value != valAccumulator) revert CallFailed();
}
/*//////////////////////////////////////////////////////////////
EXTERNAL HOOKS
//////////////////////////////////////////////////////////////*/
/// @inheritdoc IERC721Receiver
function onERC721Received(address, address, uint256, bytes calldata) external pure override returns (bytes4) {
return this.onERC721Received.selector;
}
/// @inheritdoc IERC1155Receiver
function onERC1155Received(address, address, uint256, uint256, bytes calldata)
external
pure
override
returns (bytes4)
{
return this.onERC1155Received.selector;
}
/// @inheritdoc IERC1155Receiver
function onERC1155BatchReceived(address, address, uint256[] calldata, uint256[] calldata, bytes calldata)
external
pure
override
returns (bytes4)
{
return this.onERC1155BatchReceived.selector;
}
/*//////////////////////////////////////////////////////////////
INTERNAL HELPERS
//////////////////////////////////////////////////////////////*/
function isContract(address addr) internal view returns (bool) {
uint256 size;
assembly {
size := extcodesize(addr)
}
return size > 0;
}
/*///////////////////////////////////////////////////////////////
MODIFIERS
//////////////////////////////////////////////////////////////*/
/// @notice Modifier that verifies msg sender is the approved to use the virtual account. Either the owner or an approved router.
modifier requiresApprovedCaller() {
if (!IRootPort(localPortAddress).isRouterApproved(this, msg.sender)) {
if (msg.sender != userAddress) {
revert UnauthorizedCaller();
}
}
_;
}
}