Remove google_project_services resource

[rileykarson]

The google_project_services resource is authoritative over the list of GCP
services enabled on a project, so that services not explicitly set are
removed by Terraform.

This is dangerous to use in practice. Services have dependencies that
are automatically enabled alongside them and GCP will add dependencies to
services out of band, enabling them. If a user runs Terraform after this,
Terraform will disable the added service- and implicitly disable any service that relied on it.

The google_project_service resource is a much better match for most users'
intent, managing a single service at a time. Setting several
google_project_service resources is an assertion that "these services are set
on this project", while google_project_services is an assertion that "only these services are set on this project".

Users should migrate to using google_project_service resources, or using the
"terraform-google-modules/project-factory/google//modules/project_services"
module for a similar interface to google_project_services.

Old Config

resource "google_project_services" "project" {
  project            = "your-project-id"
  services           = ["iam.googleapis.com", "cloudresourcemanager.googleapis.com"]
  disable_on_destroy = false
}

New Config (module)

module "project_services" {
  source  = "terraform-google-modules/project-factory/google//modules/project_services"
  version = "3.3.0"

  project_id    = "your-project-id"
  activate_apis =  [
    "iam.googleapis.com",
    "cloudresourcemanager.googleapis.com",
  ]

  disable_services_on_destroy = false
  disable_dependent_services  = false
}

New Config (google_project_service)

resource "google_project_service" "project_iam" {
  project = "your-project-id"
  service = "iam.googleapis.com"
  disable_on_destroy = false
}

resource "google_project_service" "project_cloudresourcemanager" {
  project = "your-project-id"
  service = "cloudresourcemanager.googleapis.com"
  disable_on_destroy = false
}

[rileykarson]

Done in GoogleCloudPlatform/magic-modules#2403

[ghost]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.

If you feel this issue should be reopened, we encourage creating a new issue linking back to this one for added context. If you feel I made an error 🤖 🙉 , please reach out to my human friends 👉 hashibot-feedback@hashicorp.com. Thanks!