build.gradle

apply plugin: 'kotlin'

buildscript {
    ext.kotlin_version = '1.1.3'

    repositories {
        mavenCentral()
        jcenter()
        maven {
            url "http://repo.onarandombox.com/content/groups/public/"
        }
        maven {
            url "https://hub.spigotmc.org/nexus/content/groups/public/"
        }
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }

    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath "gradle.plugin.org.jetbrains.intellij.plugins:gradle-intellij-plugin:0.2.13"
        classpath "org.jetbrains.dokka:dokka-gradle-plugin:0.9.15"
    }

    ext.env = System.getenv()
    ext.buildNumber = env.BUILD_NUMBER?.toInteger() ?: "UNKNOWN"
}

configurations {
    all*.exclude group: 'org.jetbrains', module: 'ideaIC'
}

allprojects  {
    apply plugin: 'maven'
    apply plugin: 'org.jetbrains.intellij'
    apply plugin: 'org.jetbrains.dokka'

    group = 'com.dumptruckman.minecraft.pluginbase'
    version = '1.6.0-SNAPSHOT'

    uploadArchives {
        repositories {
            mavenDeployer {
                repository(url: "http://repo.onarandombox.com/content/repositories/thirdparty/")
                snapshotRepository(url: "http://repo.onarandombox.com/content/repositories/thirdparty-dev/")
            }
        }
    }

    configurations {
        all*.exclude group: 'com.jetbrains', module: 'ideaIC'
    }

    patchPluginXml.enabled = false
    prepareTestingSandbox.enabled = false
    runIde.enabled = false
    publishPlugin.enabled = false

    intellij {
        downloadSources = false
    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier 'sources'
        from sourceSets.main.allSource
    }

    dokka {
        outputFormat = 'javadoc'
        outputDirectory = "$buildDir/javadoc"
    }

    task javadocJar(type: Jar) {
        classifier 'javadoc'
        from dokka
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }
}

subprojects {
    compileKotlin {
        kotlinOptions.jvmTarget = "1.8"
    }
    compileTestKotlin {
        kotlinOptions.jvmTarget = "1.8"
    }

    apply plugin: 'java'
    apply plugin: 'kotlin'
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }

    repositories {
        mavenLocal()

        maven { url "http://repo.onarandombox.com/content/groups/public/" }
        maven { url "http://repo.maven.apache.org/maven2" }
    }

    ext {
        configurateVersion = "3.1"
        kotlinShadedPattern = "pluginbase.kotlin"
        kotlin_version = '1.1.3'
    }
  
    dependencies {
        compileOnly group: 'com.intellij', name: 'annotations', version:'12.0'
        compileOnly "org.jetbrains.kotlin:kotlin-stdlib-jre8:$kotlin_version"
        testCompile group: 'junit', name: 'junit', version:'4.12'
        testCompile group: 'org.powermock', name: 'powermock-module-junit4', version:'1.6.1'
        testCompile group: 'org.powermock', name: 'powermock-api-easymock', version:'1.6.1'
        testCompile group: 'org.powermock', name: 'powermock-api-mockito', version:'1.6.1'
        testCompile group: 'org.easymock', name: 'easymock', version:'3.4'
        testCompile "org.jetbrains.kotlin:kotlin-test-junit:$kotlin_version"
    }
}