PKGBUILD

# $Id$
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: BlackEagle < ike DOT devolder AT gmail DOT com >
# Contributor: Preecha Patumchareonpol <yumyai at gmail.com> 

# See: https://www.archlinux.org/packages/community/x86_64/podofo/
# Just added a patch to make it compile with C++11

pkgname=podofo-cpp11
pkgver=0.9.5
pkgrel=2
pkgdesc="A C++ library to work with the PDF file format"
arch=('i686' 'x86_64')
url="http://podofo.sourceforge.net"
license=('GPL')
depends=('lua' 'openssl' 'fontconfig' 'libtiff' 'libidn' 'libjpeg-turbo')
makedepends=('cmake')
conflicts=('podofo')
provides=("podofo=$pkgver")
source=("http://downloads.sourceforge.net/podofo/podofo-${pkgver}.tar.gz" "c++11.patch")
md5sums=('4751a6cf41250bea550a73ff960b7228' 'c3fb541b2d28bed383e64bd170ecc90d')

build() {
  cd "podofo-${pkgver}"
  patch -i "$srcdir/c++11.patch"

  mkdir build
  cd build
  cmake -DCMAKE_INSTALL_PREFIX=/usr .. \
        -DFREETYPE_INCLUDE_DIR=/usr/include/freetype2 \
        -DPODOFO_BUILD_SHARED=1 \
        -DPODOFO_HAVE_JPEG_LIB=1 \
        -DPODOFO_HAVE_PNG_LIB=1 \
        -DPODOFO_HAVE_TIFF_LIB=1
  make
}

package() {
  cd "podofo-${pkgver}/build"
  make DESTDIR="$pkgdir" install
}