-
-
Notifications
You must be signed in to change notification settings - Fork 299
/
epm.elv
395 lines (357 loc) · 10.6 KB
/
epm.elv
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
use os
use path
use re
use str
use platform
pragma unknown-command = disallow
var dirname~ = $e:dirname~
var mkdir~ = $e:mkdir~
var git~ = $e:git~
var rsync~ = $e:rsync~
# Verbosity configuration
var debug-mode = $false
# Configuration for common domains
var -default-domain-config = [
&"github.com"= [
&method= git
&protocol= https
&levels= 2
]
&"bitbucket.org"= [
&method= git
&protocol= https
&levels= 2
]
&"gitlab.com"= [
&method= git
&protocol= https
&levels= 2
]
]
# The path of the `epm`-managed directory.
var managed-dir = (
if $platform:is-windows {
put $E:LocalAppData/elvish/lib
} elif (not-eq $E:XDG_DATA_HOME '') {
put $E:XDG_DATA_HOME/elvish/lib
} else {
put ~/.local/share/elvish/lib
}
)
# General utility functions
fn -debug {|text|
if $debug-mode {
print (styled '=> ' blue)
echo $text
}
}
fn -info {|text|
print (styled '=> ' green)
echo $text
}
fn -warn {|text|
print (styled '=> ' yellow)
echo $text
}
fn -error {|text|
print (styled '=> ' red)
echo $text
}
fn dest {|pkg|
put $managed-dir/$pkg
}
# Returns a boolean value indicating whether the given package is installed.
fn is-installed {|pkg|
path:is-dir (dest $pkg)
}
fn -package-domain {|pkg|
str:split &max=2 / $pkg | take 1
}
fn -package-without-domain {|pkg|
str:split &max=2 / $pkg | drop 1 | str:join ''
}
# Merge two maps
fn -merge {|a b|
keys $b | each {|k| set a[$k] = $b[$k] }
put $a
}
# Expand tilde at the beginning of a string to the home dir
fn -tilde-expand {|p|
re:replace "^~" $E:HOME $p
}
# Known method handlers. Each entry is indexed by method name (the
# value of the "method" key in the domain configs), and must contain
# two keys: install and upgrade, each one must be a closure that
# receives two arguments: package name and the domain config entry
#
# - Method 'git' requires the key 'protocol' in the domain config,
# which has to be 'http' or 'https'
# - Method 'rsync' requires the key 'location' in the domain config,
# which has to contain the directory where the domain files are
# stored. It can be any source location understood by the rsync
# command.
var -method-handler
set -method-handler = [
&git= [
&src= {|pkg dom-cfg|
put $dom-cfg[protocol]"://"$pkg
}
&install= {|pkg dom-cfg|
var dest = (dest $pkg)
-info "Installing "$pkg
mkdir -p $dest
git clone ($-method-handler[git][src] $pkg $dom-cfg) $dest
}
&upgrade= {|pkg dom-cfg|
var dest = (dest $pkg)
-info "Updating "$pkg
try {
git -C $dest pull
} catch _ {
-error "Something failed, please check error above and retry."
}
}
]
&rsync= [
&src= {|pkg dom-cfg|
put (-tilde-expand $dom-cfg[location])/(-package-without-domain $pkg)/
}
&install= {|pkg dom-cfg|
var dest = (dest $pkg)
var pkgd = (-package-without-domain $pkg)
-info "Installing "$pkg
rsync -av ($-method-handler[rsync][src] $pkg $dom-cfg) $dest
}
&upgrade= {|pkg dom-cfg|
var dest = (dest $pkg)
var pkgd = (-package-without-domain $pkg)
if (not (is-installed $pkg)) {
-error "Package "$pkg" is not installed."
return
}
-info "Updating "$pkg
rsync -av ($-method-handler[rsync][src] $pkg $dom-cfg) $dest
}
]
]
# Return the filename of the domain config file for the given domain
# (regardless of whether it exists)
fn -domain-config-file {|dom|
put $managed-dir/$dom/epm-domain.cfg
}
# Return the filename of the metadata file for the given package
# (regardless of whether it exists)
fn -package-metadata-file {|pkg|
put (dest $pkg)/metadata.json
}
fn -write-domain-config {|dom|
var cfgfile = (-domain-config-file $dom)
mkdir -p (dirname $cfgfile)
if (has-key $-default-domain-config $dom) {
put $-default-domain-config[$dom] | to-json > $cfgfile
} else {
-error "No default config exists for domain "$dom"."
}
}
# Returns the domain config for a given domain parsed from JSON.
# If the file does not exist but we have a built-in
# definition, then we return the default. Otherwise we return $false,
# so the result can always be checked with 'if'.
fn -domain-config {|dom|
var cfgfile = (-domain-config-file $dom)
var cfg = $false
if (path:is-regular $cfgfile) {
# If the config file exists, read it...
set cfg = (from-json < $cfgfile)
-debug "Read domain config for "$dom": "(to-string $cfg)
} else {
# ...otherwise check if we have a default config for the domain, and save it
if (has-key $-default-domain-config $dom) {
set cfg = $-default-domain-config[$dom]
-debug "No existing config for "$dom", using the default: "(to-string $cfg)
} else {
-debug "No existing config for "$dom" and no default available."
}
}
put $cfg
}
# Return the method by which a package is installed
fn -package-method {|pkg|
var dom = (-package-domain $pkg)
var cfg = (-domain-config $dom)
if $cfg {
put $cfg[method]
} else {
put $false
}
}
# Invoke package operations defined in $-method-handler above
fn -package-op {|pkg what|
var dom = (-package-domain $pkg)
var cfg = (-domain-config $dom)
if $cfg {
var method = $cfg[method]
if (has-key $-method-handler $method) {
if (has-key $-method-handler[$method] $what) {
$-method-handler[$method][$what] $pkg $cfg
} else {
fail "Unknown operation '"$what"' for package "$pkg
}
} else {
fail "Unknown method '"$method"', specified in config file "(-domain-config-file $dom)
}
} else {
-error "No config for domain '"$dom"'."
}
}
# Uninstall a single package by removing its directory
fn -uninstall-package {|pkg|
if (not (is-installed $pkg)) {
-error "Package "$pkg" is not installed."
return
}
var dest = (dest $pkg)
-info "Removing package "$pkg
os:remove-all $dest
}
######################################################################
# Main user-facing functions
# Returns a hash containing the metadata for the given package. Metadata for a
# package includes the following base attributes:
#
# - `name`: name of the package
# - `installed`: a boolean indicating whether the package is currently installed
# - `method`: method by which it was installed (`git` or `rsync`)
# - `src`: source URL of the package
# - `dst`: where the package is (or would be) installed. Note that this
# attribute is returned even if `installed` is `$false`.
#
# Additionally, packages can define arbitrary metadata attributes in a file called
# `metadata.json` in their top directory. The following attributes are
# recommended:
#
# - `description`: a human-readable description of the package
# - `maintainers`: an array containing the package maintainers, in
# `Name <email>` format.
# - `homepage`: URL of the homepage for the package, if it has one.
# - `dependencies`: an array listing dependencies of the current package. Any
# packages listed will be installed automatically by `epm:install` if they are
# not yet installed.
fn metadata {|pkg|
# Base metadata attributes
var res = [
&name= $pkg
&method= (-package-method $pkg)
&src= (-package-op $pkg src)
&dst= (dest $pkg)
&installed= (is-installed $pkg)
]
# Merge with package-specified attributes, if any
var file = (-package-metadata-file $pkg)
if (and (is-installed $pkg) (path:is-regular $file)) {
set res = (-merge (from-json < $file) $res)
}
put $res
}
# Pretty print the available metadata of the given package.
fn query {|pkg|
var data = (metadata $pkg)
echo (styled "Package "$data[name] cyan)
if $data[installed] {
echo (styled "Installed at "$data[dst] green)
} else {
echo (styled "Not installed" red)
}
echo (styled "Source:" blue) $data[method] $data[src]
var special-keys = [name method installed src dst]
keys $data | each {|key|
if (has-value $special-keys $key) {
continue
}
var val = $data[$key]
if (eq (kind-of $val) list) {
set val = (str:join ", " $val)
}
echo (styled (str:title $key)":" blue) $val
}
}
# Return an array with all installed packages. `epm:list` can be used as an alias
# for `epm:installed`.
fn installed {
put $managed-dir/*[nomatch-ok] | each {|dir|
var dom = (str:replace $managed-dir/ '' $dir)
var cfg = (-domain-config $dom)
# Only list domains for which we know the config, so that the user
# can have his own non-package directories under ~/.elvish/lib
# without conflicts.
if $cfg {
var lvl = $cfg[levels]
var pat = '^\Q'$managed-dir'/\E('(repeat (+ $lvl 1) '[^/]+' | str:join '/')')/$'
put (each {|d| re:find $pat $d } [ $managed-dir/$dom/**[nomatch-ok]/ ] )[groups][1][text]
}
}
}
# epm:list is an alias for epm:installed
fn list { installed }
# Install the named packages. By default, if a package is already installed, a
# message will be shown. This can be disabled by passing
# `&silent-if-installed=$true`, so that already-installed packages are silently
# ignored.
fn install {|&silent-if-installed=$false @pkgs|
# Install and upgrade are method-specific, so we call the
# corresponding functions using -package-op
if (eq $pkgs []) {
-error "You must specify at least one package."
return
}
for pkg $pkgs {
if (is-installed $pkg) {
if (not $silent-if-installed) {
-info "Package "$pkg" is already installed."
}
} else {
-package-op $pkg install
# Check if there are any dependencies to install
var metadata = (metadata $pkg)
if (has-key $metadata dependencies) {
var deps = $metadata[dependencies]
-info "Installing dependencies: "(str:join " " $deps)
# If the installation of dependencies fails, uninstall the
# target package (leave any already-installed dependencies in
# place)
try {
install $@deps
} catch e {
-error "Dependency installation failed. Uninstalling "$pkg", please check the errors above and try again."
-uninstall-package $pkg
}
}
}
}
}
# Upgrade named packages. If no package name is given, upgrade all installed
# packages.
fn upgrade {|@pkgs|
if (eq $pkgs []) {
set pkgs = [(installed)]
-info 'Upgrading all installed packages'
}
for pkg $pkgs {
if (not (is-installed $pkg)) {
-error "Package "$pkg" is not installed."
} else {
-package-op $pkg upgrade
}
}
}
# Uninstall named packages.
fn uninstall {|@pkgs|
# Uninstall is the same for everyone, just remove the directory
if (eq $pkgs []) {
-error 'You must specify at least one package.'
return
}
for pkg $pkgs {
-uninstall-package $pkg
}
}