forked from ivmai/bdwgc
-
Notifications
You must be signed in to change notification settings - Fork 0
/
configure.ac
1309 lines (1197 loc) · 44.7 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# Copyright (c) 1999-2001 by Red Hat, Inc. All rights reserved.
# Copyright (c) 2005-2009 Hewlett-Packard Development Company, L.P.
# Copyright (c) 2009-2022 Ivan Maidanski
#
# THIS MATERIAL IS PROVIDED AS IS, WITH ABSOLUTELY NO WARRANTY EXPRESSED
# OR IMPLIED. ANY USE IS AT YOUR OWN RISK.
#
# Permission is hereby granted to use or copy this program
# for any purpose, provided the above notices are retained on all copies.
# Permission to modify the code and to distribute modified code is granted,
# provided the above notices are retained, and a notice that the code was
# modified is included with the above copyright notice.
dnl Process this file with autoconf to produce configure.
dnl Initialization.
AC_INIT(gc,8.3.0,https://github.com/ivmai/bdwgc/issues)
dnl Version must conform to: [0-9]+[.][0-9]+[.][0-9]+
AC_CONFIG_SRCDIR(gcj_mlc.c)
AC_CONFIG_MACRO_DIR([m4])
AC_CANONICAL_TARGET
AC_PREREQ(2.61)
GC_SET_VERSION
AM_INIT_AUTOMAKE([foreign nostdinc subdir-objects])
AC_CONFIG_HEADERS([include/config.h])
AM_MAINTAINER_MODE
AC_SUBST(PACKAGE)
AC_SUBST(GC_VERSION)
AM_PROG_CC_C_O
AC_PROG_CXX
AM_PROG_AS
AC_PROG_INSTALL
LT_INIT([disable-static])
# Only the shared libraries are produced by default, use "--enable-static"
# option to override it.
dnl Note: If Autoconf reports that LIBTOOL (or AC_ENABLE_SHARED) is
dnl undefined, Libtool installation should be checked.
# Special CFLAGS to use when building
gc_cflags=""
# Set to "yes" on platforms where mmap should be used instead of sbrk.
# This will define USE_MMAP.
gc_use_mmap=""
# We should set -fexceptions if we are using gcc and might be used
# inside something like gcj. This is the zeroth approximation:
if test :"$GCC": = :yes: ; then
gc_cflags="${gc_cflags} -fexceptions"
else
case "$host" in
hppa*-*-hpux*)
if test :$GCC: != :"yes": ; then
gc_cflags="${gc_cflags} +ESdbgasm"
fi
# :TODO: actually we should check using Autoconf if
# the compiler supports this option.
;;
esac
fi
# target_optspace --enable-target-optspace ("yes", "no", "")
case "${target_optspace}:${host}" in
yes:*)
gc_cflags="${gc_cflags} -Os"
;;
:m32r-* | :d10v-* | :d30v-*)
gc_cflags="${gc_cflags} -Os"
;;
no:* | :*)
# Nothing.
;;
esac
# Set any host dependent compiler flags.
case "${host}" in
mips-tx39-* | mipstx39-unknown-*)
gc_cflags="${gc_cflags} -G 0"
;;
esac
AC_MSG_CHECKING([for emscripten])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
# ifndef __EMSCRIPTEN__
# error This is not Emscripten
# endif
]])], [emscripten=yes], [emscripten=no])
AM_CONDITIONAL(EMSCRIPTEN, test x$emscripten = xyes)
AC_MSG_RESULT([$emscripten])
AC_ARG_ENABLE(emscripten-asyncify,
[AS_HELP_STRING([--enable-emscripten-asyncify],
[use Emscripten asyncify feature])])
# Use this option if your program is targeting -sASYNCIFY. The latter is
# required to scan the stack, ASYNCIFY_STACK_SIZE is probably needed for
# gctest only.
AS_IF([test "${emscripten}" = yes -a "${enable_emscripten_asyncify}" = yes],
[gc_cflags="${gc_cflags} -DEMSCRIPTEN_ASYNCIFY"
gc_cflags="${gc_cflags} -sASYNCIFY -sASYNCIFY_STACK_SIZE=128000"])
GC_CFLAGS=${gc_cflags}
AC_SUBST(GC_CFLAGS)
dnl Extra user-defined flags to pass both to C and C++ compilers.
AC_SUBST([CFLAGS_EXTRA])
AC_ARG_ENABLE(threads,
[AS_HELP_STRING([--enable-threads=TYPE], [choose threading package])],
THREADS=$enableval,
[AC_MSG_CHECKING([for thread model used by GCC])
THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
if test -z "$THREADS" -o "x$emscripten" = "xyes"; then
THREADS=no
fi
if test "$THREADS" = "posix"; then
case "$host" in
*-*-mingw*)
# Adjust thread model if cross-compiling for MinGW.
THREADS=win32
;;
esac
fi
AC_MSG_RESULT([$THREADS])])
AC_ARG_ENABLE(parallel-mark,
[AS_HELP_STRING([--disable-parallel-mark],
[do not parallelize marking and free list construction])],
[case "$THREADS" in
no | none | single)
if test "${enable_parallel_mark}" != no; then
AC_MSG_ERROR([Parallel mark requires --enable-threads=x spec])
fi
;;
esac])
AC_ARG_ENABLE(thread-local-alloc,
[AS_HELP_STRING([--disable-thread-local-alloc],
[turn off thread-local allocation optimization])],
[case "$THREADS" in
no | none | single)
if test "${enable_thread_local_alloc}" = yes; then
AC_MSG_ERROR(
[Thread-local allocation requires --enable-threads=x spec])
fi
;;
esac])
AC_ARG_ENABLE(threads-discovery,
[AS_HELP_STRING([--disable-threads-discovery],
[disable threads discovery in GC])])
if test "${enable_threads_discovery}" = no; then
AC_DEFINE([GC_NO_THREADS_DISCOVERY], 1,
[Disable threads discovery in GC.])
fi
AC_ARG_ENABLE(rwlock,
[AS_HELP_STRING([--enable-rwlock],
[enable reader mode of the allocator lock])])
if test "${enable_rwlock}" = yes; then
AC_DEFINE([USE_RWLOCK], 1,
[Use rwlock for the allocator lock instead of mutex.])
fi
AC_ARG_ENABLE(cplusplus,
[AS_HELP_STRING([--enable-cplusplus], [install C++ support])])
dnl Features which may be selected in the following thread-detection switch.
AH_TEMPLATE([PARALLEL_MARK], [Define to enable parallel marking.])
AH_TEMPLATE([THREAD_LOCAL_ALLOC],
[Define to enable thread-local allocation optimization.])
AH_TEMPLATE([USE_COMPILER_TLS],
[Define to use of compiler-support for thread-local variables.])
dnl Thread selection macros.
AH_TEMPLATE([GC_THREADS], [Define to support platform-specific threads.])
AH_TEMPLATE([GC_WIN32_PTHREADS],
[Define to support pthreads-win32 or winpthreads.])
dnl System header feature requests.
AH_TEMPLATE([_POSIX_C_SOURCE], [The POSIX feature macro.])
AH_TEMPLATE([_PTHREADS], [Indicates the use of pthreads (NetBSD).])
dnl Win32-specific API usage controls.
AH_TEMPLATE([UNICODE],
[Use Unicode (W) variant of Win32 API instead of ASCII (A) one.])
dnl GC API symbols export control.
AH_TEMPLATE([GC_DLL],
[Define to build dynamic libraries with only API symbols exposed.])
dnl Check for a flavor of supported inline keyword.
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA"
AC_C_INLINE
CFLAGS="$old_CFLAGS"
THREADDLLIBS=
need_atomic_ops_asm=false
need_lib_rt=false
compile_asm=false
use_parallel_mark=no
use_thread_local_alloc=no
# Libraries needed to support dynamic loading and/or threads.
case "$THREADS" in
no | none | single)
THREADS=none
;;
posix | pthreads)
THREADS=posix
default_threadlibs=false
# Common defines for most POSIX platforms.
case "$host" in
*-*-aix* | *-*-android* | *-*-cygwin* | *-*-darwin* | *-*-dragonfly* | \
*-*-freebsd* | *-*-haiku* | *-*-hpux11* | *-*-irix* | \
*-*-kfreebsd*-gnu | *-*-gnu* | *-*-*linux* | *-*-msys* | *-*-nacl* | \
*-*-netbsd* | *-*-openbsd* | *-*-osf* | *-*-solaris*)
AC_DEFINE(GC_THREADS)
AC_DEFINE([_REENTRANT], [1],
[Required define if using POSIX threads.])
use_parallel_mark=$enable_parallel_mark
use_thread_local_alloc=$enable_thread_local_alloc
default_threadlibs=true
AC_MSG_WARN("Explicit GC_INIT() calls may be required.")
;;
esac
AC_CHECK_LIB(pthread, pthread_self, THREADDLLIBS="-lpthread",,)
case "$host" in
*-*-hpux11*)
AC_MSG_WARN("Only HP/UX 11 POSIX threads are supported.")
AC_DEFINE(_POSIX_C_SOURCE,199506L)
THREADDLLIBS="-lpthread"
# HPUX needs REENTRANT for the _r calls.
need_lib_rt=true
;;
*-*-openbsd*)
AM_CFLAGS="$AM_CFLAGS -pthread"
THREADDLLIBS=-pthread
;;
*-*-freebsd*)
AM_CFLAGS="$AM_CFLAGS -pthread"
;;
*-*-kfreebsd*-gnu)
AM_CFLAGS="$AM_CFLAGS -pthread"
THREADDLLIBS=-pthread
;;
*-*-gnu*) # E.g. linux but excluding kfreebsd.
# The default THREADDLLIBS.
;;
*-*-netbsd*)
AC_MSG_WARN("Only on NetBSD 2.0 or later.")
AC_DEFINE(_PTHREADS)
THREADDLLIBS="-lpthread"
need_lib_rt=true
;;
*-*-solaris*)
THREADDLLIBS="-lpthread"
need_lib_rt=true
;;
*-*-cygwin* | *-*-msys*)
# Cygwin doesn't have a real libpthread, so Libtool can't link
# against it.
THREADDLLIBS=""
win32_threads=true
;;
*-*-mingw*)
AC_DEFINE(GC_WIN32_PTHREADS)
# Using pthreads-win32 (or other non-Cygwin pthreads) library.
THREADDLLIBS="-lpthread"
use_parallel_mark=$enable_parallel_mark
use_thread_local_alloc=$enable_thread_local_alloc
win32_threads=true
;;
*-*-darwin*)
darwin_threads=true
;;
*-*-osf*)
AM_CFLAGS="$AM_CFLAGS -pthread"
THREADDLLIBS="-lpthread"
need_lib_rt=true
;;
*)
AS_IF([test x$default_threadlibs != xtrue],
[AC_MSG_ERROR(
[Pthreads not supported by the GC on this platform])])
# The default THREADDLLIBS.
;;
esac
case "$host" in
sparc*-*-solaris*)
if test "$GCC" != yes; then
need_atomic_ops_asm=true
fi
;;
esac
;;
mcf | win32)
AC_DEFINE(GC_THREADS)
use_parallel_mark=$enable_parallel_mark
if test "${enable_parallel_mark}" != no \
-o "${enable_shared}" != yes -o "${enable_static}" != no; then
# Imply THREAD_LOCAL_ALLOC unless GC_DLL.
use_thread_local_alloc=$enable_thread_local_alloc
fi
if test "${enable_win32_dllmain}" = yes; then
AC_DEFINE(GC_INSIDE_DLL, 1,
[Enable Win32 DllMain-based approach of threads registering.])
fi
win32_threads=true
AC_DEFINE([EMPTY_GETENV_RESULTS], [1],
[Wine getenv may not return NULL for missing entry.])
;;
dgux386)
AC_DEFINE(GC_THREADS)
# Use pthread GCC switch
THREADDLLIBS=-pthread
use_parallel_mark=$enable_parallel_mark
use_thread_local_alloc=$enable_thread_local_alloc
AC_MSG_WARN("Explicit GC_INIT() calls may be required.")
AM_CFLAGS="-pthread $AM_CFLAGS"
;;
aix)
THREADS=posix
THREADDLLIBS=-lpthread
AC_DEFINE(GC_THREADS)
AC_DEFINE(_REENTRANT)
use_parallel_mark=$enable_parallel_mark
use_thread_local_alloc=$enable_thread_local_alloc
;;
rtems)
THREADS=posix
AC_DEFINE(GC_THREADS)
use_parallel_mark=$enable_parallel_mark
use_thread_local_alloc=$enable_thread_local_alloc
;;
decosf1 | irix | mach | os2 | solaris | dce | vxworks)
AC_MSG_ERROR(thread package $THREADS not yet supported)
;;
*)
AC_MSG_ERROR($THREADS is an unknown thread package)
;;
esac
# Check whether -lrt linker option is needed to use clock_gettime.
if test "x$need_lib_rt" != xtrue; then
AC_MSG_CHECKING(for clock_gettime without additional libraries)
AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <time.h>],
[struct timespec t; clock_gettime(CLOCK_REALTIME, &t)])],
[AC_MSG_RESULT(yes)],
[AC_MSG_RESULT(no)
AC_CHECK_LIB(rt, clock_gettime, [need_lib_rt=true])])
fi
if test "x$need_lib_rt" = xtrue; then
THREADDLLIBS="$THREADDLLIBS -lrt"
fi
AC_SUBST(THREADDLLIBS)
AM_CONDITIONAL(THREADS, test x$THREADS != xnone)
AM_CONDITIONAL(PTHREADS, test x$THREADS = xposix)
AM_CONDITIONAL(DARWIN_THREADS, test x$darwin_threads = xtrue)
AM_CONDITIONAL(WIN32_THREADS, test x$win32_threads = xtrue)
compiler_suncc=no
pthread_start_standalone=no
case "$host" in
*-*-*linux*)
# Turn on the workaround described in pthread_start.c.
AS_IF([test "$THREADS" = posix], [pthread_start_standalone=yes])
;;
powerpc-*-darwin*)
powerpc_darwin=true
;;
*-*-solaris*)
if test "$GCC" != yes; then
# Solaris SunCC
compiler_suncc=yes
CFLAGS="-O $CFLAGS"
fi
;;
*-*-wince*)
if test "$enable_gc_debug" != "no"; then
AC_DEFINE([GC_READ_ENV_FILE], 1,
[Read environment variables from the GC 'env' file.])
fi
;;
esac
AM_CONDITIONAL(PTHREAD_START_STANDALONE,
test x$pthread_start_standalone = xyes)
if test "$GCC" = yes; then
# Output all warnings.
AC_MSG_CHECKING([whether compiler supports -Wextra])
old_CFLAGS="$CFLAGS"
CFLAGS="-Wextra $CFLAGS"
AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
[ac_cv_cc_wextra=yes], [ac_cv_cc_wextra=no])
CFLAGS="$old_CFLAGS"
AC_MSG_RESULT($ac_cv_cc_wextra)
AS_IF([test "$ac_cv_cc_wextra" = yes], [WEXTRA="-Wextra"], [WEXTRA="-W"])
AC_MSG_CHECKING([whether compiler supports -Wpedantic])
CFLAGS="-Wpedantic -Wno-long-long $CFLAGS"
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[extern int quiet;]])],
[ac_cv_cc_pedantic=yes], [ac_cv_cc_pedantic=no])
CFLAGS="$old_CFLAGS"
AC_MSG_RESULT($ac_cv_cc_pedantic)
WPEDANTIC=
AS_IF([test "$ac_cv_cc_pedantic" = yes],
[WPEDANTIC="-Wpedantic -Wno-long-long"])
CFLAGS="-Wall $WEXTRA $WPEDANTIC $CFLAGS"
CXXFLAGS="-Wall $WEXTRA $WPEDANTIC $CXXFLAGS"
fi
AC_MSG_CHECKING(for xlc)
AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
# ifndef __xlC__
# error
# endif
]])], [compiler_xlc=yes], [compiler_xlc=no])
AC_MSG_RESULT($compiler_xlc)
if test $compiler_xlc = yes -a "$powerpc_darwin" = true; then
# The darwin stack-frame-walking code is completely broken on xlc.
AC_DEFINE([DARWIN_DONT_PARSE_STACK], 1,
[Define to discover thread stack bounds on Darwin without trying
to walk the frames on the stack.])
fi
# XLC neither requires nor tolerates the unnecessary assembler goop.
# Similar for the Sun C compiler.
AM_CONDITIONAL([ASM_WITH_CPP_UNSUPPORTED],
[test $compiler_xlc = yes -o $compiler_suncc = yes])
if test "$GCC" = yes; then
# Disable aliasing optimization unless forced to.
AC_MSG_CHECKING([whether compiler supports -fno-strict-aliasing])
ac_cv_fno_strict_aliasing=no
for cflag in $CFLAGS; do
case "$cflag" in
-fstrict-aliasing)
# Opposite option already present
ac_cv_fno_strict_aliasing=skipped
break
;;
esac
done
if test "$ac_cv_fno_strict_aliasing" != skipped; then
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -fno-strict-aliasing"
AC_COMPILE_IFELSE([AC_LANG_SOURCE([])],
[ac_cv_fno_strict_aliasing=yes])
CFLAGS="$old_CFLAGS"
AS_IF([test "$ac_cv_fno_strict_aliasing" = yes],
[CFLAGS="$CFLAGS -fno-strict-aliasing"])
fi
AC_MSG_RESULT($ac_cv_fno_strict_aliasing)
fi
# Check for getcontext (uClibc can be configured without it, for example)
AC_CHECK_FUNC([getcontext], [],
[AC_DEFINE([NO_GETCONTEXT], [1], [Missing getcontext function.])])
# Check whether dl_iterate_phdr exists (as a strong symbol).
case "$host" in
*-*-cygwin* | *-*-darwin* | *-*-msys*)
;;
*)
AC_CHECK_FUNCS([dl_iterate_phdr])
;;
esac
case "$host" in
# While IRIX 6 has libdl for the O32 and N32 ABIs, it's missing for N64
# and unnecessary everywhere.
mips-sgi-irix6*)
;;
# We never want libdl on darwin. It is a fake libdl that just ends up making
# dyld calls anyway. The same applies to Cygwin.
*-*-cygwin* | *-*-darwin* | *-*-msys*)
;;
*)
AC_CHECK_LIB(dl, dlopen, THREADDLLIBS="$THREADDLLIBS -ldl")
;;
esac
avoid_cpp_lib=no
case "$host" in
*-*-hpux*)
avoid_cpp_lib=yes
;;
esac
AM_CONDITIONAL(AVOID_CPP_LIB,test $avoid_cpp_lib = yes)
# Check for various headers.
AC_CHECK_HEADER([execinfo.h], [],
[AC_DEFINE([GC_MISSING_EXECINFO_H], [1], [Missing execinfo.h header.])])
# extra LD Flags which are required for targets
case "${host}" in
*-*-darwin*)
extra_ldflags_libgc=-Wl,-single_module
;;
esac
AC_SUBST(extra_ldflags_libgc)
AC_SUBST(EXTRA_TEST_LIBS)
target_all=libgc.la
AC_SUBST(target_all)
dnl If the target is an eCos system, use the appropriate eCos
dnl I/O routines.
dnl FIXME: this should not be a local option but a global target
dnl system; at present there is no eCos target.
TARGET_ECOS="no"
AC_ARG_WITH([ecos],
[AS_HELP_STRING([--with-ecos], [enable runtime eCos target support])],
[TARGET_ECOS="$with_ecos"])
addobjs=
addlibs=
CXXLIBS=
case "$TARGET_ECOS" in
no)
;;
*)
AC_DEFINE([ECOS], 1, [Define to enable eCos target support.])
AM_CPPFLAGS="-I${TARGET_ECOS}/include $AM_CPPFLAGS"
addobjs="$addobjs ecos.lo"
;;
esac
AM_CONDITIONAL(CPLUSPLUS, test "${enable_cplusplus}" = yes)
AC_ARG_ENABLE(throw-bad-alloc-library,
[AS_HELP_STRING([--disable-throw-bad-alloc-library],
[do not build C++ gctba library])])
AM_CONDITIONAL(GC_TBA_LIBRARY,
test "${enable_cplusplus}" = yes \
-a "${enable_throw_bad_alloc_library}" != no)
if test "$GCC" = yes; then
if test "${enable_cplusplus}" = yes; then
case "$host" in
*-*-cygwin* | *-*-mingw* | *-*-msys*)
AC_MSG_CHECKING([whether libsupc++ required])
SUPC="`$CXX -print-file-name=libsupc++.a 2>/dev/null`"
if test -n "$SUPC" -a "$SUPC" != "libsupc++.a"; then
AC_MSG_RESULT(yes)
CXXLIBS="-lsupc++"
else
AC_MSG_RESULT(no)
fi
;;
esac
fi
fi
AC_SUBST(CXX)
AC_SUBST(AM_CFLAGS)
AC_SUBST(AM_CPPFLAGS)
AC_SUBST(CXXLIBS)
# Configuration of shared libraries
#
AC_MSG_CHECKING(whether to build shared libraries)
AC_ENABLE_SHARED
case "$host" in
alpha-*-openbsd*)
enable_shared=no
;;
esac
AC_MSG_RESULT($enable_shared)
# Compile with GC_DLL defined unless building static libraries.
if test "${enable_shared}" != no -a "${enable_static}" != yes; then
AC_DEFINE(GC_DLL)
if test "$GCC" = yes; then
# Pass -fvisibility=hidden option if supported
AC_MSG_CHECKING([whether compiler supports -fvisibility])
old_CFLAGS="$CFLAGS"
CFLAGS="-Werror -fvisibility=hidden $CFLAGS"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
[ac_cv_fvisibility_hidden=yes], [ac_cv_fvisibility_hidden=no])
CFLAGS="$old_CFLAGS"
AS_IF([test "$ac_cv_fvisibility_hidden" = yes],
[CFLAGS="-DGC_VISIBILITY_HIDDEN_SET -fvisibility=hidden $CFLAGS"],
[CFLAGS="-DGC_NO_VISIBILITY $CFLAGS"])
AC_MSG_RESULT($ac_cv_fvisibility_hidden)
fi
else
case "$host" in
*-*-cygwin* | *-*-mingw* | *-*-msys*)
# Do not require the clients to link with "user32" system library.
AC_DEFINE([DONT_USE_USER32_DLL], 1,
[Do not use user32.dll import library (Win32).])
# Use inline version of GC new and delete operators in cpptest
# otherwise the system ones might be used instead because of arbitrary
# ordering of object files when linking.
CXXFLAGS="$CXXFLAGS -DGC_NOT_DLL"
;;
esac
fi
# Configuration of machine-dependent code
#
AC_MSG_CHECKING(which machine-dependent code should be used)
machdep=
case "$host" in
alpha-*-openbsd*)
if test x"${ac_cv_lib_dl_dlopen}" != xyes ; then
AC_MSG_WARN(
"OpenBSD/Alpha without dlopen(). Shared library support is disabled.")
fi
;;
i?86-*-solaris2.[[89]])
# PROC_VDB appears to work in 2.8 and 2.9 but not in 2.10+ (for now).
AC_DEFINE([SOLARIS25_PROC_VDB_BUG_FIXED], 1,
[See the comment in gcconfig.h.])
;;
sparc-*-netbsd*)
machdep="sparc_netbsd_mach_dep.lo"
compile_asm=true
;;
sparc*-*-linux* | sparc*-*-openbsd* | sparc64-*-freebsd* | sparc64-*-netbsd*)
machdep="sparc_mach_dep.lo"
compile_asm=true
;;
sparc-sun-solaris2.3)
machdep="sparc_mach_dep.lo"
compile_asm=true
AC_DEFINE(SUNOS53_SHARED_LIB, 1,
[Define to work around a Solaris 5.3 bug (see dyn_load.c).])
;;
sparc*-sun-solaris2*)
machdep="sparc_mach_dep.lo"
compile_asm=true
;;
ia64-*-*)
machdep="ia64_save_regs_in_stack.lo"
;;
esac
if test "x$machdep" = x; then
AC_MSG_RESULT(none)
else
AC_MSG_RESULT($machdep)
addobjs="$addobjs $machdep"
fi
AC_SUBST(addobjs)
AC_SUBST(addlibs)
# Suppress "extension used" clang warning (when compiling .S files).
if test x$compile_asm = xtrue -a "$GCC" = yes; then
AC_MSG_CHECKING([whether compiler supports -Wno-language-extension-token])
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -Werror -Wno-language-extension-token"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])],
[ac_cv_lang_ext_token=yes], [ac_cv_lang_ext_token=no])
CFLAGS="$old_CFLAGS"
AS_IF([test "$ac_cv_lang_ext_token" = yes],
[CFLAGS="$CFLAGS -Wno-language-extension-token"])
AC_MSG_RESULT($ac_cv_lang_ext_token)
fi
dnl We use these options to decide which functions to include.
AC_ARG_WITH([target-subdir],
[AS_HELP_STRING([--with-target-subdir=SUBDIR],
[configuring target with a cross compiler])])
AC_ARG_WITH([cross-host],
[AS_HELP_STRING([--with-cross-host=HOST],
[configuring host with a cross compiler])])
dnl automake wants to see AC_EXEEXT. But we don't need it. And having
dnl it is actually a problem, because the compiler we're passed can't
dnl necessarily do a full link. So we fool automake here.
if false; then
dnl autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
dnl to nothing, so nothing would remain between `then' and `fi' if it
dnl were not for the `:' below.
:
AC_EXEEXT
fi
dnl The collector might not properly work on IBM AIX when
dnl built with gcc and -O. So we remove -O in the appropriate case.
AC_MSG_CHECKING(whether AIX gcc optimization fix is necessary)
case "$host" in
*aix*)
if test "$GCC" = yes; then
AC_MSG_RESULT(yes)
new_CFLAGS=
for i in $CFLAGS; do
case "$i" in
-O*)
;;
*)
new_CFLAGS="$new_CFLAGS $i"
;;
esac
done
CFLAGS="$new_CFLAGS"
else
AC_MSG_RESULT(no)
fi
;;
*)
AC_MSG_RESULT(no)
;;
esac
dnl Include defines that have become de facto standard.
dnl ALL_INTERIOR_POINTERS and NO_EXECUTE_PERMISSION can be overridden
dnl in the startup code.
AC_DEFINE([NO_EXECUTE_PERMISSION], [1],
[Define to make the collector not allocate executable memory
by default.])
AC_DEFINE([ALL_INTERIOR_POINTERS], [1],
[Define to recognise all pointers to the interior of objects.])
dnl Interface Selection
dnl -------------------
dnl
dnl By default, make the library as general as possible.
AC_ARG_ENABLE(gcj-support,
[AS_HELP_STRING([--disable-gcj-support], [disable support for gcj])])
if test x"$enable_gcj_support" != xno; then
AC_DEFINE(GC_GCJ_SUPPORT, 1, [Define to include support for gcj.])
case "$host" in
*-*-kfreebsd*-gnu)
# FIXME: For a reason, gctest hangs up on kFreeBSD if both of
# THREAD_LOCAL_ALLOC and GC_ENABLE_SUSPEND_THREAD are defined.
if test "${enable_thread_local_alloc}" = no; then
AC_DEFINE(GC_ENABLE_SUSPEND_THREAD)
fi
;;
*)
AC_DEFINE([GC_ENABLE_SUSPEND_THREAD], 1,
[Define to turn on GC_suspend_thread support (Linux only).])
;;
esac
fi
AM_CONDITIONAL(ENABLE_GCJ_SUPPORT, [test x"enable_gcj_support" != xno])
dnl Interaction with other programs that might use signals.
AC_ARG_ENABLE(sigrt-signals,
[AS_HELP_STRING([--enable-sigrt-signals],
[force GC to use SIGRTMIN-based signals for thread suspend/resume])])
if test x"${enable_sigrt_signals}" = xyes; then
AC_DEFINE([GC_USESIGRT_SIGNALS], 1,
[Force the GC to use signals based on SIGRTMIN+k.])
fi
dnl Debugging
dnl ---------
AH_TEMPLATE([GC_HAVE_BUILTIN_BACKTRACE],
[Define if backtrace information is supported.])
AH_TEMPLATE([MAKE_BACK_GRAPH],
[Define to build the collector with the support of the
functionality to print max length of chain through unreachable
objects ending in a reachable one.])
AH_TEMPLATE([SAVE_CALL_COUNT],
[The number of caller frames saved when allocating with the
debugging API.])
UNWINDLIBS=
AC_ARG_ENABLE(gc-debug,
[AS_HELP_STRING([--enable-gc-debug],
[include full support for pointer backtracing etc.])],
[if test "$enable_gc_debug" = "yes"; then
AC_MSG_WARN("Should define GC_DEBUG and use debug alloc in clients.")
AC_DEFINE([KEEP_BACK_PTRS], 1,
[Define to save back-pointers in debugging headers.])
keep_back_ptrs=true
AC_DEFINE([DBG_HDRS_ALL], 1,
[Define to force debug headers on all objects.])
AH_TEMPLATE([SHORT_DBG_HDRS],
[Shorten the headers to minimize object size at the expense
of checking for writes past the end.])
case $host in
ia64-*-linux*)
AC_CHECK_LIB(unwind, backtrace,
[AC_DEFINE(GC_HAVE_BUILTIN_BACKTRACE)
UNWINDLIBS=-lunwind
AC_MSG_WARN("Client code may need to link against libunwind.")])
;;
esac
case $host in
i[3456]86-*-dgux* | *-*-*linux*)
AC_DEFINE(MAKE_BACK_GRAPH)
;;
esac
case $host in
e2k-*-linux*)
# Some bug exists in backtrace().
;;
*-*-*linux*)
AC_MSG_WARN("Client must not use -fomit-frame-pointer.")
AC_DEFINE(SAVE_CALL_COUNT, 8)
;;
esac
fi])
AM_CONDITIONAL([MAKE_BACK_GRAPH], [test x"$enable_gc_debug" = xyes])
AM_CONDITIONAL([KEEP_BACK_PTRS], [test x"$keep_back_ptrs" = xtrue])
# Check whether a compiler warning of unsafe __builtin_return_address(1)
# could be suppressed by -Wno-frame-address option.
# __builtin_return_address(1) is used by libgc for debugging purposes only.
AC_MSG_CHECKING([whether -Wno-frame-address works])
use_wno_error_frame_address=no
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS -Werror -Wno-frame-address $CFLAGS_EXTRA"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
[if (!__builtin_return_address(1)) return 1;])],
[use_wno_error_frame_address=yes])
CFLAGS="$old_CFLAGS"
AC_MSG_RESULT($use_wno_error_frame_address)
if test x"$use_wno_error_frame_address" = xyes; then
CFLAGS="$CFLAGS -Wno-frame-address"
fi
# Check for dladdr (used for debugging).
AC_MSG_CHECKING(for dladdr)
have_dladdr=no
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# define _GNU_SOURCE 1
# include <dlfcn.h>
], [
Dl_info info;
(void)dladdr("", &info);
])], [have_dladdr=yes])
CFLAGS="$old_CFLAGS"
AC_MSG_RESULT($have_dladdr)
if test x"$have_dladdr" = xyes; then
AC_DEFINE([HAVE_DLADDR], 1, [Define to use 'dladdr' function.])
fi
# Check for pthread_sigmask and sigset_t.
AS_IF([test "$THREADS" = posix],
[AS_IF([test x$darwin_threads != xtrue -a x$win32_threads != xtrue],
[AC_MSG_CHECKING(for pthread_sigmask)
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# define _GNU_SOURCE 1
# include <pthread.h>
# include <signal.h>
], [sigset_t t; (void)pthread_sigmask(SIG_BLOCK, 0, &t)])],
[AC_MSG_RESULT(yes)
AC_DEFINE([GC_HAVE_PTHREAD_SIGMASK], [1],
[Define to use 'pthread_sigmask' function if needed.])],
[AC_MSG_RESULT(no)])
CFLAGS="$old_CFLAGS"])])
# sigsetjmp could be a macro (thus AC_CHECK_FUNCS cannot be used).
AC_MSG_CHECKING(for sigsetjmp)
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA"
AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <setjmp.h>],
[sigjmp_buf t; sigsetjmp(t, 0)])],
[AC_MSG_RESULT(yes)],
[AC_MSG_RESULT(no)
AC_DEFINE([GC_NO_SIGSETJMP], [1], [Missing sigsetjmp function.])])
CFLAGS="$old_CFLAGS"
# Build with GC_wcsdup() support if possible.
AC_MSG_CHECKING(for wcslen)
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA"
AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <wchar.h>],
[wchar_t ws[] = {0}; (void)wcslen(&ws)])],
[AC_MSG_RESULT(yes)
AC_DEFINE([GC_REQUIRE_WCSDUP], [1],
[Define and export GC_wcsdup function.])],
[AC_MSG_RESULT(no)])
CFLAGS="$old_CFLAGS"
# pthread_setname_np, if available, may have 1, 2 or 3 arguments.
AS_IF([test "$THREADS" = posix],
[AC_MSG_CHECKING(for pthread_setname_np)
old_CFLAGS="$CFLAGS"
CFLAGS="$CFLAGS $CFLAGS_EXTRA -Werror"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# define _GNU_SOURCE 1
# include <pthread.h>
], [pthread_setname_np("thread-name")])],
[AC_MSG_RESULT([yes (w/o tid)])
AC_DEFINE([HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID], [1],
[Define to use 'pthread_setname_np(const char*)' function.])],
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# define _GNU_SOURCE 1
# include <pthread.h>
], [pthread_setname_np(pthread_self(), "thread-name-%u", 0)])],
[AC_MSG_RESULT([yes (with tid and arg)])
AC_DEFINE([HAVE_PTHREAD_SETNAME_NP_WITH_TID_AND_ARG], [1],
[Define to use 'pthread_setname_np(pthread_t, const char*, void *)'
function.])],
[AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# define _GNU_SOURCE 1
# include <pthread.h>
], [pthread_setname_np(pthread_self(), "thread-name")])],
[AC_MSG_RESULT([yes (with tid)])
AC_DEFINE([HAVE_PTHREAD_SETNAME_NP_WITH_TID], [1],
[Define to use 'pthread_setname_np(pthread_t, const char*)'
function.])],
[AC_MSG_RESULT(no)
AC_MSG_CHECKING(for pthread_set_name_np)
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
# include <pthread.h>
# include <pthread_np.h>
], [pthread_set_name_np(pthread_self(), "thread-name")])],
[AC_MSG_RESULT(yes)
AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1],
[Define to use 'pthread_set_name_np(pthread_t, const char*)'
function.])],
[AC_MSG_RESULT(no)])])])])
CFLAGS="$old_CFLAGS"])
# Check for AViiON Machines running DGUX
ac_is_dgux=no
AC_CHECK_HEADER(sys/dg_sys_info.h,
[ac_is_dgux=yes;])
dnl :GOTCHA: we do not check anything but sys/dg_sys_info.h
if test $ac_is_dgux = yes; then
dgux_spec_opts="-DDGUX -D_DGUX_SOURCE -Di386 -mno-legend -O2"
CFLAGS="$dgux_spec_opts $CFLAGS"
CXXFLAGS="$dgux_spec_opts $CXXFLAGS"
if test "$enable_gc_debug" = "yes"; then
CFLAGS="-g -mstandard $CFLAGS"
CXXFLAGS="-g -mstandard $CXXFLAGS"
fi
AC_SUBST(CFLAGS)
AC_SUBST(CXXFLAGS)
fi
AC_ARG_ENABLE(java-finalization,
[AS_HELP_STRING([--disable-java-finalization],
[disable support for java finalization])])
if test x"$enable_java_finalization" != xno; then
AC_DEFINE([JAVA_FINALIZATION], 1,
[Define to make it somewhat safer by default to finalize objects
out of order by specifying a nonstandard finalization mark
procedure.])
fi
AC_ARG_ENABLE(atomic-uncollectable,
[AS_HELP_STRING([--disable-atomic-uncollectible],
[disable support for atomic uncollectible allocation])])
if test x"$enable_atomic_uncollectible" != x"no"; then
AC_DEFINE([GC_ATOMIC_UNCOLLECTABLE], 1,
[Define to enable atomic uncollectible allocation.])
fi
AC_ARG_ENABLE(redirect-malloc,
[AS_HELP_STRING([--enable-redirect-malloc],
[redirect malloc and friends to GC routines])])
if test "${enable_redirect_malloc}" = yes; then
if test "${enable_gc_debug}" = yes; then
AC_DEFINE([REDIRECT_MALLOC], GC_debug_malloc_replacement,
[If defined, redirect malloc to this function.])
AC_DEFINE([REDIRECT_REALLOC], GC_debug_realloc_replacement,
[If defined, redirect GC_realloc to this function.])
AC_DEFINE([REDIRECT_FREE], GC_debug_free,
[If defined, redirect free to this function.])
else
AC_DEFINE(REDIRECT_MALLOC, GC_malloc)
fi
AC_DEFINE([GC_USE_DLOPEN_WRAP], 1,
[Define to cause the collector to redefine malloc and
intercepted pthread routines with their real names while using
dlsym to refer to the original routines.])
fi
AC_ARG_ENABLE(disclaim,
[AS_HELP_STRING([--disable-disclaim],
[disable alternative (more efficient) finalization interface])])
if test x"$enable_disclaim" != xno; then
AC_DEFINE(ENABLE_DISCLAIM, 1,
[Define to enable alternative finalization interface.])
fi
AM_CONDITIONAL(ENABLE_DISCLAIM,
[test x"$enable_disclaim" != xno])
AC_ARG_ENABLE(dynamic-pointer-mask,
[AS_HELP_STRING([--enable-dynamic-pointer-mask],
[support pointer mask/shift set at runtime])])
if test "${enable_dynamic_pointer_mask}" = yes; then
AC_DEFINE(DYNAMIC_POINTER_MASK, 1,
[Define to support pointer mask/shift set at runtime.])
fi