flake.nix

{
  description = "Symbolic evaluation as a library";
  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
  inputs.flake-utils.url = "github:numtide/flake-utils";
  inputs.grisette-nix-build-env.url = "github:lsrcz/grisette-nix-build-env/main";

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      grisette-nix-build-env,
    }@inputs:
    flake-utils.lib.eachDefaultSystem (
      system:
      grisette-nix-build-env.lib.${system}.output {
        inherit nixpkgs system;
        srcRoot = ./.;
        extraHaskellPackages =
          pkgs: hfinal: helpers: setCIOptions: with helpers; {
            grisette = setCIOptions {
              extraTestToolDepends = byGhcVersion {
                "8107" = [ pkgs.z3 ];
                "902" = [ pkgs.z3 ];
                default = [
                  pkgs.z3
                  pkgs.bitwuzla
                ];
              };
              package = hfinal.callCabal2nix "grisette" ./. { };
              mixDirs = [
                ""
                "spec/spec-tmp"
                "doctest/doctest-tmp"
              ];
            };

          };
        devShellExtraBuildInputs =
          pkgs:
          {
            bitwuzla ? false,
            ...
          }:
          [
            pkgs.boolector
            pkgs.cvc5
          ]
          ++ (if bitwuzla then [ pkgs.bitwuzla ] else [ ]);
        treefmtExcludes = [
          "tutorials/*.ipynb"
          "tutorials/*.svg"
        ];
        pname = "grisette";
        extraOutputs = pkgs: haskellPackages: devShellWithVersion: {
          devShells = {
            "9101" = devShellWithVersion {
              ghcVersion = "9101";
              config = {
                isDevelopmentEnvironment = true;
                bitwuzla = true;
              };
            };
            default = devShellWithVersion {
              ghcVersion = "9101";
              config = {
                isDevelopmentEnvironment = true;
                bitwuzla = true;
              };
            };
            "9121" = devShellWithVersion {
              ghcVersion = "9121";
              config = {
                isDevelopmentEnvironment = false;
                bitwuzla = true;
              };
            };
          };
        };
      }
    );
}