build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'signing'
    id "com.google.cloud.artifactregistry.gradle-plugin" version "2.1.5"
}

sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

dependencies {
    //google
    implementation('com.google.inject:guice:5.0.1')

    //selenium
    implementation('org.seleniumhq.selenium:selenium-java:3.141.59')
    implementation('io.appium:java-client:7.5.1')

    //lombok
    implementation('org.projectlombok:lombok:1.18.20')
    annotationProcessor('org.projectlombok:lombok:1.18.20')
    testImplementation('org.projectlombok:lombok:1.18.20')
    testAnnotationProcessor('org.projectlombok:lombok:1.18.20')

    // generic wait
    implementation('org.awaitility:awaitility:4.1.0')
}

task sourceJar(type: Jar) {
    classifier "sources"
    from sourceSets.main.allJava
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier "javadoc"
    from javadoc.destinationDir
}

artifacts {
    archives jar
    archives sourceJar
    archives javadocJar
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            customizePom(pom)
            groupId 'dunzoit'
            artifactId 'ekam-atoms'
            version '1.0.2'

            from components.java

            artifact(sourceJar) {
                classifier = 'sources'
            }
            artifact(javadocJar) {
                classifier = 'javadoc'
            }

        }
    }

    repositories {
        maven {
            url "artifactregistry://asia-south1-maven.pkg.dev/dev-application-294611/maven-qe"
//            credentials {
//                username System.getenv("sonatypeUsername")
//                password System.getenv("sonatypePassword")
//                username sonatypeUsername
//                password sonatypePassword
//            }
        }
    }
}

def customizePom(pom) {
    pom.withXml {
        def root = asNode()

        // eliminate test-scoped dependencies (no need in maven central POMs)
        root.dependencies.removeAll { dep ->
            dep.scope == "test"
        }

        // add all items necessary for maven central publication
        root.children().last() + {
            resolveStrategy = Closure.DELEGATE_FIRST

            description 'Ekam atoms for all common driver actions'
            name 'Atoms'
            url 'https://github.com/dunzoit/ekam-atoms'
            licenses {
                license {
                    name 'MIT License'
                    url 'https://github.com/dunzoit/ekam-atoms/-/blob/master/LICENSE'
                    distribution 'repo'
                }
            }
            scm {
                url 'https://github.com/dunzoit/ekam-atoms'
                connection 'https://github.com/dunzoit/ekam-atoms.git'
                developerConnection 'git@github.com:dunzoit/ekam-atoms.git'
            }
            developers {
                developer {
                    name 'Central QA'
                }
            }
        }
    }
}

model {
    tasks.generatePomFileForMavenJavaPublication {
        destination = file("$buildDir/generated-pom.xml")
    }
}

task runTests(type: Test) {
    useTestNG()
}