Force newlines within reader conditionals

[arichiardi]

Hi again Kim,
as you noticed I am going through my zprint configuration and try and improve it :D

My next task is to format this:

#?(:bb nil
   :clj
   [(defn merr->exception [merr] (exception (merr/type merr) (merr/message merr) (merr/data merr)))
    (defn append-bug-message
      [s]
      (str s
           (when-not (str/ends-with? s ".") ".")
           " "
           "This is likely a bug, contact your system administrator."))])

to this

#?(:bb nil
   :clj
   [(defn merr->exception [merr]
      (exception (merr/type merr) (merr/message merr) (merr/data merr)))
    
    (defn append-bug-message
      [s]
      (str s
           (when-not (str/ends-with? s ".") ".")
           " "
           "This is likely a bug, contact your system administrator."))])

Basically there should be a newline between the defns, better visual clarity.

I tried to use :respect-nl? but as per your docs it cannot be used on :reader-cond so I was wondering if there is a better way.

Thank you in advance Kim 😄

[kkinnear]

This is an interesting one, since there is no current code to place additional newline between list elements. So we end up with another guide, this one actually having to look at the data and create a guide vector unique to each call. But we have the tools for that. I can make this a standard "style" if you like what it does, but until I do that, if you put this into your configuration:

 {:style-map
     {:vector-defn
        {:vector {:option-fn
                    (fn
                      ([] "vector-defn")
                      ([options n sexpr]
                       (when (= (:ztype options) :zipper)
                         (let [first-seq? (list? (first sexpr))
                               defn? (when first-seq?
                                       (= (first (first sexpr)) 'defn))]
                           (when defn?
                             (let [guide (into []
                                               (flatten (interpose [:newline
                                                                    :newline]
                                                          (repeat (count sexpr)
                                                                  :element))))]
                               {:guide guide}))))))}}}}

And then this this style:

(czprint i323 {:parse-string? true :style :vector-defn})
#?(:bb nil
   :clj [(defn merr->exception
           [merr]
           (exception (merr/type merr) (merr/message merr) (merr/data merr)))

         (defn append-bug-message
           [s]
           (str s
                (when-not (str/ends-with? s ".") ".")
                " "
                "This is likely a bug, contact your system administrator."))])

I think you will get what you want.

Note that this will put a blank line between every element in a vector where the first vector element is a list that starts with a 'defn symbol. It could be smarter, and check for 'defn in every element if you think that might be important.

Let me know how it goes. If this is useful, I can put it in the style-map and then you won't have to configure it directly.