build.gradle

plugins {
    id 'jacoco'
    id 'com.github.kt3k.coveralls' version '2.8.2'
}

apply plugin: 'eclipse'
apply plugin: 'java'
apply plugin: 'maven-publish'

wrapper.gradleVersion = '4.6'

version = '1.0.10'
group = 'com.github.edugonza'

println name+" v"+version

repositories {
	mavenLocal()
	mavenCentral()
	maven { url "https://jitpack.io" }
}

sourceSets {
	main {
		java {
			srcDirs = ['src/']
		}
		resources {
			srcDirs = ['resources/']
		}
	}
	test {
		java {
			srcDirs = ['test/']
		}
	}
}

jar {
	dependsOn javadoc
	from sourceSets.main.allSource
	from javadoc.destinationDir
}

task javadocJar(type: Jar, dependsOn: javadoc) {
	classifier "javadoc"
	from javadoc.destinationDir
}

artifacts {
	archives javadocJar
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
	    artifact javadocJar
        }
    }
    repositories {
        mavenLocal()
    }
}

jacocoTestReport {
    reports {
        xml.enabled = true // coveralls plugin depends on xml format report
        html.enabled = true
    }
}

dependencies {
	compile  'log4j:log4j:1.2.16'
	compile  'org.jgrapht:jgrapht-core:1.0.0'
	compile  'org.xerial:sqlite-jdbc:3.23.1'
	compile  'org.mapdb:mapdb:3.0.5'
	testCompile 'junit:junit:4.12'
}