-
Notifications
You must be signed in to change notification settings - Fork 0
/
uBank.pas
290 lines (222 loc) · 7.84 KB
/
uBank.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
unit uBank;
interface
uses
System.Generics.Collections;
type
{ Base class for all our transactions }
TTransaction = class
private
FId: integer;
FAmount: Currency;
FDateTime: TDateTime;
FDescription: string;
class var
FIdSeed: integer;
protected
constructor Create(AAmount: Currency; ADescription: string);
public
property Id: integer read FId;
property Amount: Currency read FAmount;
property DateTime: TDateTime read FDateTime;
property Description: string read FDescription;
function ToString: string; override;
end;
{ Represents a deposit }
TDeposit = class(TTransaction)
public
constructor Create(AAmount: Currency);
end;
{ Represents a withdrawal }
TWithdrawal = class(TTransaction)
public
constructor Create(AAmount: Currency);
end;
{ an account at the bank }
TAccount = class
private
FName: string;
FTransactions: TObjectList<TTransaction>;
function GetBalance: Currency;
public
constructor Create(AName: string);
destructor Destroy; override;
property Name: string read FName;
property Balance: Currency read GetBalance;
function GetEnumerator: TEnumerator<TTransaction>;
procedure Withdraw(AAmount: Currency);
procedure Deposit(AAmount: Currency);
procedure Add(ATransaction: TTransaction);
class procedure ValidateName(AName: string);
end;
{ the bank }
TBank = class
private
FAccounts: TObjectDictionary<string, TAccount>;
public
constructor Create;
destructor Destroy; override;
function GetEnumerator: TEnumerator<TAccount>;
function CreateAccount(AName: string): TAccount;
end;
{ the mini statement }
TMiniStatement = class
class function Generate(ABank: TBank): string;
end;
implementation
uses
System.SysUtils, System.Generics.Defaults, System.RegularExpressions;
{ TBank }
{------------------------------------------------------------------------------------------------------------}
constructor TBank.Create;
begin
FAccounts := TObjectDictionary<string, TAccount>.Create(
[doOwnsValues],
TIStringComparer.Ordinal);
end;
{------------------------------------------------------------------------------------------------------------}
function TBank.CreateAccount(AName: string): TAccount;
begin
TAccount.ValidateName(AName);
if FAccounts.ContainsKey(AName) then
raise EArgumentException.Create('Account already exists error: ' + AName);
Result := TAccount.Create(AName);
FAccounts.Add(Result.Name, Result);
end;
{------------------------------------------------------------------------------------------------------------}
destructor TBank.Destroy;
begin
if Assigned(FAccounts) then
FreeAndNil(FAccounts);
inherited;
end;
{------------------------------------------------------------------------------------------------------------}
function TBank.GetEnumerator: TEnumerator<TAccount>;
begin
Result := FAccounts.Values.GetEnumerator;
end;
{ TAccount }
{------------------------------------------------------------------------------------------------------------}
procedure TAccount.Add(ATransaction: TTransaction);
begin
if (not Assigned(ATransaction)) or (ATransaction.Amount <= 0) then
raise EArgumentException.Create('Invalid transaction error.');
if (ATransaction is TWithdrawal) and (ATransaction.Amount > Balance) then
raise EArgumentException.Create('Insufficient funds error.');
FTransactions.Add(ATransaction);
end;
{------------------------------------------------------------------------------------------------------------}
constructor TAccount.Create(AName: string);
begin
ValidateName(AName);
FName := AName.Trim;
FTransactions := TObjectList<TTransaction>.Create;
end;
{------------------------------------------------------------------------------------------------------------}
procedure TAccount.Deposit(AAmount: Currency);
begin
Add(TDeposit.Create(AAmount));
end;
{------------------------------------------------------------------------------------------------------------}
destructor TAccount.Destroy;
begin
if Assigned(FTransactions) then
FreeAndNil(FTransactions);
inherited;
end;
{------------------------------------------------------------------------------------------------------------}
function TAccount.GetBalance: Currency;
var
Transaction: TTransaction;
begin
Result := 0;
for Transaction in FTransactions do
if Transaction is TDeposit then
Result := Result + Transaction.Amount
else
Result := Result - Transaction.Amount;
end;
{------------------------------------------------------------------------------------------------------------}
function TAccount.GetEnumerator: TEnumerator<TTransaction>;
begin
Result := FTransactions.GetEnumerator;
end;
{------------------------------------------------------------------------------------------------------------}
class procedure TAccount.ValidateName(AName: string);
begin
if string.IsNullOrWhitespace(AName) then
raise EArgumentException.Create('Account name is missing a value.');
if (AName.Length < 2) or (AName.Length > 20) then
raise EArgumentException.Create('Account name must be between 2-20 characters in length.');
if not TRegEx.IsMatch(AName, '^[A-Z]*$', [roIgnoreCase]) then
raise EArgumentException.Create('Account name must contain letters only.');
end;
{------------------------------------------------------------------------------------------------------------}
procedure TAccount.Withdraw(AAmount: Currency);
begin
Add(TWithdrawal.Create(AAmount));
end;
{ TTransaction }
{------------------------------------------------------------------------------------------------------------}
constructor TTransaction.Create(AAmount: Currency; ADescription: string);
begin
if (AAmount <= 0) then
raise EArgumentException.Create('Transaction amount must be greater than zero');
FId := AtomicIncrement(FIdSeed);
FAmount := AAmount;
FDateTime := Now;
FDescription := ADescription;
end;
{------------------------------------------------------------------------------------------------------------}
function TTransaction.ToString: string;
begin
Result := Format('%-4s %s %-15s %s', [
FId.ToString,
FormatDateTime('dd/mm/yy', FDateTime),
FDescription,
CurrToStrF(FAmount, ffCurrency, 2)]);
end;
{ TDeposit }
{------------------------------------------------------------------------------------------------------------}
constructor TDeposit.Create(AAmount: Currency);
begin
if AAmount <= 0 then
raise EArgumentException.Create('Invalid deposit amount error.');
inherited Create(AAmount, 'deposit');
end;
{ TWithdrawal }
{------------------------------------------------------------------------------------------------------------}
constructor TWithdrawal.Create(AAmount: Currency);
begin
if AAmount <= 0 then
raise EArgumentException.Create('Invalid withdrawal amount error.');
inherited Create(AAmount, 'withdrawal');
end;
{ TMiniStatement }
{------------------------------------------------------------------------------------------------------------}
class function TMiniStatement.Generate(ABank: TBank): string;
var
Sb: TStringBuilder;
Balance: string;
Account: TAccount;
Transaction: TTransaction;
begin
Sb := TStringBuilder.Create;
try
Sb.Append('Bank of Delphi MiniStatement')
.AppendLine;
for Account in ABank do begin
Balance := CurrToStrF(Account.GetBalance, ffCurrency, 2);
Sb.AppendLine
.Append(Format('Act: %-45s Bal: %s', [Account.Name, Balance]))
.AppendLine;
for Transaction in Account do begin
sb.Append(#9 + Transaction.ToString)
.AppendLine;
end;
end;
Result := sb.ToString.Trim;
finally
FreeAndNil(Sb);
end;
end;
end.