-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
153 lines (130 loc) · 3.67 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
import com.github.spotbugs.snom.SpotBugsTask
plugins {
id 'java-library'
id 'maven-publish'
id 'jacoco'
id 'com.github.spotbugs' version '5.0.13'
}
ext {
versions = [:]
versions.spring = System.getenv("SPRING") == '5' ? '5.3.24' : '6.0.3'
versions.springApi = System.getenv("SPRING") == '5' ? '5.1.0.RELEASE' : '6.0.0'
versions.target = System.getenv("SPRING") == '5' ? 8 : 17
versions.junit = '5.9.1'
}
version = "${majorVersion}.${minorVersion}.${patchVersion}"
// dependencies
repositories {
mavenLocal()
mavenCentral()
}
dependencies {
api "org.springframework:spring-context:${versions.springApi}"
implementation "org.springframework:spring-context:${versions.spring}"
testImplementation "org.junit.jupiter:junit-jupiter-api:${versions.junit}",
"org.springframework:spring-test:${versions.spring}",
'org.hamcrest:hamcrest:2.2',
'org.mockito:mockito-junit-jupiter:4.10.0'
testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${versions.junit}"
}
// compiling
java {
sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.toVersion(versions.target)
withJavadocJar()
withSourcesJar()
}
tasks.withType(JavaCompile) {
configure(options) {
encoding = 'UTF-8'
deprecation = true
compilerArgs << "-Xlint:unchecked"
}
}
// unit tests
test {
useJUnitPlatform()
}
// publishing
javadoc {
options {
memberLevel = JavadocMemberLevel.PROTECTED
source = '1.8'
author = false
header "${project.description} ${project.version}"
links 'https://docs.oracle.com/javase/8/docs/api/', "https://docs.spring.io/spring-framework/docs/${versions.spring}/javadoc-api/"
encoding 'UTF-8'
addStringOption('Xdoclint:none', '-quiet')
}
}
tasks.withType(Jar) {
from(project.projectDir) {
include 'LICENSE'
into('META-INF')
}
manifest {
attributes(
"Automatic-Module-Name": "diergo.spring.legacy",
"Specification-Title": project.description,
"Specification-Version": "${majorVersion}.${minorVersion}",
"Specification-Vendor": vendor,
"Implementation-Title": project.description,
"Implementation-Version": "${majorVersion}.${minorVersion}.${patchVersion}",
"Implementation-Vendor": vendor,
"Implementation-Vendor-Id": project.group
)
}
}
publishing {
publications {
mavenJava(MavenPublication) {
from components.java
pom {
description = project.description
licenses {
license {
name = 'The Apache License, Version 2.0'
url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
}
}
}
}
}
}
// code analysis
tasks.withType(SpotBugsTask) {
reports {
xml.required = false
html.required = true
}
}
jacocoTestReport {
reports {
html.required = true
}
}
jacocoTestCoverageVerification {
dependsOn jacocoTestReport
violationRules {
rule {
limit {
counter = 'CLASS'
minimum = 0.9
}
limit {
counter = 'LINE'
minimum = 0.8
}
limit {
counter = 'BRANCH'
minimum = 0.7
}
}
}
}
// task dependencies
check.dependsOn jacocoTestCoverageVerification, jacocoTestReport
assemble.dependsOn javadoc
wrapper {
gradleVersion = '7.6'
}