-
Notifications
You must be signed in to change notification settings - Fork 14
/
MomentFittedQuadratures.jl
357 lines (304 loc) · 11.9 KB
/
MomentFittedQuadratures.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
module MomentFittedQuadratures
using Gridap
using Gridap.Arrays
using Gridap.CellData
using Gridap.Fields
using Gridap.Geometry
using Gridap.Helpers
using Gridap.Polynomials
using Gridap.ReferenceFEs
import Gridap.ReferenceFEs: Quadrature
using GridapEmbedded.Interfaces
using GridapEmbedded.CSG
using FillArrays
using Gridap.Geometry: FaceToCellGlue
using Gridap.Geometry: push_normal
using GridapEmbedded.Interfaces: SubFacetTriangulation
using GridapEmbedded.Interfaces: SubFacetBoundaryTriangulation
using GridapEmbedded.Interfaces: CutInOrOut
using GridapEmbedded.Interfaces: AbstractEmbeddedDiscretization
using GridapEmbedded.Interfaces: get_geometry
using GridapEmbedded.LevelSetCutters: _check_and_get_polytope
export momentfitted
struct MomentFitted <: QuadratureName end
const momentfitted = MomentFitted()
function Quadrature(trian::Grid,::MomentFitted,args...;kwargs...)
@abstractmethod
end
function Quadrature(trian::Grid,
::MomentFitted,
cut::AbstractEmbeddedDiscretization,
degree::Int;
in_or_out=IN)
geo = get_geometry(cut)
Quadrature(trian,momentfitted,cut,geo,degree;in_or_out=in_or_out)
end
function Quadrature(active_mesh::Grid,
::MomentFitted,
cut::AbstractEmbeddedDiscretization,
geo::CSG.Geometry,
degree::Int;
in_or_out=IN)
acell_to_point_vals, acell_to_weight_vals = #
compute_lag_moments_from_leg(cut,geo,in_or_out,degree)
acell_to_weight_vals = collect(get_array(acell_to_weight_vals))
D = num_dims(active_mesh)
bgcell_to_inoutcut = compute_bgcell_to_inoutcut(cut,geo)
acell_to_bgcell = get_glue(active_mesh,Val{D}()).tface_to_mface
acell_to_inoutcut = lazy_map(Reindex(bgcell_to_inoutcut),acell_to_bgcell)
acell_to_point_ptrs = lazy_map(i->(i == CUT ? 1 : 2),acell_to_inoutcut)
quad = map(r->Quadrature(get_polytope(r),degree),get_reffes(active_mesh))
@assert length(quad) == 1
acell_to_point_vals = [acell_to_point_vals,get_coordinates(quad[1])]
push!(acell_to_weight_vals,get_weights(quad[1]))
acell_to_is_cut = findall(lazy_map(i->(i == CUT),acell_to_inoutcut))
num_quads = length(acell_to_weight_vals)
acell_to_weight_ptrs = map(acell_to_inoutcut) do i
i == in_or_out ? num_quads : 0
end
acell_to_weight_ptrs[acell_to_is_cut] .= 1:length(acell_to_is_cut)
acell_to_point = CompressedArray(acell_to_point_vals,acell_to_point_ptrs)
acell_to_weight = CompressedArray(acell_to_weight_vals,acell_to_weight_ptrs)
acell_to_quad = map(1:length(acell_to_point)) do i
GenericQuadrature(acell_to_point[i],acell_to_weight[i],"Moment-fitted quadrature of degree $degree")
end
acell_to_quad = CompressedArray(acell_to_quad,1:length(acell_to_quad))
end
struct CutCellMoments
data::Vector{Vector{Float64}}
bgcell_to_cut_cell::Vector{Int32}
end
function CutCellMoments(trian::Triangulation,
facet_moments::DomainContribution)
fi = [ testitem(array) for (trian,array) in facet_moments.dict ]
li = map(length,fi)
@assert all(li .== first(li))
bgmodel = get_background_model(trian)
Dm = num_dims(bgmodel)
cell_to_parent_cell = get_glue(trian,Val{Dm}()).tface_to_mface
data = [ zero(first(fi)) for i in 1:length(cell_to_parent_cell) ]
bgcell_to_cut_cell = zeros(Int32,num_cells(bgmodel))
bgcell_to_cut_cell[cell_to_parent_cell] .= 1:length(cell_to_parent_cell)
CutCellMoments(data,bgcell_to_cut_cell)
end
function Pᵢ(i::Int)
P = []
a = (-1)^i
for k in 0:i
push!(P,a*binomial(i,k)*binomial(i+k,k)*(-1)^k)
end
P
end
function legendreToMonomial1D(n::Int)
B = zeros(n+1,n+1)
for i in 1:n+1
B[i,1:i] = sqrt(2*i-1)*Pᵢ(i-1)
end
B
end
function legendreToMonomial(n::Int,d::Int)
nt = ntuple(i->1:(n+1),d)
cis = CartesianIndices(nt)
B = zeros(length(cis),length(cis))
B1D = legendreToMonomial1D(n)
for (i,ci) in enumerate(cis)
ti = [ B1D[j,:] for j in Tuple(ci) ]
B[i,:] = kron(ti[end:-1:1]...)
end
B
end
function compute_lag_moments_from_leg(cut::AbstractEmbeddedDiscretization,
geo::CSG.Geometry,
in_or_out,
degree::Int)
cut_trian = Triangulation(cut,CUT,geo)
T = eltype(eltype(get_node_coordinates(cut_trian)))
D = num_dims(cut_trian)
b = MonomialBasis{D}(T,degree)
mon_contribs = compute_monomial_domain_contribution(cut,geo,in_or_out,b,degree)
mon_moments = compute_monomial_cut_cell_moments(cut_trian,mon_contribs,b)
mon_to_leg = Fill(legendreToMonomial(degree,D),num_cells(cut_trian))
leg_moments = lazy_map(*,mon_to_leg,mon_moments)
p = JacobiPolynomialBasis{D}(T,degree)
lag_nodes, lag_to_leg = get_nodes_and_change_of_basis(cut_trian,cut,p,degree)
lag_moments = lazy_map(*,lag_to_leg,leg_moments)
lag_nodes, lag_moments
end
function compute_monomial_domain_contribution(cut::AbstractEmbeddedDiscretization,
in_or_out,
b::MonomialBasis,
deg::Int)
geo = get_geometry(cut)
compute_monomial_domain_contribution(cut,geo,in_or_out,b,deg)
end
function compute_monomial_domain_contribution(cut::AbstractEmbeddedDiscretization,
geo::CSG.Geometry,
in_or_out::Integer,
b::MonomialBasis,
deg::Int)
cut_io = CutInOrOut(in_or_out)
dir_Γᵉ = (-1)^(in_or_out==OUT)
cutf = cut_facets(cut,geo)
# Embedded facets
Γᵉ = EmbeddedBoundary(cut,geo)
# Interior fitted cut facets
Γᶠ = SkeletonTriangulation(cutf,cut_io,geo)
# Boundary fitted cut facets
Γᵒ = BoundaryTriangulation(cutf,cut_io,geo)
# Interior non-cut facets
Γᵇ = SkeletonTriangulation(cutf,in_or_out,geo)
# Boundary non-cut facets
Γᵖ = BoundaryTriangulation(cutf,in_or_out,geo)
D = num_dims(get_background_model(cut))
int_c_b(Γᵉ,b,deg*D)*dir_Γᵉ + int_c_b(Γᶠ,b,deg*D) + int_c_b(Γᵒ,b,deg*D) +
int_c_b(Γᵇ,b,deg) + int_c_b(Γᵖ,b,deg)
end
function int_c_b(t::SkeletonTriangulation,b::MonomialBasis,deg::Int)
int_c_b(t.plus,b,deg) + int_c_b(t.minus,b,deg)
end
function int_c_b(t::AppendedTriangulation,b::MonomialBasis,deg::Int)
int_c_b(t.a,b,deg) + int_c_b(t.b,b,deg)
end
function int_c_b(t::Triangulation,b::MonomialBasis,deg::Int)
cont = DomainContribution()
if num_cells(t) > 0
Dm = num_dims(get_background_model(t))
dt = CellQuadrature(t,deg)
x_gp_ref_1d = dt.cell_point
facet_map = get_glue(t,Val{Dm}()).tface_to_mface_map
x_gp_ref = lazy_map(evaluate,facet_map,x_gp_ref_1d)
cell_map = get_cell_map(get_background_model(t))
facet_cell = get_glue(t,Val{Dm}()).tface_to_mface
facet_cell_map = lazy_map(Reindex(cell_map),facet_cell)
facet_cell_Jt = lazy_map(∇,facet_cell_map)
facet_cell_Jtx = lazy_map(evaluate,facet_cell_Jt,x_gp_ref)
facet_n = get_facet_normal(t)
facet_nx = lazy_map(evaluate,facet_n,x_gp_ref_1d)
facet_nx_r = lazy_map(Broadcasting(push_normal),facet_cell_Jtx,facet_nx)
c = lazy_map(Broadcasting(⋅),facet_nx_r,x_gp_ref)
v = Fill(b,num_cells(t))
v_gp_ref = lazy_map(evaluate,v,x_gp_ref)
c_v = lazy_map(Broadcasting(*),v_gp_ref,c)
facet_Jt = lazy_map(∇,facet_map)
facet_Jtx = lazy_map(evaluate,facet_Jt,x_gp_ref_1d)
I_c_v_in_t = lazy_map(IntegrationMap(),c_v,dt.cell_weight,facet_Jtx)
add_contribution!(cont,t,I_c_v_in_t)
end
cont
end
function compute_monomial_cut_cell_moments(model::Triangulation,
facet_moments::DomainContribution,
b::MonomialBasis{D,T}) where {D,T}
cut_cell_to_moments = CutCellMoments(model,facet_moments)
for (trian,array) in facet_moments.dict
add_facet_moments!(cut_cell_to_moments,trian,array)
end
o = get_terms_degrees(b)
q = 1 ./ ( D .+ o )
[ q .* d for d in cut_cell_to_moments.data ]
end
function add_facet_moments!(ccm::CutCellMoments,trian,array::AbstractArray)
@abstractmethod
end
function add_facet_moments!(ccm::CutCellMoments,
trian::SubFacetTriangulation,
array::AbstractArray)
add_facet_moments!(ccm,trian.subfacets,array)
end
function add_facet_moments!(ccm::CutCellMoments,
sfd::SubFacetData,
array::AbstractArray)
facet_to_cut_cell = lazy_map(Reindex(ccm.bgcell_to_cut_cell),sfd.facet_to_bgcell)
c = array_cache(array)
for i = 1:length(facet_to_cut_cell)
ccm.data[facet_to_cut_cell[i]] += getindex!(c,array,i)
end
end
function add_facet_moments!(ccm::CutCellMoments,
trian::SubFacetBoundaryTriangulation,
array::AbstractArray)
if length(trian.subfacet_to_facet) > 0
subfacet_to_bgcell = lazy_map(Reindex(trian.facets.glue.face_to_cell),trian.subfacet_to_facet)
subfacet_to_cut_cell = lazy_map(Reindex(ccm.bgcell_to_cut_cell),subfacet_to_bgcell)
l = length(subfacet_to_cut_cell)
c = array_cache(array)
for i = 1:l
ccm.data[subfacet_to_cut_cell[i]] += getindex!(c,array,i)
end
else
add_facet_moments!(ccm,trian.facets,array)
end
end
function add_facet_moments!(ccm::CutCellMoments,
trian::BoundaryTriangulation,
array::AbstractArray)
add_facet_moments!(ccm,trian.glue,array)
end
function add_facet_moments!(ccm::CutCellMoments,
glue::FaceToCellGlue,
array::AbstractArray)
facet_to_cut_cell = lazy_map(Reindex(ccm.bgcell_to_cut_cell),glue.face_to_cell)
cell_to_is_cut = findall(lazy_map(i->(i>0),facet_to_cut_cell))
facet_to_cut_cell = lazy_map(Reindex(facet_to_cut_cell),cell_to_is_cut)
l = length(facet_to_cut_cell)
c = array_cache(array)
for i = 1:l
ccm.data[facet_to_cut_cell[i]] += getindex!(c,array,cell_to_is_cut[i])
end
end
function add_facet_moments!(ccm::CutCellMoments,
trian::Triangulation,
array::AbstractArray)
Dp = num_point_dims(trian)
Dc = num_cell_dims(trian)
@assert Dc == Dp-1
@assert Dp == num_dims(get_background_model(trian))
facet_to_bgcell = get_glue(trian,Val(Dp)).tface_to_mface
facet_to_cut_cell = lazy_map(Reindex(ccm.bgcell_to_cut_cell),facet_to_bgcell)
l = length(facet_to_cut_cell)
c = array_cache(array)
for i = 1:l
ccm.data[facet_to_cut_cell[i]] += getindex!(c,array,i)
end
end
function get_nodes_and_change_of_basis(model::Triangulation,
cut::AbstractEmbeddedDiscretization,
b,
degree::Int)
D = num_dims(model)
T = eltype(eltype(get_node_coordinates(model)))
p = check_and_get_polytope(cut)
orders = tfill(degree,Val{D}())
nodes, _ = compute_nodes(p,orders)
dofs = LagrangianDofBasis(T,nodes)
change = evaluate(dofs,b)
change = transpose(inv(change))
change = Fill(change,num_cells(model))
nodes, change
end
function map_to_ref_space!(moments::AbstractArray,
nodes::Vector{<:Point},
model::Triangulation)
cell_map = get_cell_map(model)
cell_Jt = lazy_map(∇,cell_map)
cell_detJt = lazy_map(Operation(det),cell_Jt)
cell_nodes = Fill(nodes,num_cells(model))
detJt = lazy_map(evaluate,cell_detJt,cell_nodes)
moments = lazy_map(Broadcasting(/),moments,detJt)
end
@inline function check_and_get_polytope(cut::AbstractEmbeddedDiscretization)
bgmodel = get_background_model(cut)
grid = get_grid(bgmodel)
_check_and_get_polytope(grid)
end
@inline function get_terms_degrees(b::MonomialBasis)
[ _get_terms_degrees(c) for c in b.terms ]
end
function _get_terms_degrees(c::CartesianIndex)
d = 0
for i in 1:length(c)
d += (c[i]-1)
end
d
end
end #module