-
-
Notifications
You must be signed in to change notification settings - Fork 44
/
gitattributes-mode.el
233 lines (209 loc) · 8.72 KB
/
gitattributes-mode.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
;;; gitattributes-mode.el --- Major mode for editing .gitattributes files -*- lexical-binding:t -*-
;; Copyright (C) 2013-2015 Rüdiger Sonderfeld
;; Copyright (C) 2013-2024 The Magit Project Contributors
;; Author: Rüdiger Sonderfeld <ruediger@c-plusplus.net>
;; Maintainer: Jonas Bernoulli <emacs.git-modes@jonas.bernoulli.dev>
;; Homepage: https://github.com/magit/git-modes
;; Keywords: convenience vc git
;; SPDX-License-Identifier: GPL-3.0-or-later
;; This file is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published
;; by the Free Software Foundation, either version 3 of the License,
;; or (at your option) any later version.
;;
;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this file. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; A major mode for editing .gitattributes files. See
;; the gitattributes(5) manpage for more information.
;; `eldoc-mode' is supported for known attributes.
;;; Code:
(require 'compat)
(require 'easymenu)
(require 'thingatpt)
(defgroup gitattributes-mode nil
"Edit .gitattributes files."
:link '(url-link "https://github.com/magit/git-modes")
:prefix "gitattributes-mode-"
:group 'tools)
(defcustom gitattributes-mode-enable-eldoc t
"Enable `eldoc-mode' when loading `gitattributes-mode'.
This provides documentation for known variables in the echo area.
Alternatively add `turn-on-eldoc-mode' to the mode hook."
:type 'boolean
:group 'gitattributes-mode)
(defcustom gitattributes-mode-man-function #'man
"Function to open the gitattributes(5) manpage."
:type '(choice (const :tag "Man" man)
(const :tag "Woman" woman)
(function :tag "Function"))
:group 'gitattributes-mode)
(defun gitattributes-mode-help ()
"Open the gitattributes(5) manpage using `gitattributes-mode-man-function'."
(interactive)
(funcall gitattributes-mode-man-function "gitattributes"))
(defconst gitattributes-mode-attributes
'(("text"
"This attribute enables and controls end-of-line normalization."
(t "auto"))
("eol"
"This attribute sets a specific line-ending style to be used in the \
working directory."
("crlf" "lf"))
("ident" "Handle $Id$." t)
("filter"
"A filter attribute can be set to a string value that names a filter \
driver specified in the configuration."
string)
("diff"
"The attribute diff affects how Git generates diffs for particular files."
(t string "ada" "bibtex" "cpp" "csharp" "fortran" "html" "java"
"matlab" "objc" "pascal" "perl" "php" "python" "ruby" "tex"))
("merge"
"The attribute merge affects how three versions of a file are merged."
(t string "text" "binary" "union"))
("conflict-marker-size"
"This attribute controls the length of conflict markers left in the work \
tree file during a conflicted merge."
(number))
("whitespace"
"The core.whitespace configuration variable allows you to define what \
diff and apply should consider whitespace errors for all paths in the project."
(t string))
("export-ignore"
"Files and directories with the attribute export-ignore won’t be added to \
archive files."
t)
("export-subst"
"If the attribute export-subst is set for a file then Git will expand \
several placeholders when adding this file to an archive."
t)
("delta"
"Delta compression will not be attempted for blobs for paths with the \
attribute delta set to false."
t)
("encoding"
"The encoding used for the file in GUI Tools (e.g., gitk(1) and \
git-gui(1))."
string))
"List of known attributes.
Format (NAME DOC ALLOWED-STATES).
NAME should be the name as a string.
DOC should be a short doc-string.
ALLOWED-STATE should be a list or single symbol or string of allowed values.
t means the attribute can be Set or Unset. `string' means the symbol value
can be any string and `number' means the value should be a number.")
(defun gitattributes-mode-eldoc (&optional no-state)
"Support for `eldoc-mode'.
If NO-STATE is non-nil then do not print state."
(let (entry)
(when (and (thing-at-point-looking-at "\\s-+\\(-\\|!\\)?\\(\\(?:\\sw-?\\)+\\)\\(=\\)?")
(setq entry (assoc-string (match-string 2)
gitattributes-mode-attributes)))
(concat (unless no-state
(cond
((string= (match-string 1) "-") "[Unset] ")
((string= (match-string 1) "!") "[Unspecified] ")
((string= (match-string 3) "=") "[Set to a value] ")
(t "[Set] ")))
(cadr entry)))))
(defvar gitattributes-mode-syntax-table
(let ((table (make-syntax-table)))
(modify-syntax-entry ?\s " " table)
(modify-syntax-entry ?\t " " table)
(modify-syntax-entry ?- "_." table)
(modify-syntax-entry ?! "." table)
(modify-syntax-entry ?= "." table)
(modify-syntax-entry ?# "<" table)
(modify-syntax-entry ?\n ">" table)
table)
"Syntax table for `gitattributes-mode'.")
(defun gitattributes-mode--highlight-1st-field (regexp)
"Highlight REGEXP in the first field only."
`(lambda (limit)
(let ((old-limit limit))
(save-excursion
(beginning-of-line)
(while (and (not (eobp)) (looking-at "^\\s-*$"))
(forward-line))
(when (re-search-forward "[[:space:]]" limit 'noerror)
(setq limit (point))))
(unless (< limit (point))
(if (re-search-forward ,regexp limit 'noerror)
t
(forward-line)
(when (< (point) old-limit)
(gitattributes-mode--highlight-1st-field old-limit)))))))
(defvar gitattributes-mode-font-lock-keywords
`(("^\\[attr]" . 'font-lock-function-name-face)
("\\s-+\\(-\\|!\\)[[:word:]]+" (1 'font-lock-negation-char-face))
("\\s-+\\(?:-\\|!\\)?\\(\\sw\\(?:\\sw\\|\\s_\\)*\\)=?"
(1 'font-lock-variable-name-face))
;; Pattern highlight similar to `gitignore-mode-font-lock-keywords'
(,(gitattributes-mode--highlight-1st-field "/") . 'font-lock-constant-face)
(,(gitattributes-mode--highlight-1st-field "[*?]") . 'font-lock-keyword-face)
(,(gitattributes-mode--highlight-1st-field "\\[.+?]") . 'font-lock-keyword-face))
"Keywords for highlight in `gitattributes-mode'.")
(defun gitattributes-mode-forward-field (&optional arg)
"Move point ARG fields forward.
If ARG is omitted or nil, move point forward one field."
(interactive "p")
(if (< arg 0)
(gitattributes-mode-backward-field (- arg))
(dotimes (_ (or arg 1))
(re-search-forward "\\s-[!-]?\\<" nil 'move))))
(defun gitattributes-mode-backward-field (&optional arg)
"Move point ARG fields backward.
If ARG is omitted or nil, move point backward one field."
(interactive "p")
(if (< arg 0)
(gitattributes-mode-forward-field (- arg))
(dotimes (_ (or arg 1))
(re-search-backward "\\s-[!-]?\\<" nil 'move))))
(defvar-keymap gitattributes-mode-map
:doc "Keymap for `gitattributes-mode'.")
(easy-menu-define gitattributes-mode-menu
gitattributes-mode-map
"Menu for `gitattributes-mode'."
'("Git Attributes"
["Forward Field" forward-sexp :active t
:help "Move forward across one field"]
["Backward Field" backward-sexp :active t
:help "Move backward across one field"]
["Kill Field Forward" kill-sexp :active t
:help "Kill field following cursor"]
["Kill Field Backward" backward-kill-sexp :active t
:help "Kill field preceding cursor"]
"--"
["Help" gitattributes-mode-help :active t
:help "Open gitattributes(5) manpage"]))
;;;###autoload
(define-derived-mode gitattributes-mode text-mode "Gitattributes"
"A major mode for editing .gitattributes files.
\\{gitattributes-mode-map}"
:group 'gitattributes-mode
:syntax-table gitattributes-mode-syntax-table
(setq font-lock-defaults '(gitattributes-mode-font-lock-keywords))
(setq-local comment-start "# ")
(setq-local comment-start-skip "#+\\s-*")
(setq-local eldoc-documentation-function #'gitattributes-mode-eldoc)
(setq-local forward-sexp-function #'gitattributes-mode-forward-field)
(when (and gitattributes-mode-enable-eldoc
(require 'eldoc nil 'noerror))
(eldoc-mode 1)))
;;;###autoload
(dolist (pattern '("/\\.gitattributes\\'"
"/info/attributes\\'"
"/git/attributes\\'"))
(add-to-list 'auto-mode-alist (cons pattern #'gitattributes-mode)))
;;; _
(provide 'gitattributes-mode)
;; Local Variables:
;; indent-tabs-mode: nil
;; End:
;;; gitattributes-mode.el ends here