build.gradle

apply from: 'gradle/githooks.gradle'

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    repositories {
        google()
        maven { url "https://jitpack.io" }
        maven { url 'https://maven.fabric.io/public' }
        jcenter()
    }
    dependencies {
        classpath Libraries.androidGradlePlugin
        classpath Libraries.coveralls
        classpath Libraries.googleServicesPlugin
        classpath Libraries.kotlinGradlePlugin
        classpath Libraries.jacoco
        classpath Libraries.navigationControllerSafeArgsPlugin
        classpath Libraries.fabricTools
        classpath Libraries.buildProperties
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven { url "https://dl.bintray.com/ethereum/maven/" }
        maven { url "https://jitpack.io" }
        maven { url 'https://maven.fabric.io/public' }
        maven { url 'https://onfido.bintray.com/maven/' }

        maven { url "http://dl.bintray.com/argo/sdk" } // probity
        maven { url "https://cdn.veriff.me/android/" } // veriff
        jcenter()
    }
    configurations.all {
        resolutionStrategy.force Libraries.findbugs
        resolutionStrategy.force Libraries.jacksonCore
        resolutionStrategy.force Libraries.okIo
        resolutionStrategy.force Libraries.kotlinReflect
    }
}

subprojects {
    // Increase the error output of the compiler, to prevent a flood of databinder errors
    // masking any dagger - and, indeed, other - annotation processor failures.
    afterEvaluate {
        if (project.plugins.hasPlugin("kotlin-kapt")) {
            kapt {
                javacOptions {
                    option("-Xmaxerrs", 500)
                }
            }
        }
    }
}

apply from: 'quality/jacocoRootReport.gradle'