build.gradle

description = "Spring Boot example using Hexagonal Architecture and Kotlin"

buildscript {
	ext {
        kotlinVersion = '1.2.10'
        springBootVersion = '1.5.7.RELEASE'
	}
	repositories {
        mavenLocal()
		mavenCentral()
	}
	dependencies {
		classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlinVersion}")
        classpath("org.jetbrains.kotlin:kotlin-allopen:${kotlinVersion}")
	}
}

ext['jackson.version'] = '2.9.2'

allprojects {
    apply plugin: 'kotlin'
    apply plugin: 'kotlin-spring'
    apply plugin: 'org.springframework.boot'

	group = 'io.pileworx.hex'
    version = '0.0.1-SNAPSHOT'

	repositories {
        jcenter()
        mavenLocal()
        mavenCentral()
	}

	sourceCompatibility = 1.8
	targetCompatibility = 1.8

    dependencies {
        compile("org.jetbrains.kotlin:kotlin-stdlib:${kotlinVersion}")
        compile("org.jetbrains.kotlin:kotlin-reflect:${kotlinVersion}")
        compile("org.springframework.boot:spring-boot-starter-data-couchbase")
        compile("org.springframework.boot:spring-boot-starter-hateoas")
        compile("org.springframework.boot:spring-boot-starter-security")
        compile("org.springframework.boot:spring-boot-starter-aop:")
        compile("org.springframework.boot:spring-boot-starter-amqp")
        compile("org.springframework.boot:spring-boot-starter-web")
        compile("org.springframework.boot:spring-boot-starter-actuator")
        compile('javax.inject:javax.inject:1')
        testCompile("org.springframework.boot:spring-boot-starter-test:")
    }

    springBoot {
        executable = true
        buildInfo {
            additionalProperties = [
                    'buildNumber': project.hasProperty("buildNumber") ? buildNumber : "DEV"
            ]
        }
    }
}

dependencies {
    compile project(':pileworx-hex-port')
    compile ("org.springframework.boot:spring-boot-starter-logging")
}

project('pileworx-hex-port') {
    dependencies {
        compile project(':pileworx-hex-app')
    }
}

project('pileworx-hex-app') {
    dependencies {
        compile project(':pileworx-hex-domain')
    }
}

project('pileworx-hex-domain') {
    dependencies {
        compile project(':pileworx-hex-common')
		compile("com.fasterxml.jackson.module:jackson-module-kotlin")
    }
}

project('pileworx-hex-common')

task wrapper(type: Wrapper) {
	gradleVersion = '3.5'
}