-
Notifications
You must be signed in to change notification settings - Fork 3
/
p_plats.pas
286 lines (252 loc) · 7.5 KB
/
p_plats.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
//------------------------------------------------------------------------------
//
// DoomXS - A basic Windows source port of Doom
// based on original Linux Doom as published by "id Software"
// Copyright (C) 1993-1996 by id Software, Inc.
// Copyright (C) 2021-2022 by Jim Valavanis
//
// This program is free software; you can redistribute it and/or
// modify it under the terms of the GNU General Public License
// as published by the Free Software Foundation; either version 2
// of the License, or (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program; if not, write to the Free Software
// Foundation, inc., 59 Temple Place - Suite 330, Boston, MA
// 02111-1307, USA.
//
//------------------------------------------------------------------------------
// Site: https://sourceforge.net/projects/doomxs/
//------------------------------------------------------------------------------
unit p_plats;
interface
uses
p_spec,
r_defs;
var
activeplats: array[0..MAXPLATS - 1] of Pplat_t;
procedure T_PlatRaise(plat: Pplat_t);
function EV_DoPlat(line: Pline_t; typ: plattype_e; amount: integer): integer;
procedure P_ActivateInStasis(tag: integer);
procedure EV_StopPlat(line: Pline_t);
procedure P_AddActivePlat(plat: Pplat_t);
procedure P_RemoveActivePlat(plat: Pplat_t);
implementation
uses
doomdef,
m_fixed,
i_system,
m_rnd,
p_tick,
p_floor,
p_setup,
s_sound,
sounds,
z_memory;
procedure T_PlatRaise(plat: Pplat_t);
var
res: result_e;
begin
case plat.status of
up:
begin
res := T_MovePlane(plat.sector, plat.speed, plat.high, plat.crush, 0, 1);
if (plat.typ = raiseAndChange) or (plat.typ = raiseToNearestAndChange) then
begin
if leveltime and 7 = 0 then
S_StartSound(@plat.sector.soundorg, Ord(sfx_stnmov));
end;
if (res = crushed) and not plat.crush then
begin
plat.count := plat.wait;
plat.status := down;
S_StartSound(@plat.sector.soundorg, Ord(sfx_pstart));
end
else
begin
if res = pastdest then
begin
plat.count := plat.wait;
plat.status := waiting;
S_StartSound(@plat.sector.soundorg, Ord(sfx_pstop));
case plat.typ of
blazeDWUS,
downWaitUpStay:
P_RemoveActivePlat(plat);
raiseAndChange,
raiseToNearestAndChange:
P_RemoveActivePlat(plat);
end;
end;
end;
end;
down:
begin
res := T_MovePlane(plat.sector, plat.speed, plat.low, False, 0, -1);
if res = pastdest then
begin
plat.count := plat.wait;
plat.status := waiting;
S_StartSound(@plat.sector.soundorg, Ord(sfx_pstop));
end;
end;
waiting:
begin
plat.count := plat.count - 1;
if plat.count = 0 then
begin
if plat.sector.floorheight = plat.low then
plat.status := up
else
plat.status := down;
S_StartSound(@plat.sector.soundorg, Ord(sfx_pstart));
end;
end;
end;
end;
// Do Platforms
// "amount" is only used for SOME platforms.
function EV_DoPlat(line: Pline_t; typ: plattype_e; amount: integer): integer;
var
plat: Pplat_t;
secnum: integer;
sec: Psector_t;
begin
Result := 0;
// Activate all <type> plats that are in_stasis
if typ = perpetualRaise then
P_ActivateInStasis(line.tag);
secnum := P_FindSectorFromLineTag(line, -1);
while secnum >= 0 do
begin
sec := @sectors[secnum];
secnum := P_FindSectorFromLineTag(line, secnum);
if sec.specialdata <> nil then
Continue;
// Find lowest & highest floors around sector
Result := 1;
plat := Z_Malloc(SizeOf(plat_t), PU_LEVSPEC, nil);
P_AddThinker(@plat.thinker);
plat.typ := typ;
plat.sector := sec;
plat.sector.specialdata := plat;
plat.thinker.func.acp1 := @T_PlatRaise;
plat.crush := False;
plat.tag := line.tag;
case typ of
raiseToNearestAndChange:
begin
plat.speed := PLATSPEED div 2;
sec.floorpic := sides[line.sidenum[0]].sector.floorpic;
plat.high := P_FindNextHighestFloor(sec, sec.floorheight);
plat.wait := 0;
plat.status := up;
// NO MORE DAMAGE, IF APPLICABLE
sec.special := 0;
S_StartSound(@sec.soundorg, Ord(sfx_stnmov));
end;
raiseAndChange:
begin
plat.speed := PLATSPEED div 2;
sec.floorpic := sides[line.sidenum[0]].sector.floorpic;
plat.high := sec.floorheight + amount * FRACUNIT;
plat.wait := 0;
plat.status := up;
S_StartSound(@sec.soundorg, Ord(sfx_stnmov));
end;
downWaitUpStay:
begin
plat.speed := PLATSPEED * 4;
plat.low := P_FindLowestFloorSurrounding(sec);
if plat.low > sec.floorheight then
plat.low := sec.floorheight;
plat.high := sec.floorheight;
plat.wait := TICRATE * PLATWAIT;
plat.status := down;
S_StartSound(@sec.soundorg, Ord(sfx_pstart));
end;
blazeDWUS:
begin
plat.speed := PLATSPEED * 8;
plat.low := P_FindLowestFloorSurrounding(sec);
if plat.low > sec.floorheight then
plat.low := sec.floorheight;
plat.high := sec.floorheight;
plat.wait := TICRATE * PLATWAIT;
plat.status := down;
S_StartSound(@sec.soundorg, Ord(sfx_pstart));
end;
perpetualRaise:
begin
plat.speed := PLATSPEED;
plat.low := P_FindLowestFloorSurrounding(sec);
if plat.low > sec.floorheight then
plat.low := sec.floorheight;
plat.high := P_FindHighestFloorSurrounding(sec);
if plat.high < sec.floorheight then
plat.high := sec.floorheight;
plat.wait := TICRATE * PLATWAIT;
plat.status := plat_e(P_Random and 1);
S_StartSound(@sec.soundorg, Ord(sfx_pstart));
end;
end;
P_AddActivePlat(plat);
end;
end;
procedure P_ActivateInStasis(tag: integer);
var
i: integer;
begin
for i := 0 to MAXPLATS - 1 do
if (activeplats[i] <> nil) and (activeplats[i].tag = tag) and
(activeplats[i].status = in_stasis) then
begin
activeplats[i].status := activeplats[i].oldstatus;
activeplats[i].thinker.func.acp1 := @T_PlatRaise;
end;
end;
procedure EV_StopPlat(line: Pline_t);
var
i: integer;
begin
for i := 0 to MAXPLATS - 1 do
if (activeplats[i] <> nil) and (activeplats[i].status <> in_stasis) and
(activeplats[i].tag = line.tag) then
begin
activeplats[i].oldstatus := activeplats[i].status;
activeplats[i].status := in_stasis;
activeplats[i].thinker.func.acv := nil;
end;
end;
procedure P_AddActivePlat(plat: Pplat_t);
var
i: integer;
begin
for i := 0 to MAXPLATS - 1 do
if activeplats[i] = nil then
begin
activeplats[i] := plat;
Exit;
end;
I_Error('P_AddActivePlat(): no more plats!');
end;
procedure P_RemoveActivePlat(plat: Pplat_t);
var
i: integer;
begin
for i := 0 to MAXPLATS - 1 do
if plat = activeplats[i] then
begin
activeplats[i].sector.specialdata := nil;
P_RemoveThinker(@activeplats[i].thinker);
activeplats[i] := nil;
Exit;
end;
I_Error('P_RemoveActivePlat(): can''t find plat!');
end;
end.