[Bug]: Assume role identity is different than what aws_caller_identity reports

[bryantbiggs]

Terraform Core Version

1.3.6

AWS Provider Version

4.46.0

Affected Resource(s)

• aws_caller_identity

Expected Behavior

When providing an IAM role to assume in the provider via assume_role, I would expect that the data source aws_caller_identity would return the ARN of the role to be assumed.

Actual Behavior

The role ARN returned is an STS session ARN for the SDK

Terraform Configuration Files

Note: the role ARN to assume will need to be updated (i.e. - "arn:aws:iam::111111111111:role/terraform" should be updated)

provider "aws" {
  region = "us-east-1"

  assume_role {
    role_arn = "arn:aws:iam::111111111111:role/terraform"
  }
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "this" {
  statement {
    sid       = "Default"
    actions   = ["kms:*"]
    resources = ["*"]

    principals {
      type        = "AWS"
      identifiers = [data.aws_caller_identity.current.arn]
    }
  }
}

output "policy" {
  value = data.aws_iam_policy_document.this.json
}

Steps to Reproduce

Using the code provided above:

1. terraform init
2. terraform plan
3. You should see the ARN in the output is not the ARN of the assumed role passed

Changes to Outputs:
  + policy = jsonencode(
        {
          + Statement = [
              + {
                  + Action    = "kms:*"
                  + Effect    = "Allow"
                  + Principal = {
                      + AWS = "arn:aws:sts::111111111111:assumed-role/terraform/aws-go-sdk-1671120217066190188"
                      # This should be:
                      # AWS =  "arn:aws:iam::111111111111:role/terraform"
                    }
                  + Resource  = "*"
                  + Sid       = "Default"
                },
            ]
          + Version   = "2012-10-17"
        }
    )

Debug Output

No response

Panic Output

No response

Important Factoids

No response

References

No response

Would you like to implement a fix?

None

[github-actions]

Community Note

Voting for Prioritization

• Please vote on this issue by adding a 👍 reaction to the original post to help the community and maintainers prioritize this request.
• Please see our prioritization guide for information on how we prioritize.
• Please do not leave "+1" or other comments that do not add relevant new information or questions, they generate extra noise for issue followers and do not help prioritize the request.

Volunteering to Work on This Issue

• If you are interested in working on this issue, please leave a comment.
• If this would be your first contribution, please review the contribution guide.

[bryantbiggs]

TIL - theres a data source for this. As pointed out by @fknittel - this works as intended for both scenarios (w/ or w/o assume_role):

provider "aws" {
  region = "us-east-1"

  assume_role {
    role_arn = "arn:aws:iam::111111111111:role/terraform"
  }
}

data "aws_caller_identity" "current" {}
data "aws_iam_session_context" "current" {
  arn = data.aws_caller_identity.current.arn
}

data "aws_iam_policy_document" "this" {
  statement {
    sid       = "Default"
    actions   = ["kms:*"]
    resources = ["*"]

    principals {
      type        = "AWS"
      identifiers = [data.aws_iam_session_context.current.issuer_arn]
    }
  }
}

output "policy" {
  value = data.aws_iam_policy_document.this.json
}

[github-actions]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.
If you have found a problem that seems similar to this, please open a new issue and complete the issue template so we can capture all the details necessary to investigate further.